Add ability to switch View

By forwarding all `Key`s to the agent and allow it to decide what should
be done, instead of converting the `Key` to a `Control` and then decide
what should be done

gleam.toml

@@ -18,6 +18,7 @@ gleam_otp = ">= 1.2.0 and < 2.0.0"
 gleam_erlang = ">= 1.3.0 and < 2.0.0"
 simplifile = ">= 2.3.1 and < 3.0.0"
 gleam_json = ">= 3.1.0 and < 4.0.0"
+gleam_time = ">= 1.6.0 and < 2.0.0"
 
 [dev-dependencies]
 gleeunit = ">= 1.0.0 and < 2.0.0"

manifest.toml

@@ -7,6 +7,7 @@ packages = [
   { name = "gleam_json", version = "3.1.0", build_tools = ["gleam"], requirements = ["gleam_stdlib"], otp_app = "gleam_json", source = "hex", outer_checksum = "44FDAA8847BE8FC48CA7A1C089706BD54BADCC4C45B237A992EDDF9F2CDB2836" },
   { name = "gleam_otp", version = "1.2.0", build_tools = ["gleam"], requirements = ["gleam_erlang", "gleam_stdlib"], otp_app = "gleam_otp", source = "hex", outer_checksum = "BA6A294E295E428EC1562DC1C11EA7530DCB981E8359134BEABC8493B7B2258E" },
   { name = "gleam_stdlib", version = "0.65.0", build_tools = ["gleam"], requirements = [], otp_app = "gleam_stdlib", source = "hex", outer_checksum = "7C69C71D8C493AE11A5184828A77110EB05A7786EBF8B25B36A72F879C3EE107" },
+  { name = "gleam_time", version = "1.6.0", build_tools = ["gleam"], requirements = ["gleam_stdlib"], otp_app = "gleam_time", source = "hex", outer_checksum = "0DF3834D20193F0A38D0EB21F0A78D48F2EC276C285969131B86DF8D4EF9E762" },
   { name = "gleeunit", version = "1.9.0", build_tools = ["gleam"], requirements = ["gleam_stdlib"], otp_app = "gleeunit", source = "hex", outer_checksum = "DA9553CE58B67924B3C631F96FE3370C49EB6D6DC6B384EC4862CC4AAA718F3C" },
   { name = "simplifile", version = "2.3.1", build_tools = ["gleam"], requirements = ["filepath", "gleam_stdlib"], otp_app = "simplifile", source = "hex", outer_checksum = "957E0E5B75927659F1D2A1B7B75D7B9BA96FAA8D0C53EA71C4AD9CD0C6B848F6" },
 ]
@@ -16,5 +17,6 @@ gleam_erlang = { version = ">= 1.3.0 and < 2.0.0" }
 gleam_json = { version = ">= 3.1.0 and < 4.0.0" }
 gleam_otp = { version = ">= 1.2.0 and < 2.0.0" }
 gleam_stdlib = { version = ">= 0.44.0 and < 2.0.0" }
+gleam_time = { version = ">= 1.6.0 and < 2.0.0" }
 gleeunit = { version = ">= 1.0.0 and < 2.0.0" }
 simplifile = { version = ">= 2.3.1 and < 3.0.0" }

src/musicplayer.gleam

@@ -2,11 +2,14 @@ import gleam/erlang/process.{type Name}
 
 import musicplayer/input/input
 import musicplayer/input/key.{type Key}
