Move styling to style and add Border type

By forwarding all `Key`s to the agent and allow it to decide what should
be done, instead of converting the `Key` to a `Control` and then decide
what should be done

src/musicplayer/control.gleam

@@ -1,30 +1,58 @@
+import gleam/string
+import musicplayer/ui/layout
+
 import musicplayer/input/key.{type Key}
 
+pub type Mode {
+  Idle
+  Searching(input: String)
+}
+
 pub type Control {
   TogglePlayPause
-  Search
+  Search(input: String, capturing: Bool)
 
-  Raw(String)
-  Return
-  Backspace
+  SetView(view_idx: layout.ViewIdx)
 
   Exit
 }
 
-pub fn from_key(key: Key) -> Result(Control, Nil) {
+pub fn from_key(key: Key, mode: Mode) -> Result(Control, Nil) {
+  case mode {
+    Idle -> idle_from_key(key)
+    Searching(input) -> searching_from_key(key, input)
+  }
+}
+
+pub fn idle_from_key(key: Key) -> Result(Control, Nil) {
   case key {
-    key.Return -> Ok(Return)
-    key.Backspace -> Ok(Backspace)
-    key.Char(char) -> Ok(char_control(char))
+    key.Char(char) -> {
+      case char {
+        // Views are zero indexed
+        "1" -> Ok(SetView(0))
+        "2" -> Ok(SetView(1))
+
+        " " -> Ok(TogglePlayPause)
+        "/" -> Ok(Search(input: "", capturing: True))
+        "q" -> Ok(Exit)
+
+        // NOOP
         _ -> Error(Nil)
       }
     }
 
-fn char_control(char: String) -> Control {
-  case char {
-    " " -> TogglePlayPause
-    "/" -> Search
-    "q" -> Exit
-    _ -> Raw(char)
+    // NOOP
+    _ -> Error(Nil)
+  }
+}
+
+pub fn searching_from_key(key: Key, input: String) -> Result(Control, Nil) {
+  case key {
+    key.Char(char) -> Ok(Search(input <> char, True))
+    key.Backspace -> Ok(Search(string.drop_end(input, 1), True))
+    key.Return -> Ok(Search(input, False))
+
+    // NOOP
+    _ -> Error(Nil)
   }
 }

src/musicplayer/musicplayer.gleam

@@ -1,9 +1,8 @@
 import gleam/erlang/process.{type Name, type Pid, type Subject}
 import gleam/otp/actor
-import gleam/result
 import gleam/string
 
-import musicplayer/control.{type Control}
+import musicplayer/control.{type Mode}
 import musicplayer/input/key.{type Key}
 import musicplayer/logging/logging
 import musicplayer/mpv/control as mpv_control
@@ -11,19 +10,9 @@ import musicplayer/time/time
 import musicplayer/ui/control as ui_control
 import musicplayer/ui/layout
 
-type Mode {
-  Idle
-  Searching
-}
-
-type Input {
-  Input(capturing: Bool, content: String)
-}
-
 type State {
   State(
     mode: Mode,
-    input: Input,
     ui: Subject(ui_control.Control),
     mpv: Subject(mpv_control.Control),
   )
@@ -36,10 +25,8 @@ pub fn new(
 ) -> Result(Pid, String) {
   let input_keys = process.named_subject(input_keys_name)
 
-  let input = Input(False, "")
-
   case
-    actor.new(State(Idle, input, ui, mpv))
+    actor.new(State(control.Idle, ui, mpv))
     |> actor.on_message(handle_message)
     |> actor.start
   {
@@ -49,75 +36,53 @@ pub fn new(
       logging.log("musicplayer - started")
       process.spawn(fn() {
         let assert Ok(_) = process.register(process.self(), input_keys_name)
-        handle_key(musicplayer, input_keys)
+        forward_key(musicplayer, input_keys)
       })
 
-      process.spawn(fn() { update_playback_time_loop(mpv, ui, 1000) })
+      process.spawn(fn() { update_playback_time_loop(mpv, ui, 250) })
 
       Ok(pid)
     }
   }
 }
 
-fn handle_message(state: State, control: Control) -> actor.Next(State, Control) {
-  case control {
-    control.Search -> {
-      logging.log("musicplayer - initiating search")
-
-      update_search(state.ui, "searching: ")
-
-      actor.continue(
-        State(
-          ..state,
-          mode: Searching,
-          input: Input(..state.input, capturing: True),
-        ),
-      )
-    }
-
-    control.Raw(content) -> {
-      logging.log("musicplayer - recieved raw input: " <> content)
-
-      let content = case state.mode {
-        Idle -> state.input.content
-        Searching -> {
-          let updated = state.input.content <> content
-          update_search(state.ui, "searching: " <> updated)
-          updated
-        }
-      }
-
-      actor.continue(State(..state, input: Input(..state.input, content:)))
-    }
-    control.Backspace -> {
-      logging.log("musicplayer - recieved backspace")
-
-      let content = case state.mode {
-        Idle -> state.input.content
-        Searching -> string.drop_end(state.input.content, 1)
-      }
-      actor.continue(State(..state, input: Input(..state.input, content:)))
-    }
-    control.Return -> {
+fn handle_message(state: State, key: Key) -> actor.Next(State, Key) {
+  case control.from_key(key, state.mode) {
+    Error(_) -> actor.continue(state)
+    Ok(c) ->
+      case c {
+        control.SetView(view_idx) -> {
           logging.log(
-        "musicplayer - recieved return. `input.capture`: "
+            "musicplayer - setting current view to: "
+            <> string.inspect(view_idx),
+          )
+
+          update_current_view(state.ui, view_idx)
+          actor.continue(state)
+        }
+        control.Search(input, capturing) -> {
+          case capturing {
+            True -> {
+              logging.log("musicplayer - searching: " <> input)
+
+              update_search(state.ui, "searching: " <> input)
+
+              actor.continue(State(..state, mode: control.Searching(input)))
+            }
+            False -> {
+              logging.log(
+                "musicplayer - recieved return. `input`: "
                 <> "'"
-        <> state.input.content
+                <> input
                 <> "'",
               )
 
-      // Note: state.input.content is now the final input, use it
-      // before it is reset
-      case state.mode {
-        Idle -> Nil
-        Searching -> update_search(state.ui, "")
-      }
+              update_search(state.ui, "")
 
-      actor.continue(
-        State(..state, mode: Idle, input: Input(capturing: False, content: "")),
-      )
+              actor.continue(State(..state, mode: control.Idle))
+            }
+          }
         }
-
         control.TogglePlayPause -> {
           logging.log("musicplayer - toggling play/pause")
 
@@ -128,10 +93,14 @@ fn handle_message(state: State, control: Control) -> actor.Next(State, Control)
         control.Exit -> {
           logging.log("musicplayer - initiating musicplayer shutdown")
           // Close `mpv` socket
-      process.call(state.mpv, 1000, fn(reply_to) { mpv_control.Exit(reply_to) })
+          process.call(state.mpv, 1000, fn(reply_to) {
+            mpv_control.Exit(reply_to)
+          })
 
           // Reset terminal state (show cursor etc.)
-      process.call(state.ui, 1000, fn(reply_to) { ui_control.Exit(reply_to) })
+          process.call(state.ui, 1000, fn(reply_to) {
+            ui_control.Exit(reply_to)
+          })
 
           logging.log("musicplayer - stopped")
 
@@ -139,6 +108,7 @@ fn handle_message(state: State, control: Control) -> actor.Next(State, Control)
         }
       }
   }
+}
 
 fn update_playback_time_loop(
   mpv: Subject(mpv_control.Control),
@@ -164,7 +134,7 @@ fn update_playback_time(
     Error(err) ->
       process.send(
         ui,
-        ui_control.UpdateState(
+        ui_control.UpdateHeading(
           layout.PlaybackTime,
           "playback time: N/A (err: " <> err.details <> ")",
         ),
@@ -173,7 +143,7 @@ fn update_playback_time(
     Ok(mpv_control.PlaybackTime(data: playback_time)) ->
       process.send(
         ui,
-        ui_control.UpdateState(
+        ui_control.UpdateHeading(
           layout.PlaybackTime,
           "playback time: " <> time.to_duration_string(playback_time),
         ),
@@ -182,17 +152,24 @@ fn update_playback_time(
 }
 
 fn update_search(ui: Subject(ui_control.Control), content: String) -> Nil {
-  process.send(ui, ui_control.UpdateState(layout.Search, content))
+  process.send(ui, ui_control.UpdateHeading(layout.Search, content))
 }
 
-/// `handle_key` listens to a subject onto which `input` will send messages with `Key`s
-fn handle_key(musicplayer: Subject(Control), input_keys: Subject(Key)) -> Nil {
+fn update_current_view(
+  ui: Subject(ui_control.Control),
+  view_idx: layout.ViewIdx,
+) {
+  process.send(ui, ui_control.SetView(view_idx))
+}
+
+/// `forward_key` listens to a subject onto which `input` will send messages with `Key`s
+/// that is then forwarded to the `musicplayer` agent to handle
+fn forward_key(musicplayer: Subject(Key), input_keys: Subject(Key)) -> Nil {
   let _ =
     process.new_selector()
     |> process.select(input_keys)
     |> process.selector_receive_forever
-    |> control.from_key
-    |> result.map(process.send(musicplayer, _))
+    |> process.send(musicplayer, _)
 
-  handle_key(musicplayer, input_keys)
+  forward_key(musicplayer, input_keys)
 }

src/musicplayer/ui/control.gleam

@@ -1,10 +1,11 @@
 import gleam/erlang/process.{type Subject}
 
-import musicplayer/ui/layout.{type Section}
+import musicplayer/ui/layout.{type Section, type ViewIdx}
 
 pub type Control {
-  UpdateDimensions(width: Int, height: Int)
-  UpdateState(section: Section, content: String)
+  UpdateDimensions(columns: Int, rows: Int)
+  UpdateHeading(section: Section, heading: String)
+  SetView(view_idx: ViewIdx)
 
   Exit(reply_to: Subject(Nil))
 }

src/musicplayer/ui/internal.gleam

@@ -3,13 +3,23 @@ import gleam/io
 
 // https://en.wikipedia.org/wiki/ANSI_escape_code#Control_Sequence_Introducer_commands
 
+pub const move_to_home = "\u{001B}[H"
+
+pub const disable_auto_wrap = "\u{001B}[?7l"
+
+pub const enable_auto_wrap = "\u{001B}[?7h"
+
+pub fn update(frame: String) -> Nil {
+  io.print(disable_auto_wrap <> move_to_home <> frame <> enable_auto_wrap)
+}
+
 pub fn clear_screen() -> Nil {
   io.print("\u{001B}[2J\u{001B}[H")
 }
 
-pub fn print_at(text: String, x: Int, y: Int) -> Nil {
+pub fn chars_at(chars: String, x: Int, y: Int) -> String {
   let seq = "\u{001B}[" <> int.to_string(y) <> ";" <> int.to_string(x) <> "H"
-  io.print(seq <> text)
+  seq <> chars
 }
 
 pub fn hide_cursor() -> Nil {

src/musicplayer/ui/layout.gleam

@@ -1,180 +1,251 @@
 import gleam/dict
-import gleam/float
 import gleam/int
 import gleam/list
+import gleam/option.{type Option, None, Some}
+import gleam/pair
+import gleam/set
 import gleam/string
 
-import musicplayer/logging/logging
 import musicplayer/ui/internal
+import musicplayer/ui/plot.{type Buffer}
+import musicplayer/ui/style.{type Style, Percent, Style}
 
-pub type Layout {
-  Layout(width: Int, height: Int, nodes: dict.Dict(Section, Node))
-}
+pub const root_section = "reserved_root_section"
 
 pub type Section {
-  Root
+  Section(String)
+
   Header
   Search
   PlaybackTime
 }
 
-/// A Nodes width and height is in percentage (of the available width/height of its parent Node)
 pub type Node {
-  Node(
-    content: String,
-    width_percent: Int,
-    height_percent: Int,
-    children: List(Section),
+  Row(heading: Option(String), style: Style, children: List(Section))
+  Cell(heading: Option(String), style: Style)
+}
+
+pub type ViewIdx =
+  Int
+
+pub type View =
+  dict.Dict(Section, Node)
+
+// Layout consists of a list Views, and only one View is rendered at a time
+pub type Layout {
+  Layout(
+    columns: Int,
+    rows: Int,
+    current_view: ViewIdx,
+    views: dict.Dict(ViewIdx, View),
   )
 }
 
-pub fn new() -> Layout {
-  let nodes =
-    dict.from_list([
-      #(
-        Root,
-        Node(content: "", width_percent: 100, height_percent: 100, children: [
-          // Header,
-          // Search,
-          PlaybackTime,
-        ]),
-      ),
-      // #(
-      //   Header,
-      //   Node(content: "Music Player", width: 50, height: 10, children: []),
-      // ),
-      // #(Search, Node(content: "", width: 50, height: 10, children: [])),
-      #(
-        PlaybackTime,
-        Node(
-          content: "00:00",
-          width_percent: 50,
-          height_percent: 100,
-          children: [],
-        ),
-      ),
-    ])
+pub fn new(
+  columns: Int,
+  rows: Int,
+  views: List(List(#(Section, Node))),
+) -> Layout {
+  let views =
+    list.index_map(views, fn(view_nodes, i) { #(i, view_nodes) })
+    |> list.fold(dict.new(), fn(view_acc, iv) {
+      let #(i, view_nodes) = iv
 
-  Layout(0, 0, nodes: nodes)
+      dict.insert(view_acc, i, view_loop(i, view_nodes))
+    })
+
+  Layout(columns:, rows:, current_view: 0, views:)
 }
 
-pub fn update_section(
+fn view_loop(i: ViewIdx, view_nodes: List(#(Section, Node))) -> View {
+  let children =
+    view_nodes
+    |> list.flat_map(fn(node) {
+      case pair.second(node) {
+        Row(children: c, ..) -> c
+        Cell(..) -> []
+      }
+    })
+    |> set.from_list
+
+  // All sections that are not children of other nodes will be added as
+  // children to the root
+  let orphans =
+    view_nodes
+    |> list.map(pair.first)
+    |> list.filter(fn(node) { !set.contains(children, node) })
+
+  dict.from_list(view_nodes)
+  |> dict.insert(
+    view_index_section(i),
+    Row(
+      heading: None,
+      style: Style(dimensions: Percent(width: 100, height: 100), border: None),
+      children: orphans,
+    ),
+  )
+}
+
+/// Takes a ViewIndex and create a Section key from it
+fn view_index_section(view_idx: ViewIdx) -> Section {
+  Section(string.append("view_", int.to_string(view_idx)))
+}
+
+pub fn update_section_heading(
   layout: Layout,
   section: Section,
-  content: String,
+  heading: String,
 ) -> Layout {
-  case dict.get(layout.nodes, section) {
+  case dict.get(layout.views, layout.current_view) {
     Error(_) -> layout
-    Ok(node) ->
+    Ok(view) ->
+      case dict.get(view, section) {
+        Error(_) -> layout
+        Ok(node) -> {
+          let updated_node = case node {
+            Cell(..) -> Cell(..node, heading: Some(heading))
+            Row(..) -> Row(..node, heading: Some(heading))
+          }
+
+          let updated_view = dict.insert(view, section, updated_node)
+
           Layout(
             ..layout,
-        nodes: dict.insert(
-          layout.nodes,
-          section,
-          Node(..node, content: content),
-        ),
+            views: dict.insert(layout.views, layout.current_view, updated_view),
           )
         }
       }
+  }
+}
 
-pub fn update_dimensions(layout: Layout, width: Int, height: Int) -> Layout {
-  Layout(..layout, width:, height:)
+pub fn update_dimensions(layout: Layout, columns: Int, rows: Int) -> Layout {
+  Layout(..layout, columns:, rows:)
+}
+
+pub fn update_current_view(layout: Layout, view_idx: ViewIdx) -> Layout {
+  Layout(..layout, current_view: view_idx)
 }
 
 pub fn render(layout: Layout) -> Nil {
-  internal.clear_screen()
-  [layout.width, layout.height]
-  |> list.map(int.to_string)
-  |> string.join(" ")
-  |> string.append("layout - render: ", _)
-  |> logging.log
+  let context =
+    RenderContext(
+      parent_width: layout.columns,
+      parent_height: layout.rows,
+      parent_top_left_x: 1,
+      parent_top_left_y: 1,
+      position_index: 0,
+    )
 
-  let container_width = int.to_float(layout.width)
-  let container_height = int.to_float(layout.height)
-  let container_top_left_x = 1
-  let container_top_left_y = 1
+  case dict.get(layout.views, layout.current_view) {
+    Error(_) -> Nil
+    Ok(view) -> {
+      let buffer: Buffer = dict.new()
 
       render_loop(
-    layout,
-    container_width,
-    container_height,
-    container_top_left_x,
-    container_top_left_y,
-    Root,
+        view,
+        context,
+        view_index_section(layout.current_view),
+        buffer,
+      )
+      |> plot.flush_buffer(layout.columns, layout.rows)
+      |> internal.update
+    }
+  }
+}
+
+pub type RenderContext {
+  RenderContext(
+    parent_width: Int,
+    parent_height: Int,
+    parent_top_left_x: Int,
+    parent_top_left_y: Int,
+    position_index: Int,
   )
 }
 
 pub fn render_loop(
-  layout: Layout,
-  container_width: Float,
-  container_height: Float,
-  container_top_left_x: Int,
-  container_top_left_y: Int,
+  view: View,
+  context: RenderContext,
   from: Section,
-) -> Nil {
-  let margin = 2.0
-
-  case dict.get(layout.nodes, from) {
-    Error(_) -> Nil
+  buffer: Buffer,
+) -> Buffer {
+  case dict.get(view, from) {
+    Error(_) -> buffer
     Ok(node) -> {
-      list.each(node.children, fn(child) {
-        let cw =
-          container_width
-          *. { int.to_float(node.width_percent) /. 100.0 }
-          -. margin
-          |> float.floor
+      // Margin between container and the node being rendered
+      let margin = 2
 
-        let ch =
-          container_height
-          *. { int.to_float(node.height_percent) /. 100.0 }
-          -. margin
-          |> float.floor
+      let #(node_width, node_height) = case node.style.dimensions {
+        Percent(width:, height:) -> {
+          let width = { context.parent_width * width } / 100
+          let height = { context.parent_height * height } / 100
 
-        let cx = container_top_left_x + 1
-        let cy = container_top_left_y + 1
+          #(width, height)
+        }
+      }
 
-        render_loop(layout, cw, ch, cx, cy, child)
-      })
+      // Check if this node should be placed to the left or below the parent
+      let #(node_top_left_x, node_top_left_y) = case node {
+        Row(..) -> #(
+          context.parent_top_left_x,
+          context.parent_top_left_y + { context.position_index * node_height },
+        )
+        Cell(..) -> #(
+          context.parent_top_left_x + { context.position_index * node_width },
+          context.parent_top_left_y,
+        )
+      }
 
-      logging.log("section: " <> string.inspect(from))
-      logging.log("container width: " <> float.to_string(container_width))
-      logging.log("container height: " <> float.to_string(container_height))
+      let parent = case node.heading {
+        None ->
+          plot.box(
+            buffer,
+            node_top_left_x,
+            node_top_left_y,
+            node_width,
+            node_height,
+          )
+        option.Some(heading) ->
+          plot.box_with_heading(
+            buffer,
+            node_top_left_x,
+            node_top_left_y,
+            node_width,
+            node_height,
+            heading,
+          )
+      }
 
-      let width =
-        container_width *. { int.to_float(node.width_percent) /. 100.0 }
-        |> float.floor
-        |> float.truncate
+      case node {
+        Cell(..) -> parent
+        Row(children:, ..) -> {
+          list.index_map(children, fn(child, i) { #(i, child) })
+          |> list.fold(parent, fn(acc_buffer, ic) {
+            let #(i, child) = ic
 
+            let #(child_width, child_height) = case node.style.dimensions {
+              Percent(width:, height:) -> {
+                let width = { { context.parent_width * width } / 100 } - margin
                 let height =
-        container_height *. { int.to_float(node.height_percent) /. 100.0 }
-        |> float.floor
-        |> float.truncate
+                  { { context.parent_height * height } / 100 } - margin
 
-      logging.log("width: " <> int.to_string(width))
-      logging.log("height: " <> int.to_string(height))
-
-      let cx = container_top_left_x
-      let cy = container_top_left_y
-      logging.log("cx: " <> int.to_string(cx))
-      logging.log("cy: " <> int.to_string(cy))
-
-      draw_box(cx, cy, width, height)
-      // Box heading
-      internal.print_at(node.content, cx, cy)
-    }
+                #(width, height)
               }
             }
 
-fn draw_box(x: Int, y: Int, width: Int, height: Int) -> Nil {
-  let box_chars = #("┌", "┐", "└", "┘", "─", "│")
-  let #(tl, tr, bl, br, h, v) = box_chars
-  internal.print_at(tl <> string.repeat(h, width - 2) <> tr, x, y)
+            let context =
+              RenderContext(
+                parent_width: child_width,
+                parent_height: child_height,
+                parent_top_left_x: context.parent_top_left_x + 1,
+                parent_top_left_y: context.parent_top_left_y + 1,
+                position_index: i,
+              )
 
-  list.range(1, height - 2)
-  |> list.each(fn(row) {
-    internal.print_at(v, x, y + row)
-    internal.print_at(v, x + width - 1, y + row)
+            render_loop(view, context, child, acc_buffer)
           })
-
-  internal.print_at(bl <> string.repeat(h, width - 2) <> br, x, y + height - 1)
+        }
+      }
+    }
+  }
 }

src/musicplayer/ui/layout_examples/layout_examples.gleam

@@ -0,0 +1,73 @@
+import gleam/option.{Some}
+
+import musicplayer/ui/internal
+import musicplayer/ui/layout.{Section}
+import musicplayer/ui/layout_examples/wait_for_input.{wait_for_input}
+import musicplayer/ui/style.{Percent, Style}
+
+pub fn main() {
+  let assert Ok(columns) = internal.io_get_columns()
+  let assert Ok(rows) = internal.io_get_rows()
+
+  two_rows_with_cells(columns, rows)
+  |> layout.render
+
+  wait_for_input()
+}
+
+/// Two rows:
+/// First row has two cells
+/// Second row has no cells
+fn two_rows_with_cells(columns: Int, rows: Int) -> layout.Layout {
+  let views = [
+    [
+      #(
+        Section("Row1"),
+        layout.Row(
+          heading: Some("row 1"),
+          style: Style(
+            dimensions: Percent(width: 100, height: 50),
+            border: Some(style.BorderSingle),
+          ),
+          children: [
+            Section("A"),
+            Section("B"),
+          ],
+        ),
+      ),
+      #(
+        Section("A"),
+        layout.Cell(
+          heading: Some("cell 1"),
+          style: Style(
+            dimensions: Percent(width: 50, height: 50),
+            border: Some(style.BorderSingle),
+          ),
+        ),
+      ),
+      #(
+        Section("B"),
+        layout.Cell(
+          heading: Some("cell 2"),
+          style: Style(
+            dimensions: Percent(width: 50, height: 50),
+            border: Some(style.BorderSingle),
+          ),
+        ),
+      ),
+      #(
+        Section("Row2"),
+        layout.Row(
+          heading: Some("row 2"),
+          style: Style(
+            dimensions: Percent(width: 50, height: 50),
+            border: Some(style.BorderSingle),
+          ),
+          children: [],
+        ),
+      ),
+    ],
+  ]
+
+  layout.new(columns, rows, views)
+}

src/musicplayer/ui/layout_examples/wait_for_input.gleam

@@ -0,0 +1,15 @@
+import gleam/erlang/process.{type Name}
+
+import musicplayer/input/input
+import musicplayer/input/key.{type Key}
+
+pub fn wait_for_input() {
+  let input_keys_name: Name(Key) = process.new_name("input_keys")
+  let assert Ok(_) = process.register(process.self(), input_keys_name)
+
+  input.new(input_keys_name)
+
+  process.new_selector()
+  |> process.select(process.named_subject(input_keys_name))
+  |> process.selector_receive_forever
+}

src/musicplayer/ui/plot.gleam

@@ -0,0 +1,85 @@
+import gleam/dict.{type Dict}
+import gleam/list
+import gleam/string
+
+pub type Buffer =
+  Dict(#(Int, Int), String)
+
+pub fn flush_buffer(buffer: Buffer, columns: Int, rows: Int) -> String {
+  list.range(1, rows)
+  |> list.map(fn(y) {
+    list.range(1, columns)
+    |> list.map(fn(x) {
+      case dict.get(buffer, #(x, y)) {
+        Ok(char) -> char
+        Error(_) -> " "
+      }
+    })
+    |> string.join("")
+  })
+  |> string.join("\r\n")
+}
+
+pub fn text(buffer: Buffer, text: String, x: Int, y: Int) -> Buffer {
+  text
+  |> string.to_graphemes
+  |> list.index_fold(buffer, fn(acc, char, i) {
+    dict.insert(acc, #(x + i, y), char)
+  })
+}
+
+pub fn box(buffer: Buffer, x: Int, y: Int, width: Int, height: Int) -> Buffer {
+  // TODO move box style to `layout.Style`
+  let box_chars = #("┌", "┐", "└", "┘", "─", "│")
+  let #(tl, tr, bl, br, hor, ver) = box_chars
+
+  case width < 2 || height < 2 {
+    True -> buffer
+    False -> {
+      buffer
+      |> dict.insert(#(x, y), tl)
+      |> dict.insert(#(x + width - 1, y), tr)
+      |> dict.insert(#(x, y + height - 1), bl)
+      |> dict.insert(#(x + width - 1, y + height - 1), br)
+      |> horizontal_line(x + 1, y, width - 2, hor)
+      |> horizontal_line(x + 1, y + height - 1, width - 2, hor)
+      |> vertical_line(x, y + 1, height - 2, ver)
+      |> vertical_line(x + width - 1, y + 1, height - 2, ver)
+    }
+  }
+}
+
+pub fn box_with_heading(
+  buffer: Buffer,
+  x: Int,
+  y: Int,
+  width: Int,
+  height: Int,
+  heading: String,
+) -> Buffer {
+  let heading_margin = 1
+  box(buffer, x, y, width, height)
+  |> text(heading, x + heading_margin, y)
+}
+
+fn horizontal_line(
+  buffer: Buffer,
+  x: Int,
+  y: Int,
+  len: Int,
+  char: String,
+) -> Buffer {
+  list.range(0, len - 1)
+  |> list.fold(buffer, fn(acc, i) { dict.insert(acc, #(x + i, y), char) })
+}
+
+fn vertical_line(
+  buffer: Buffer,
+  x: Int,
+  y: Int,
+  len: Int,
+  char: String,
+) -> Buffer {
+  list.range(0, len - 1)
+  |> list.fold(buffer, fn(acc, i) { dict.insert(acc, #(x, y + i), char) })
+}

src/musicplayer/ui/style.gleam

@@ -0,0 +1,34 @@
+import gleam/option.{type Option}
+
+pub type Dimension {
+  Percent(width: Int, height: Int)
+  // TODO add Flex that flows
+}
+
+pub type Border {
+  BorderNone
+  BorderSingle
+}
+
+pub type Style {
+  Style(dimensions: Dimension, border: Option(Border))
+}
+
+pub type BorderChars {
+  BorderChars(
+    top_left: String,
+    top_right: String,
+    bottom_left: String,
+    bottom_right: String,
+    horisontal: String,
+    vertical: String,
+  )
+}
+
+// https://en.wikipedia.org/wiki/Box-drawing_characters
+pub fn border_chars(border: Border) -> BorderChars {
+  case border {
+    BorderNone -> BorderChars("", "", "", "", "", "")
+    BorderSingle -> BorderChars("┌", "┐", "└", "┘", "─", "│")
+  }
+}

src/musicplayer/ui/ui.gleam

@@ -1,6 +1,7 @@
 import gleam/erlang/process.{type Subject}
 import gleam/int
 import gleam/list
+import gleam/option.{None, Some}
 import gleam/otp/actor
 import gleam/string
 
@@ -8,6 +9,7 @@ import musicplayer/logging/logging
 import musicplayer/ui/control.{type Control}
 import musicplayer/ui/internal
 import musicplayer/ui/layout.{type Layout}
+import musicplayer/ui/style
 
 pub type State(redraw, content) {
   State(redraw: Subject(Layout), layout: Layout)
@@ -17,7 +19,69 @@ pub fn new() -> Result(Subject(Control), String) {
   let redraw_name = process.new_name("redraw")
   let redraw: Subject(Layout) = process.named_subject(redraw_name)
 
-  let layout = layout.new()
+  let layout =
+    [
+      [
+        #(
+          layout.Header,
+          layout.Row(
+            heading: Some("Foo <1> | Bar (2)"),
+            style: style.Style(
+              dimensions: style.Percent(width: 100, height: 50),
+              border: Some(style.BorderSingle),
+            ),
+            children: [],
+          ),
+        ),
+        #(
+          layout.PlaybackTime,
+          layout.Row(
+            heading: None,
+            style: style.Style(
+              dimensions: style.Percent(width: 100, height: 50),
+              border: Some(style.BorderSingle),
+            ),
+            children: [],
+          ),
+        ),
+      ],
+      [
+        #(
+          layout.Header,
+          layout.Row(
+            heading: Some("Foo (1) | Bar <2>"),
+            style: style.Style(
+              dimensions: style.Percent(width: 100, height: 33),
+              border: Some(style.BorderSingle),
+            ),
+            children: [],
+          ),
+        ),
+        #(
+          layout.Search,
+          layout.Row(
+            heading: None,
+            style: style.Style(
+              dimensions: style.Percent(width: 100, height: 33),
+              border: Some(style.BorderSingle),
+            ),
+            children: [],
+          ),
+        ),
+        #(
+          layout.PlaybackTime,
+          layout.Row(
+            heading: None,
+            style: style.Style(
+              dimensions: style.Percent(width: 100, height: 33),
+              border: Some(style.BorderSingle),
+            ),
+            children: [],
+          ),
+        ),
+      ],
+    ]
+    |> layout.new(0, 0, _)
 
   case
     actor.new(State(redraw, layout))
@@ -51,27 +115,27 @@ fn handle_message(
   control: Control,
 ) -> actor.Next(State(redraw, layout), Control) {
   case control {
-    control.UpdateDimensions(width, height) -> {
-      let current_dimensions = #(state.layout.width, state.layout.height)
+    control.UpdateDimensions(columns, rows) -> {
+      let current_dimensions = #(state.layout.columns, state.layout.rows)
 
-      case #(width, height) == current_dimensions {
+      case #(columns, rows) == current_dimensions {
         True -> actor.continue(state)
         False -> {
-          [width, height]
+          [columns, rows]
           |> list.map(int.to_string)
           |> string.join(" ")
           |> string.append("ui - updating dimensions: ", _)
           |> logging.log
 
-          let layout = layout.update_dimensions(state.layout, width, height)
+          let layout = layout.update_dimensions(state.layout, columns, rows)
 
           process.send(state.redraw, layout)
           actor.continue(State(..state, layout:))
         }
       }
     }
-    control.UpdateState(section, content) -> {
-      let layout = layout.update_section(state.layout, section, content)
+    control.UpdateHeading(section, heading) -> {
+      let layout = layout.update_section_heading(state.layout, section, heading)
 
       actor.send(state.redraw, layout)
       actor.continue(State(..state, layout:))
@@ -82,6 +146,12 @@ fn handle_message(
       process.send(reply_to, Nil)
       actor.stop()
     }
+    control.SetView(view_idx) -> {
+      let layout = layout.update_current_view(state.layout, view_idx)
+
+      actor.send(state.redraw, layout)
+      actor.continue(State(..state, layout:))
+    }
   }
 }
 

test/musicplayer/control_test.gleam

@@ -1,7 +1,7 @@
 import gleam/list
 import gleeunit
 
-import musicplayer/control.{type Control}
+import musicplayer/control.{type Control, type Mode}
 import musicplayer/input/key.{type Key, Char}
 
 pub fn main() -> Nil {
@@ -9,16 +9,24 @@ pub fn main() -> Nil {
 }
 
 type TestCase {
-  TestCase(key: Key, expected: Result(Control, Nil))
+  TestCase(key: Key, mode: Mode, expected: Result(Control, Nil))
 }
 
 pub fn control_from_key_test() {
-  let test_cases = [
-    TestCase(Char(" "), Ok(control.TogglePlayPause)),
-    TestCase(Char("q"), Ok(control.Exit)),
+  let idle_tests = [
+    TestCase(Char(" "), control.Idle, Ok(control.TogglePlayPause)),
+    TestCase(Char("/"), control.Idle, Ok(control.Search("", True))),
+    TestCase(Char("q"), control.Idle, Ok(control.Exit)),
   ]
 
-  list.each(test_cases, fn(tc) {
-    assert tc.expected == control.from_key(tc.key)
+  let search_tests = [
+    TestCase(Char("a"), control.Searching(""), Ok(control.Search("a", True))),
+    TestCase(Char("b"), control.Searching("a"), Ok(control.Search("ab", True))),
+  ]
+
+  let test_cases = [idle_tests, search_tests]
+
+  list.each(list.flatten(test_cases), fn(tc) {
+    assert tc.expected == control.from_key(tc.key, tc.mode)
   })
 }

test/musicplayer/ui/layout_test.gleam

@@ -0,0 +1,130 @@
+import gleam/dict
+import gleam/io
+import gleam/option.{Some}
+import gleam/string
+import gleeunit
+import gleeunit/should
+
+import musicplayer/ui/layout.{RenderContext, Section}
+import musicplayer/ui/plot
+import musicplayer/ui/style.{Percent, Style}
+
+pub fn main() -> Nil {
+  gleeunit.main()
+}
+
+pub fn percent_layout_test() {
+  let views = [
+    [
+      #(
+        Section("Row1"),
+        layout.Row(
+          heading: Some("row 1"),
+          style: Style(
+            dimensions: Percent(width: 100, height: 50),
+            border: Some(style.BorderSingle),
+          ),
+          children: [
+            Section("A"),
+            Section("B"),
+          ],
+        ),
+      ),
+      #(
+        Section("A"),
+        layout.Cell(
+          heading: Some("cell 1"),
+          style: Style(
+            dimensions: Percent(width: 50, height: 100),
+            border: Some(style.BorderSingle),
+          ),
+        ),
+      ),
+      #(
+        Section("B"),
+        layout.Cell(
+          heading: Some("cell 2"),
+          style: Style(
+            dimensions: Percent(width: 50, height: 100),
+            border: Some(style.BorderSingle),
+          ),
+        ),
+      ),
+      #(
+        Section("Row2"),
+        layout.Row(
+          heading: Some("row 1"),
+          style: Style(
+            dimensions: Percent(width: 100, height: 50),
+            border: Some(style.BorderSingle),
+          ),
+          children: [],
+        ),
+      ),
+    ],
+  ]
+
+  let columns = 80
+  let rows = 20
+  let layout = layout.new(columns, rows, views)
+
+  let expected =
+    "
+┌──────────────────────────────────────────────────────────────────────────────┐
+│┌row 1───────────────────────────────────────────────────────────────────────┐│
+││┌cell 1──────────────────────────────┐┌cell 2──────────────────────────────┐││
+│││                                    ││                                    │││
+│││                                    ││                                    │││
+│││                                    ││                                    │││
+│││                                    ││                                    │││
+│││                                    ││                                    │││
+││└────────────────────────────────────┘└────────────────────────────────────┘││
+│└────────────────────────────────────────────────────────────────────────────┘│
+│┌row 1───────────────────────────────────────────────────────────────────────┐│
+││                                                                            ││
+││                                                                            ││
+││                                                                            ││
+││                                                                            ││
+││                                                                            ││
+││                                                                            ││
+││                                                                            ││
+│└────────────────────────────────────────────────────────────────────────────┘│
+└──────────────────────────────────────────────────────────────────────────────┘
+"
+    |> string.replace(each: "\n", with: "\r\n")
+    |> string.trim
+
+  let context =
+    RenderContext(
+      parent_width: layout.columns,
+      parent_height: layout.rows,
+      parent_top_left_x: 1,
+      parent_top_left_y: 1,
+      position_index: 0,
+    )
+
+  let assert Ok(view) = dict.get(layout.views, layout.current_view)
+
+  let flushed =
+    layout.render_loop(
+      view,
+      context,
+      Section(string.append("view_", string.inspect(layout.current_view))),
+      dict.new(),
+    )
+    |> plot.flush_buffer(layout.columns, layout.rows)
+
+  case flushed == expected {
+    True -> Nil
+    False -> {
+      io.println("Test failed")
+      io.println("Expected:")
+      io.println(string.trim(expected))
+
+      io.println("Got:")
+      io.println(flushed)
+
+      should.equal(flushed, expected)
+    }
+  }
+}