+import musicplayer/logging/logging
 import musicplayer/mpv/mpv
 import musicplayer/musicplayer
 import musicplayer/ui/ui
 
 pub fn main() -> Nil {
+  let assert Ok(_) = logging.initialize()
+
   let input_keys_name: Name(Key) = process.new_name("input_keys")
   input.new(input_keys_name)
 

src/musicplayer/control.gleam

@@ -1,30 +1,58 @@
+import gleam/string
+import musicplayer/ui/layout
+
 import musicplayer/input/key.{type Key}
 
+pub type Mode {
+  Idle
+  Searching(input: String)
+}
+
 pub type Control {
   TogglePlayPause
-  Search
+  Search(input: String, capturing: Bool)
 
-  Raw(String)
-  Return
-  Backspace
+  SetView(view_idx: layout.ViewIdx)
 
   Exit
 }
 
-pub fn from_key(key: Key) -> Result(Control, Nil) {
+pub fn from_key(key: Key, mode: Mode) -> Result(Control, Nil) {
+  case mode {
+    Idle -> idle_from_key(key)
+    Searching(input) -> searching_from_key(key, input)
+  }
+}
+
+pub fn idle_from_key(key: Key) -> Result(Control, Nil) {
   case key {
-    key.Return -> Ok(Return)
-    key.Backspace -> Ok(Backspace)
-    key.Char(char) -> Ok(char_control(char))
+    key.Char(char) -> {
+      case char {
+        // Views are zero indexed
+        "1" -> Ok(SetView(0))
+        "2" -> Ok(SetView(1))
+
+        " " -> Ok(TogglePlayPause)
+        "/" -> Ok(Search(input: "", capturing: True))
+        "q" -> Ok(Exit)
+
+        // NOOP
         _ -> Error(Nil)
       }
     }
 
-fn char_control(char: String) -> Control {
-  case char {
-    " " -> TogglePlayPause
-    "/" -> Search
-    "q" -> Exit
-    _ -> Raw(char)
+    // NOOP
+    _ -> Error(Nil)
+  }
+}
+
+pub fn searching_from_key(key: Key, input: String) -> Result(Control, Nil) {
+  case key {
+    key.Char(char) -> Ok(Search(input <> char, True))
+    key.Backspace -> Ok(Search(string.drop_end(input, 1), True))
+    key.Return -> Ok(Search(input, False))
+
+    // NOOP
+    _ -> Error(Nil)
   }
 }

src/musicplayer/logging/control.gleam

@@ -0,0 +1,5 @@
+pub type Control {
+  Write(String)
+
+  Exit
+}

src/musicplayer/logging/logging.gleam

@@ -0,0 +1,30 @@
+import gleam/result
+import gleam/string
+import gleam/time/calendar
+import gleam/time/timestamp
+import simplifile
+
+const filepath = "/tmp/musicplayer.log"
+
+pub fn initialize() -> Result(Nil, String) {
+  case simplifile.is_file(filepath) {
+    Ok(True) -> Ok(Nil)
+    _ -> simplifile.create_file(filepath)
+  }
+  |> result.map_error(fn(e) {
+    "Could not access or create log file: " <> string.inspect(e)
+  })
+}
+
+pub fn log(content: String) -> Nil {
+  let log_line =
+    timestamp.system_time()
+    |> timestamp.to_rfc3339(calendar.utc_offset)
+    <> ": "
+    <> content
+    <> "\n"
+
+  // Ignore any logging errors
+  let _ = simplifile.append(filepath, log_line)
+  Nil
+}

src/musicplayer/mpv/mpv.gleam

@@ -24,7 +24,7 @@ pub fn new() -> Result(Subject(Control), String) {
         |> actor.start
       {
         Error(start_error) ->
-          Error("Could not start actor: " <> string.inspect(start_error))
+          Error("Could not start mpv: " <> string.inspect(start_error))
         Ok(actor.Started(data: mpv, ..)) -> Ok(mpv)
       }
     }

src/musicplayer/musicplayer.gleam

@@ -1,28 +1,18 @@
 import gleam/erlang/process.{type Name, type Pid, type Subject}
 import gleam/otp/actor
-import gleam/result
 import gleam/string
-import musicplayer/time/time
 
-import musicplayer/control.{type Control}
+import musicplayer/control.{type Mode}
 import musicplayer/input/key.{type Key}
+import musicplayer/logging/logging
 import musicplayer/mpv/control as mpv_control
+import musicplayer/time/time
 import musicplayer/ui/control as ui_control
 import musicplayer/ui/layout
 
-type Mode {
-  Idle
-  Searching
-}
-
-type Input {
-  Input(capturing: Bool, content: String)
-}
-
 type State {
   State(
     mode: Mode,
-    input: Input,
     ui: Subject(ui_control.Control),
     mpv: Subject(mpv_control.Control),
   )
@@ -35,90 +25,90 @@ pub fn new(
 ) -> Result(Pid, String) {
   let input_keys = process.named_subject(input_keys_name)
 
-  let input = Input(False, "")
-
   case
-    actor.new(State(Idle, input, ui, mpv))
+    actor.new(State(control.Idle, ui, mpv))
     |> actor.on_message(handle_message)
     |> actor.start
   {
     Error(start_error) ->
       Error("Could not start actor: " <> string.inspect(start_error))
     Ok(actor.Started(pid:, data: musicplayer)) -> {
+      logging.log("musicplayer - started")
       process.spawn(fn() {
         let assert Ok(_) = process.register(process.self(), input_keys_name)
-        handle_key(musicplayer, input_keys)
+        forward_key(musicplayer, input_keys)
       })
 
-      process.spawn(fn() { update_playback_time_loop(mpv, ui, 1000) })
+      process.spawn(fn() { update_playback_time_loop(mpv, ui, 250) })
 
       Ok(pid)
     }
   }
 }
 
-fn handle_message(state: State, control: Control) -> actor.Next(State, Control) {
-  case control {
-    control.Search -> {
-      update_search(state.ui, "searching: ")
-
-      actor.continue(
-        State(
-          ..state,
-          mode: Searching,
-          input: Input(..state.input, capturing: True),
-        ),
+fn handle_message(state: State, key: Key) -> actor.Next(State, Key) {
+  case control.from_key(key, state.mode) {
+    Error(_) -> actor.continue(state)
+    Ok(c) ->
+      case c {
+        control.SetView(view_idx) -> {
+          logging.log(
+            "musicplayer - setting current view to: "
+            <> string.inspect(view_idx),
           )
-    }
 
-    control.Raw(content) -> {
-      let content = case state.mode {
-        Idle -> state.input.content
-        Searching -> {
-          let updated = state.input.content <> content
-          update_search(state.ui, "searching: " <> updated)
-          updated
-        }
+          update_current_view(state.ui, view_idx)
+          actor.continue(state)
         }
+        control.Search(input, capturing) -> {
+          case capturing {
+            True -> {
+              logging.log("musicplayer - searching: " <> input)
 
-      actor.continue(State(..state, input: Input(..state.input, content:)))
-    }
-    control.Backspace -> {
-      let content = case state.mode {
-        Idle -> state.input.content
-        Searching -> string.drop_end(state.input.content, 1)
-      }
-      actor.continue(State(..state, input: Input(..state.input, content:)))
-    }
-    control.Return -> {
-      // Note: state.input.content is now the final input, use it
-      // before it is reset
-      case state.mode {
-        Idle -> Nil
-        Searching -> update_search(state.ui, "")
-      }
+              update_search(state.ui, "searching: " <> input)
 
-      actor.continue(
-        State(..state, mode: Idle, input: Input(capturing: False, content: "")),
+              actor.continue(State(..state, mode: control.Searching(input)))
+            }
+            False -> {
+              logging.log(
+                "musicplayer - recieved return. `input`: "
+                <> "'"
+                <> input
+                <> "'",
               )
-    }
 
+              update_search(state.ui, "")
+
+              actor.continue(State(..state, mode: control.Idle))
+            }
+          }
+        }
         control.TogglePlayPause -> {
+          logging.log("musicplayer - toggling play/pause")
+
           process.send(state.mpv, mpv_control.TogglePlayPause)
           update_playback_time(state.mpv, state.ui)
           actor.continue(state)
         }
         control.Exit -> {
+          logging.log("musicplayer - initiating musicplayer shutdown")
           // Close `mpv` socket
-      process.call(state.mpv, 1000, fn(reply_to) { mpv_control.Exit(reply_to) })
+          process.call(state.mpv, 1000, fn(reply_to) {
+            mpv_control.Exit(reply_to)
+          })
 
           // Reset terminal state (show cursor etc.)
-      process.call(state.ui, 1000, fn(reply_to) { ui_control.Exit(reply_to) })
+          process.call(state.ui, 1000, fn(reply_to) {
+            ui_control.Exit(reply_to)
+          })
+
+          logging.log("musicplayer - stopped")
 
           actor.stop()
         }
       }
   }
+}
 
 fn update_playback_time_loop(
   mpv: Subject(mpv_control.Control),
@@ -126,6 +116,7 @@ fn update_playback_time_loop(
   interval_ms: Int,
 ) {
   process.sleep(interval_ms)
+  // TODO only update if state is playing
   update_playback_time(mpv, ui)
 
   update_playback_time_loop(mpv, ui, interval_ms)
@@ -164,14 +155,21 @@ fn update_search(ui: Subject(ui_control.Control), content: String) -> Nil {
   process.send(ui, ui_control.UpdateState(layout.Search, content))
 }
 
-/// `handle_key` listens to a subject onto which `input` will send messages with `Key`s
-fn handle_key(musicplayer: Subject(Control), input_keys: Subject(Key)) -> Nil {
+fn update_current_view(
+  ui: Subject(ui_control.Control),
+  view_idx: layout.ViewIdx,
+) {
+  process.send(ui, ui_control.SetView(view_idx))
+}
+
+/// `forward_key` listens to a subject onto which `input` will send messages with `Key`s
+/// that is then forwarded to the `musicplayer` agent to handle
+fn forward_key(musicplayer: Subject(Key), input_keys: Subject(Key)) -> Nil {
   let _ =
     process.new_selector()
     |> process.select(input_keys)
     |> process.selector_receive_forever
-    |> control.from_key
-    |> result.map(process.send(musicplayer, _))
+    |> process.send(musicplayer, _)
 
-  handle_key(musicplayer, input_keys)
+  forward_key(musicplayer, input_keys)
 }

src/musicplayer/ui/control.gleam

@@ -1,9 +1,11 @@
 import gleam/erlang/process.{type Subject}
 
-import musicplayer/ui/layout.{type Section}
+import musicplayer/ui/layout.{type Section, type ViewIdx}
 
 pub type Control {
+  UpdateDimensions(columns: Int, rows: Int)
   UpdateState(section: Section, content: String)
+  SetView(view_idx: ViewIdx)
 
   Exit(reply_to: Subject(Nil))
 }

src/musicplayer/ui/internal.gleam

@@ -1,19 +1,25 @@
 import gleam/int
 import gleam/io
 
-pub fn print(content: String) -> Nil {
-  io.print(content <> "\n")
-}
-
 // https://en.wikipedia.org/wiki/ANSI_escape_code#Control_Sequence_Introducer_commands
 
+pub const move_to_home = "\u{001B}[H"
+
+pub const disable_auto_wrap = "\u{001B}[?7l"
+
+pub const enable_auto_wrap = "\u{001B}[?7h"
+
+pub fn update(frame: String) -> Nil {
+  io.print(disable_auto_wrap <> move_to_home <> frame <> enable_auto_wrap)
+}
+
 pub fn clear_screen() -> Nil {
   io.print("\u{001B}[2J\u{001B}[H")
 }
 
-pub fn print_at(text: String, x: Int, y: Int) -> Nil {
+pub fn chars_at(chars: String, x: Int, y: Int) -> String {
   let seq = "\u{001B}[" <> int.to_string(y) <> ";" <> int.to_string(x) <> "H"
-  io.print(seq <> text)
+  seq <> chars
 }
 
 pub fn hide_cursor() -> Nil {
@@ -23,3 +29,13 @@ pub fn hide_cursor() -> Nil {
 pub fn show_cursor() -> Nil {
   io.print("\u{001B}[?25h")
 }
+
+pub type Enotsup
+
+// https://www.erlang.org/doc/apps/stdlib/io.html#rows/0
+@external(erlang, "io", "rows")
+pub fn io_get_rows() -> Result(Int, Enotsup)
+
+// https://www.erlang.org/doc/apps/stdlib/io.html#columns/0
+@external(erlang, "io", "columns")
+pub fn io_get_columns() -> Result(Int, Enotsup)

src/musicplayer/ui/layout.gleam

@@ -1,37 +1,101 @@
 import gleam/dict
+import gleam/int
+import gleam/list
+import gleam/pair
+import gleam/set
+import gleam/string
 
-pub type Layout {
-  Layout(nodes: dict.Dict(Section, Node))
-}
+import musicplayer/ui/internal
+import musicplayer/ui/plot.{type Buffer}
+
+pub const root_section = "reserved_root_section"
 
 pub type Section {
-  Root
+  Section(String)
+
   Header
   Search
   PlaybackTime
 }
 
-pub type Node {
-  Node(content: String, x: Int, y: Int, children: List(Section))
+pub type Dimension {
+  Percent(width: Int, height: Int)
+  // TODO add Flex that flows
 }
 
-pub fn new() -> Layout {
-  let nodes =
-    dict.from_list([
-      #(
-        Root,
-        Node(content: "", x: 0, y: 0, children: [
-          Header,
-          Search,
-          PlaybackTime,
-        ]),
-      ),
-      #(Header, Node(content: "Music Player", x: 1, y: 1, children: [])),
-      #(Search, Node(content: "", x: 30, y: 1, children: [])),
-      #(PlaybackTime, Node(content: "00:00", x: 1, y: 2, children: [])),
-    ])
+pub type Style {
+  Style(dimensions: Dimension)
+}
 
-  Layout(nodes: nodes)
+pub type Node {
+  Row(content: String, style: Style, children: List(Section))
+  Cell(content: String, style: Style)
+}
+
+pub type ViewIdx =
+  Int
+
+pub type View =
+  dict.Dict(Section, Node)
+
+// Layout consists of a list Views, and only one View is rendered at a time
+pub type Layout {
+  Layout(
+    columns: Int,
+    rows: Int,
+    current_view: ViewIdx,
+    views: dict.Dict(ViewIdx, View),
+  )
+}
+
+pub fn new(
+  columns: Int,
+  rows: Int,
+  views: List(List(#(Section, Node))),
+) -> Layout {
+  let views =
+    list.index_map(views, fn(view_nodes, i) { #(i, view_nodes) })
+    |> list.fold(dict.new(), fn(view_acc, iv) {
+      let #(i, view_nodes) = iv
+
+      dict.insert(view_acc, i, view_loop(i, view_nodes))
+    })
+
+  Layout(columns:, rows:, current_view: 0, views:)
+}
+
+fn view_loop(i: ViewIdx, view_nodes: List(#(Section, Node))) -> View {
+  let children =
+    view_nodes
+    |> list.flat_map(fn(node) {
+      case pair.second(node) {
+        Row(children: c, ..) -> c
+        Cell(..) -> []
+      }
+    })
+    |> set.from_list
+
+  // All sections that are not children of other nodes will be added as
+  // children to the root
+  let orphans =
+    view_nodes
+    |> list.map(pair.first)
+    |> list.filter(fn(node) { !set.contains(children, node) })
+
+  dict.from_list(view_nodes)
+  |> dict.insert(
+    view_index_section(i),
+    Row(
+      content: "",
+      style: Style(dimensions: Percent(width: 100, height: 100)),
+      children: orphans,
+    ),
+  )
+}
+
+/// Takes a ViewIndex and create a Section key from it
+fn view_index_section(view_idx: ViewIdx) -> Section {
+  Section(string.append("view_", int.to_string(view_idx)))
 }
 
 pub fn update_section(
@@ -39,13 +103,146 @@ pub fn update_section(
   section: Section,
   content: String,
 ) -> Layout {
-  case dict.get(layout.nodes, section) {
+  case dict.get(layout.views, layout.current_view) {
     Error(_) -> layout
-    Ok(node) ->
-      Layout(nodes: dict.insert(
-        layout.nodes,
-        section,
-        Node(..node, content: content),
-      ))
+    Ok(view) ->
+      case dict.get(view, section) {
+        Error(_) -> layout
+        Ok(node) -> {
+          let updated_node = case node {
+            Cell(..) -> Cell(..node, content: content)
+            Row(..) -> Row(..node, content: content)
+          }
+
+          let updated_view = dict.insert(view, section, updated_node)
+
+          Layout(
+            ..layout,
+            views: dict.insert(layout.views, layout.current_view, updated_view),
+          )
+        }
+      }
+  }
+}
+
+pub fn update_dimensions(layout: Layout, columns: Int, rows: Int) -> Layout {
+  Layout(..layout, columns:, rows:)
+}
+
+pub fn update_current_view(layout: Layout, view_idx: ViewIdx) -> Layout {
+  Layout(..layout, current_view: view_idx)
+}
+
+pub fn render(layout: Layout) -> Nil {
+  let context =
+    RenderContext(
+      parent_width: layout.columns,
+      parent_height: layout.rows,
+      parent_top_left_x: 1,
+      parent_top_left_y: 1,
+      position_index: 0,
+    )
+
+  case dict.get(layout.views, layout.current_view) {
+    Error(_) -> Nil
+    Ok(view) -> {
+      let buffer: Buffer = dict.new()
+
+      render_loop(
+        view,
+        context,
+        view_index_section(layout.current_view),
+        buffer,
+      )
+      |> plot.flush_buffer(layout.columns, layout.rows)
+      |> internal.update
+    }
+  }
+}
+
+pub type RenderContext {
+  RenderContext(
+    parent_width: Int,
+    parent_height: Int,
+    parent_top_left_x: Int,
+    parent_top_left_y: Int,
+    position_index: Int,
+  )
+}
+
+pub fn render_loop(
+  view: View,
+  context: RenderContext,
+  from: Section,
+  buffer: Buffer,
+) -> Buffer {
+  case dict.get(view, from) {
+    Error(_) -> buffer
+    Ok(node) -> {
+      // Margin between container and the node being rendered
+      let margin = 2
+
+      let #(node_width, node_height) = case node.style.dimensions {
+        Percent(width:, height:) -> {
+          let width = { context.parent_width * width } / 100
+          let height = { context.parent_height * height } / 100
+
+          #(width, height)
+        }
+      }
+
+      // Check if this node should be placed to the left or below the parent
+      let #(node_top_left_x, node_top_left_y) = case node {
+        Row(..) -> #(
+          context.parent_top_left_x,
+          context.parent_top_left_y + { context.position_index * node_height },
+        )
+        Cell(..) -> #(
+          context.parent_top_left_x + { context.position_index * node_width },
+          context.parent_top_left_y,
+        )
+      }
+
+      let parent =
+        plot.box(
+          buffer,
+          node_top_left_x,
+          node_top_left_y,
+          node_width,
+          node_height,
+        )
+        |> plot.text(node.content, node_top_left_x, node_top_left_y)
+
+      case node {
+        Cell(..) -> parent
+        Row(children:, ..) -> {
+          list.index_map(children, fn(child, i) { #(i, child) })
+          |> list.fold(parent, fn(acc_buffer, ic) {
+            let #(i, child) = ic
+
+            let #(child_width, child_height) = case node.style.dimensions {
+              Percent(width:, height:) -> {
+                let width = { { context.parent_width * width } / 100 } - margin
+                let height =
+                  { { context.parent_height * height } / 100 } - margin
+
+                #(width, height)
+              }
+            }
+
+            let context =
+              RenderContext(
+                parent_width: child_width,
+                parent_height: child_height,
+                parent_top_left_x: context.parent_top_left_x + 1,
+                parent_top_left_y: context.parent_top_left_y + 1,
+                position_index: i,
+              )
+
+            render_loop(view, context, child, acc_buffer)
+          })
+        }
+      }
+    }
   }
 }

src/musicplayer/ui/layout_examples/layout_examples.gleam

@@ -0,0 +1,58 @@
+import musicplayer/ui/internal
+import musicplayer/ui/layout.{Percent, Section, Style}
+import musicplayer/ui/layout_examples/wait_for_input.{wait_for_input}
+
+pub fn main() {
+  let assert Ok(columns) = internal.io_get_columns()
+  let assert Ok(rows) = internal.io_get_rows()
+
+  two_rows_with_cells(columns, rows)
+  |> layout.render
+
+  wait_for_input()
+}
+
+/// Two rows:
+/// First row has two cells
+/// Second row has no cells
+fn two_rows_with_cells(columns: Int, rows: Int) -> layout.Layout {
+  let views = [
+    [
+      #(
+        Section("Row1"),
+        layout.Row(
+          content: "row 1",
+          style: Style(dimensions: Percent(width: 100, height: 50)),
+          children: [
+            Section("A"),
+            Section("B"),
+          ],
+        ),
+      ),
+      #(
+        Section("A"),
+        layout.Cell(
+          content: "cell 1",
+          style: Style(dimensions: Percent(width: 50, height: 50)),
+        ),
+      ),
+      #(
+        Section("B"),
+        layout.Cell(
+          content: "cell 2",
+          style: Style(dimensions: Percent(width: 50, height: 50)),
+        ),
+      ),
+      #(
+        Section("Row2"),
+        layout.Row(
+          content: "row 2",
+          style: Style(dimensions: Percent(width: 50, height: 50)),
+          children: [],
+        ),
+      ),
+    ],
+  ]
+
+  layout.new(columns, rows, views)
+}

src/musicplayer/ui/layout_examples/wait_for_input.gleam

@@ -0,0 +1,15 @@
+import gleam/erlang/process.{type Name}
+
+import musicplayer/input/input
+import musicplayer/input/key.{type Key}
+
+pub fn wait_for_input() {
+  let input_keys_name: Name(Key) = process.new_name("input_keys")
+  let assert Ok(_) = process.register(process.self(), input_keys_name)
+
+  input.new(input_keys_name)
+
+  process.new_selector()
+  |> process.select(process.named_subject(input_keys_name))
+  |> process.selector_receive_forever
+}

src/musicplayer/ui/plot.gleam

@@ -0,0 +1,72 @@
+import gleam/dict.{type Dict}
+import gleam/list
+import gleam/string
+
+pub type Buffer =
+  Dict(#(Int, Int), String)
+
+pub fn flush_buffer(buffer: Buffer, columns: Int, rows: Int) -> String {
+  list.range(1, rows)
+  |> list.map(fn(y) {
+    list.range(1, columns)
+    |> list.map(fn(x) {
+      case dict.get(buffer, #(x, y)) {
+        Ok(char) -> char
+        Error(_) -> " "
+      }
+    })
+    |> string.join("")
+  })
+  |> string.join("\r\n")
+}
+
+pub fn text(buffer: Buffer, text: String, x: Int, y: Int) -> Buffer {
+  text
+  |> string.to_graphemes
+  |> list.index_fold(buffer, fn(acc, char, i) {
+    dict.insert(acc, #(x + i, y), char)
+  })
+}
+
+pub fn box(buffer: Buffer, x: Int, y: Int, width: Int, height: Int) -> Buffer {
+  // TODO move box style to `layout.Style`
+  let box_chars = #("┌", "┐", "└", "┘", "─", "│")
+  let #(tl, tr, bl, br, hor, ver) = box_chars
+
+  case width < 2 || height < 2 {
+    True -> buffer
+    False -> {
+      buffer
+      |> dict.insert(#(x, y), tl)
+      |> dict.insert(#(x + width - 1, y), tr)
+      |> dict.insert(#(x, y + height - 1), bl)
+      |> dict.insert(#(x + width - 1, y + height - 1), br)
+      |> horizontal_line(x + 1, y, width - 2, hor)
+      |> horizontal_line(x + 1, y + height - 1, width - 2, hor)
+      |> vertical_line(x, y + 1, height - 2, ver)
+      |> vertical_line(x + width - 1, y + 1, height - 2, ver)
+    }
+  }
+}
+
+fn horizontal_line(
+  buffer: Buffer,
+  x: Int,
+  y: Int,
+  len: Int,
+  char: String,
+) -> Buffer {
+  list.range(0, len - 1)
+  |> list.fold(buffer, fn(acc, i) { dict.insert(acc, #(x + i, y), char) })
+}
+
+fn vertical_line(
+  buffer: Buffer,
+  x: Int,
+  y: Int,
+  len: Int,
+  char: String,
+) -> Buffer {
+  list.range(0, len - 1)
+  |> list.fold(buffer, fn(acc, i) { dict.insert(acc, #(x, y + i), char) })
+}

src/musicplayer/ui/ui.gleam

@@ -1,12 +1,13 @@
-import gleam/dict
 import gleam/erlang/process.{type Subject}
+import gleam/int
 import gleam/list
 import gleam/otp/actor
 import gleam/string
 
+import musicplayer/logging/logging
 import musicplayer/ui/control.{type Control}
-import musicplayer/ui/internal as ui_internal
-import musicplayer/ui/layout.{type Layout, type Section}
+import musicplayer/ui/internal
+import musicplayer/ui/layout.{type Layout}
 
 pub type State(redraw, content) {
   State(redraw: Subject(Layout), layout: Layout)
@@ -16,7 +17,69 @@ pub fn new() -> Result(Subject(Control), String) {
   let redraw_name = process.new_name("redraw")
   let redraw: Subject(Layout) = process.named_subject(redraw_name)
 
-  let layout = layout.new()
+  let layout =
+    [
+      [
+        #(
+          layout.Header,
+          layout.Row(
+            content: "Foo <1> | Bar (2)",
+            style: layout.Style(dimensions: layout.Percent(
+              width: 100,
+              height: 50,
+            )),
+            children: [],
+          ),
+        ),
+        #(
+          layout.PlaybackTime,
+          layout.Row(
+            content: "00:00",
+            style: layout.Style(dimensions: layout.Percent(
+              width: 100,
+              height: 50,
+            )),
+            children: [],
+          ),
+        ),
+      ],
+      [
+        #(
+          layout.Header,
+          layout.Row(
+            content: "Foo (1) | Bar <2>",
+            style: layout.Style(dimensions: layout.Percent(
+              width: 100,
+              height: 33,
+            )),
+            children: [],
+          ),
+        ),
+        #(
+          layout.Search,
+          layout.Row(
+            content: "",
+            style: layout.Style(dimensions: layout.Percent(
+              width: 100,
+              height: 33,
+            )),
+            children: [],
+          ),
+        ),
+        #(
+          layout.PlaybackTime,
+          layout.Row(
+            content: "00:00",
+            style: layout.Style(dimensions: layout.Percent(
+              width: 100,
+              height: 33,
+            )),
+            children: [],
+          ),
+        ),
+      ],
+    ]
+    |> layout.new(0, 0, _)
 
   case
     actor.new(State(redraw, layout))
@@ -26,13 +89,18 @@ pub fn new() -> Result(Subject(Control), String) {
     Error(start_error) ->
       Error("Could not start actor: " <> string.inspect(start_error))
     Ok(actor.Started(data: ui, ..)) -> {
+      process.spawn(fn() {
+        let update_dimensions_interval_ms = 300
+        update_dimensions_on_interval(ui, update_dimensions_interval_ms)
+      })
+
       process.spawn(fn() {
         let assert Ok(_) = process.register(process.self(), redraw_name)
 
-        ui_internal.clear_screen()
-        ui_internal.hide_cursor()
+        internal.clear_screen()
+        internal.hide_cursor()
 
-        redraw_on_update_loop(redraw)
+        redraw_loop(redraw)
       })
 
       Ok(ui)
@@ -45,37 +113,61 @@ fn handle_message(
   control: Control,
 ) -> actor.Next(State(redraw, layout), Control) {
   case control {
+    control.UpdateDimensions(columns, rows) -> {
+      let current_dimensions = #(state.layout.columns, state.layout.rows)
+
+      case #(columns, rows) == current_dimensions {
+        True -> actor.continue(state)
+        False -> {
+          [columns, rows]
+          |> list.map(int.to_string)
+          |> string.join(" ")
+          |> string.append("ui - updating dimensions: ", _)
+          |> logging.log
+
+          let layout = layout.update_dimensions(state.layout, columns, rows)
+
+          process.send(state.redraw, layout)
+          actor.continue(State(..state, layout:))
+        }
+      }
+    }
     control.UpdateState(section, content) -> {
       let layout = layout.update_section(state.layout, section, content)
-      let state = State(..state, layout:)
 
       actor.send(state.redraw, layout)
-      actor.continue(state)
+      actor.continue(State(..state, layout:))
     }
 
     control.Exit(reply_to) -> {
-      ui_internal.show_cursor()
+      internal.show_cursor()
       process.send(reply_to, Nil)
       actor.stop()
     }
+    control.SetView(view_idx) -> {
+      let layout = layout.update_current_view(state.layout, view_idx)
+
+      actor.send(state.redraw, layout)
+      actor.continue(State(..state, layout:))
+    }
   }
 }
 
-fn redraw_on_update_loop(redraw: Subject(Layout)) -> Nil {
-  let layout = process.receive_forever(redraw)
+fn redraw_loop(redraw: Subject(Layout)) -> Nil {
+  process.receive_forever(redraw)
+  |> layout.render
 
-  ui_internal.clear_screen()
-  render_layout(layout, layout.Root)
-
-  redraw_on_update_loop(redraw)
+  redraw_loop(redraw)
 }
 
-fn render_layout(layout: Layout, from: Section) -> Nil {
-  case dict.get(layout.nodes, from) {
-    Error(_) -> Nil
-    Ok(node) -> {
-      list.each(node.children, fn(child) { render_layout(layout, child) })
-      ui_internal.print_at(node.content, node.x, node.y)
+fn update_dimensions_on_interval(ui: Subject(Control), interval_ms: Int) {
+  case internal.io_get_columns(), internal.io_get_rows() {
+    Ok(width), Ok(height) -> {
+      process.send(ui, control.UpdateDimensions(width, height))
     }
+    _, _ -> logging.log("ui - failed to update dimensions")
   }
+
+  process.sleep(interval_ms)
+  update_dimensions_on_interval(ui, interval_ms)
 }

test/musicplayer/control_test.gleam

@@ -1,7 +1,7 @@
 import gleam/list
 import gleeunit
 
-import musicplayer/control.{type Control}
+import musicplayer/control.{type Control, type Mode}
 import musicplayer/input/key.{type Key, Char}
 
 pub fn main() -> Nil {
@@ -9,16 +9,24 @@ pub fn main() -> Nil {
 }
 
 type TestCase {
-  TestCase(key: Key, expected: Result(Control, Nil))
+  TestCase(key: Key, mode: Mode, expected: Result(Control, Nil))
 }
 
 pub fn control_from_key_test() {
-  let test_cases = [
-    TestCase(Char(" "), Ok(control.TogglePlayPause)),
-    TestCase(Char("q"), Ok(control.Exit)),
+  let idle_tests = [
+    TestCase(Char(" "), control.Idle, Ok(control.TogglePlayPause)),
+    TestCase(Char("/"), control.Idle, Ok(control.Search("", True))),
+    TestCase(Char("q"), control.Idle, Ok(control.Exit)),
   ]
 
-  list.each(test_cases, fn(tc) {
-    assert tc.expected == control.from_key(tc.key)
+  let search_tests = [
+    TestCase(Char("a"), control.Searching(""), Ok(control.Search("a", True))),
+    TestCase(Char("b"), control.Searching("a"), Ok(control.Search("ab", True))),
+  ]
+
+  let test_cases = [idle_tests, search_tests]
+
+  list.each(list.flatten(test_cases), fn(tc) {
+    assert tc.expected == control.from_key(tc.key, tc.mode)
   })
 }

test/musicplayer/mpv/mpv_test.gleam

@@ -1,6 +1,6 @@
 import gleeunit
 
-import musicplayer/mpv/internal as control_internal
+import musicplayer/mpv/internal
 
 pub fn main() -> Nil {
   gleeunit.main()
@@ -10,6 +10,6 @@ pub fn parse_playback_time_test() {
   let json_string =
     "{\"data\":\"123.456789\",\"request_id\":0,\"error\":\"success\"}\n"
 
-  let assert Ok(data) = control_internal.parse_playback_time(json_string)
+  let assert Ok(data) = internal.parse_playback_time(json_string)
   assert data == 123.456789
 }

test/musicplayer/ui/layout_test.gleam

@@ -0,0 +1,116 @@
+import gleam/dict
+import gleam/io
+import gleam/string
+import gleeunit
+import gleeunit/should
+
+import musicplayer/ui/layout.{Percent, RenderContext, Section, Style}
+import musicplayer/ui/plot
+
+pub fn main() -> Nil {
+  gleeunit.main()
+}
+
+pub fn percent_layout_test() {
+  let views = [
+    [
+      #(
+        Section("Row1"),
+        layout.Row(
+          content: "row 1",
+          style: Style(dimensions: Percent(width: 100, height: 50)),
+          children: [
+            Section("A"),
+            Section("B"),
+          ],
+        ),
+      ),
+      #(
+        Section("A"),
+        layout.Cell(
+          content: "cell 1",
+          style: Style(dimensions: Percent(width: 50, height: 100)),
+        ),
+      ),
+      #(
+        Section("B"),
+        layout.Cell(
+          content: "cell 2",
+          style: Style(dimensions: Percent(width: 50, height: 100)),
+        ),
+      ),
+      #(
+        Section("Row2"),
+        layout.Row(
+          content: "row 1",
+          style: Style(dimensions: Percent(width: 100, height: 50)),
+          children: [],
+        ),
+      ),
+    ],
+  ]
+
+  let columns = 80
+  let rows = 20
+  let layout = layout.new(columns, rows, views)
+
+  let expected =
+    "
+┌──────────────────────────────────────────────────────────────────────────────┐
+│row 1────────────────────────────────────────────────────────────────────────┐│
+││cell 1───────────────────────────────┐cell 2───────────────────────────────┐││
+│││                                    ││                                    │││
+│││                                    ││                                    │││
+│││                                    ││                                    │││
+│││                                    ││                                    │││
+│││                                    ││                                    │││
+││└────────────────────────────────────┘└────────────────────────────────────┘││
+│└────────────────────────────────────────────────────────────────────────────┘│
+│row 1────────────────────────────────────────────────────────────────────────┐│
+││                                                                            ││
+││                                                                            ││
+││                                                                            ││
+││                                                                            ││
+││                                                                            ││
+││                                                                            ││
+││                                                                            ││
+│└────────────────────────────────────────────────────────────────────────────┘│
+└──────────────────────────────────────────────────────────────────────────────┘
+"
+    |> string.replace(each: "\n", with: "\r\n")
+    |> string.trim
+
+  let context =
+    RenderContext(
+      parent_width: layout.columns,
+      parent_height: layout.rows,
+      parent_top_left_x: 1,
+      parent_top_left_y: 1,
+      position_index: 0,
+    )
+
+  let assert Ok(view) = dict.get(layout.views, layout.current_view)
+
+  let flushed =
+    layout.render_loop(
+      view,
+      context,
+      Section(string.append("view_", string.inspect(layout.current_view))),
+      dict.new(),
+    )
+    |> plot.flush_buffer(layout.columns, layout.rows)
+
+  case flushed == expected {
+    True -> Nil
+    False -> {
+      io.println("Test failed")
+      io.println("Expected:")
+      io.println(string.trim(expected))
+
+      io.println("Got:")
+      io.println(flushed)
+
+      should.equal(flushed, expected)
+    }
+  }
+}