wip

And add the ability of other modules to listen to either
the final result (a `Key`) or tap into the input as it is read

gleam.toml

@@ -17,6 +17,7 @@ gleam_stdlib = ">= 0.44.0 and < 2.0.0"
 gleam_otp = ">= 1.2.0 and < 2.0.0"
 gleam_erlang = ">= 1.3.0 and < 2.0.0"
 simplifile = ">= 2.3.1 and < 3.0.0"
+gleam_json = ">= 3.1.0 and < 4.0.0"
 
 [dev-dependencies]
 gleeunit = ">= 1.0.0 and < 2.0.0"

manifest.toml

@@ -4,6 +4,7 @@
 packages = [
   { name = "filepath", version = "1.1.2", build_tools = ["gleam"], requirements = ["gleam_stdlib"], otp_app = "filepath", source = "hex", outer_checksum = "B06A9AF0BF10E51401D64B98E4B627F1D2E48C154967DA7AF4D0914780A6D40A" },
   { name = "gleam_erlang", version = "1.3.0", build_tools = ["gleam"], requirements = ["gleam_stdlib"], otp_app = "gleam_erlang", source = "hex", outer_checksum = "1124AD3AA21143E5AF0FC5CF3D9529F6DB8CA03E43A55711B60B6B7B3874375C" },
+  { name = "gleam_json", version = "3.1.0", build_tools = ["gleam"], requirements = ["gleam_stdlib"], otp_app = "gleam_json", source = "hex", outer_checksum = "44FDAA8847BE8FC48CA7A1C089706BD54BADCC4C45B237A992EDDF9F2CDB2836" },
   { name = "gleam_otp", version = "1.2.0", build_tools = ["gleam"], requirements = ["gleam_erlang", "gleam_stdlib"], otp_app = "gleam_otp", source = "hex", outer_checksum = "BA6A294E295E428EC1562DC1C11EA7530DCB981E8359134BEABC8493B7B2258E" },
   { name = "gleam_stdlib", version = "0.65.0", build_tools = ["gleam"], requirements = [], otp_app = "gleam_stdlib", source = "hex", outer_checksum = "7C69C71D8C493AE11A5184828A77110EB05A7786EBF8B25B36A72F879C3EE107" },
   { name = "gleeunit", version = "1.9.0", build_tools = ["gleam"], requirements = ["gleam_stdlib"], otp_app = "gleeunit", source = "hex", outer_checksum = "DA9553CE58B67924B3C631F96FE3370C49EB6D6DC6B384EC4862CC4AAA718F3C" },
@@ -12,6 +13,7 @@ packages = [
 
 [requirements]
 gleam_erlang = { version = ">= 1.3.0 and < 2.0.0" }
+gleam_json = { version = ">= 3.1.0 and < 4.0.0" }
 gleam_otp = { version = ">= 1.2.0 and < 2.0.0" }
 gleam_stdlib = { version = ">= 0.44.0 and < 2.0.0" }
 gleeunit = { version = ">= 1.0.0 and < 2.0.0" }

src/input/input.gleam

@@ -0,0 +1,50 @@
+import gleam/erlang/process.{type Name, type Subject}
+
+import input/key.{type Key}
+
+/// `new` accepts a list of listeners that are composed of two subjects;
+///   - one to get the final `Key` and
+///   - one to tap the input as it is read from i/o
+/// and
+///   - a subject name that is used to create a `Subject` that other processes
+///     know they can inject a `Key` into the input with
+pub fn new(
+  ui_input_keys_name: Name(Key),
+  ui_input_stream_name: Name(List(String)),
+  input_ui_inject_name: Name(Key),
+) -> Nil {
+  let _ =
+    process.spawn(fn() {
+      let ui_input_keys: Subject(Key) =
+        process.named_subject(ui_input_keys_name)
+      let ui_input_stream: Subject(List(String)) =
+        process.named_subject(ui_input_stream_name)
+
+      let input_ui_inject_input: Subject(Key) =
+        process.named_subject(input_ui_inject_name)
+      let assert Ok(_) = process.register(process.self(), input_ui_inject_name)
+
+      read_input(ui_input_keys, ui_input_stream, input_ui_inject_input)
+    })
+
+  echo "waiting for input"
+  key.start_raw_shell()
+
+  Nil
+}
+
+fn read_input(
+  ui_input_keys: Subject(Key),
+  ui_input_stream: Subject(List(String)),
+  input_ui_inject: Subject(Key),
+) -> Nil {
+  let buffer = case process.receive(input_ui_inject, 1) {
+    Ok(key.Continue(buffer)) -> buffer
+    Ok(_) | Error(_) -> []
+  }
+
+  key.read_input_until_key(buffer, ui_input_stream)
+  |> process.send(ui_input_keys, _)
+
+  read_input(ui_input_keys, ui_input_stream, input_ui_inject)
+}

src/input/internal.gleam

@@ -0,0 +1,15 @@
+import gleam/erlang/atom
+
+pub fn read_input() -> String {
+  io_get_chars("", 1)
+}
+
+pub type NotUsed
+
+// https://www.erlang.org/doc/apps/stdlib/shell.html#start_interactive/1
+@external(erlang, "shell", "start_interactive")
+pub fn shell_start_interactive(options: #(atom.Atom, atom.Atom)) -> NotUsed
+
+// https://www.erlang.org/doc/apps/stdlib/io.html#get_chars/2
+@external(erlang, "io", "get_chars")
+fn io_get_chars(prompt: String, count: Int) -> String

src/input/key.gleam

@@ -0,0 +1,79 @@
+import gleam/erlang/atom
+import gleam/erlang/process.{type Subject}
+import gleam/list
+import gleam/string
+
+import input/internal as internal_input
+
+pub type Key {
+  Char(String)
+
+  Input(String)
+  Left
+  Right
+  Up
+  Down
+
+  Continue(buffer: List(String))
+  Unknown
+}
+
+pub const esc = "\u{001B}"
+
+// control sequence introducer
+pub const csi = "["
+
+// input introducer
+pub const input_introducer = "::"
+
+pub fn from_list(l: List(String)) -> Key {
+  case l {
+    [e, c, "D"] if e == esc && c == csi -> Left
+    [e, c, "C"] if e == esc && c == csi -> Right
+    [e, c, "A"] if e == esc && c == csi -> Up
+    [e, c, "B"] if e == esc && c == csi -> Down
+
+    [e, c] if e == esc && c == csi -> Continue(l)
+
+    [ci] | [ci, _] if ci == input_introducer -> Continue(l)
+    [ii, cmd, tail] if ii == input_introducer -> {
+      case tail {
+        // Return
+        "\r" -> Input(cmd)
+        // Backspace
+        "\u{007F}" -> Continue([ii, string.drop_end(cmd, 1)])
+        _ -> Continue([ii, cmd <> tail])
+      }
+    }
+
+    [e] if e == esc -> Continue(l)
+    [char] -> Char(char)
+
+    [] -> Continue([])
+    _ -> Unknown
+  }
+}
+
+pub fn start_raw_shell() {
+  let no_shell = atom.create("noshell")
+  let raw = atom.create("raw")
+  internal_input.shell_start_interactive(#(no_shell, raw))
+}
+
+pub fn read_input_until_key(
+  l: List(String),
+  ui_input_stream: Subject(List(String)),
+) -> Key {
+  case
+    internal_input.read_input()
+    |> list.wrap
+    |> list.append(l, _)
+    |> from_list
+  {
+    Continue(l) -> {
+      process.send(ui_input_stream, l)
+      read_input_until_key(l, ui_input_stream)
+    }
+    k -> k
+  }
+}

src/mpv/control.gleam

@@ -0,0 +1,58 @@
+import gleam/json
+import gleam/result
+import gleam/string
+
+import mpv/internal as internal_control
+import tcp/reason.{type Reason}
+import tcp/tcp.{type Socket}
+
+pub type Control {
+  TogglePlayPause
+
+  Exit
+}
+
+pub type ControlError {
+  ControlError(details: String)
+}
+
+pub fn toggle_play_pause(socket: Socket) -> Result(Nil, ControlError) {
+  let command =
+    json.object([#("command", json.array(["cycle", "pause"], of: json.string))])
+
+  case send_command(socket, command) {
+    Error(r) -> Error(ControlError(reason.to_string(r)))
+    Ok(_) -> Ok(Nil)
+  }
+}
+
+// https://mpv.io/manual/master/#command-interface-playback-time
+pub type PlaybackTime {
+  PlaybackTime(data: Float)
+}
+
+pub fn get_playback_time(socket: Socket) -> Result(PlaybackTime, ControlError) {
+  let command =
+    json.object([
+      #(
+        "command",
+        json.array(["get_property_string", "playback-time"], of: json.string),
+      ),
+    ])
+
+  case send_command(socket, command) {
+    Error(r) -> Error(ControlError(reason.to_string(r)))
+    Ok(json_string) ->
+      case internal_control.parse_playback_time(json_string) {
+        Error(e) -> Error(ControlError(string.inspect(e)))
+        Ok(data) -> Ok(PlaybackTime(data))
+      }
+  }
+}
+
+fn send_command(socket: Socket, command: json.Json) -> Result(String, Reason) {
+  result.try(tcp.send(socket, json.to_string(command) <> "\n"), fn(_) {
+    let timeout_ms = 10_000
+    tcp.receive(socket, timeout_ms)
+  })
+}

src/mpv/internal.gleam

@@ -1,66 +1,25 @@
-import gleam/erlang/atom
-import gleam/list
+import gleam/dynamic/decode
+import gleam/float
+import gleam/json
+import gleam/string
 
-pub type Key {
-  Char(String)
+pub fn parse_playback_time(
+  json_string: String,
+) -> Result(Float, json.DecodeError) {
+  let decoder = {
+    let float_dececoder = fn(data_string) {
+      case float.parse(data_string) {
+        Error(_) -> decode.failure(0.0, "data")
+        Ok(float_value) -> decode.success(float_value)
+      }
+    }
+    use data <- decode.field(
+      "data",
+      decode.then(decode.string, float_dececoder),
+    )
 
-  Left
-  Right
-  Up
-  Down
-
-  Continue
-  Unknown
-}
-
-pub const esc = "\u{001B}"
-
-// control sequence introducer
-pub const csi = "["
-
-pub fn from_list(l: List(String)) -> Key {
-  case l {
-    [e, c, "D"] if e == esc && c == csi -> Left
-    [e, c, "C"] if e == esc && c == csi -> Right
-    [e, c, "A"] if e == esc && c == csi -> Up
-    [e, c, "B"] if e == esc && c == csi -> Down
-
-    [e, c] if e == esc && c == csi -> Continue
-
-    [e] if e == esc -> Continue
-    [char] -> Char(char)
-
-    [] -> Continue
-    _ -> Unknown
+    decode.success(data)
   }
+
+  json.parse(from: string.trim(json_string), using: decoder)
 }
-
-pub fn start_raw_shell() {
-  let no_shell = atom.create("noshell")
-  let raw = atom.create("raw")
-  shell_start_interactive(#(no_shell, raw))
-}
-
-// TODO map key to something like Control, to not leak `Continue` etc.
-pub fn read_input_until_key(l: List(String)) -> Key {
-  let l = read_input() |> list.wrap |> list.append(l, _)
-
-  case from_list(l) {
-    Continue -> read_input_until_key(l)
-    k -> k
-  }
-}
-
-fn read_input() -> String {
-  io_get_chars("", 1)
-}
-
-pub type NotUsed
-
-// https://www.erlang.org/doc/apps/stdlib/shell.html#start_interactive/1
-@external(erlang, "shell", "start_interactive")
-fn shell_start_interactive(options: #(atom.Atom, atom.Atom)) -> NotUsed
-
-// https://www.erlang.org/doc/apps/stdlib/io.html#get_line/1
-@external(erlang, "io", "get_chars")
-fn io_get_chars(prompt: String, count: Int) -> String

src/mpv/mpv.gleam

@@ -1,37 +1,48 @@
-import gleam/erlang/process.{type Subject}
+import gleam/erlang/process.{type Name, type Subject}
+import gleam/float
 import gleam/otp/actor
+import gleam/result
 import gleam/string
 
-import mpv/internal.{type Key, Char}
-import tcp/reason.{type Reason}
+import mpv/control as mpv_control
+import tcp/reason
 import tcp/tcp.{type Socket}
+import ui/control as ui_control
 
-pub type Message {
-  KeyPress(Key)
+type State(socket, mpv_ui, ui_mpv) {
+  State(
+    socket: Socket,
+    mpv_ui: Subject(ui_control.Control),
+    ui_mpv: Subject(mpv_control.Control),
+  )
 }
 
-type State(socket, exit) {
-  State(socket: Socket, exit: Subject(Nil))
-}
-
-pub fn new(exit: Subject(Nil)) -> Result(Nil, String) {
+pub fn new(
+  mpv_ui_name: Name(ui_control.Control),
+  ui_mpv_name: Name(mpv_control.Control),
+) -> Result(Nil, String) {
   // TODO start up mvp here, currently hi-jacking `naviterm`s socket
   let socket_path = "/tmp/naviterm_mpv"
 
+  let mpv_ui: Subject(ui_control.Control) = process.named_subject(mpv_ui_name)
+  let ui_mpv: Subject(mpv_control.Control) = process.named_subject(ui_mpv_name)
+
   case tcp.connect(socket_path) {
     Error(r) -> Error("Could not connect to mpv: " <> reason.to_string(r))
     Ok(socket) -> {
       case
-        actor.new(State(socket, exit))
+        actor.new(State(socket, mpv_ui, ui_mpv))
         |> actor.on_message(handle_message)
         |> actor.start
       {
         Error(start_error) ->
           Error("Could not start actor: " <> string.inspect(start_error))
-        Ok(actor.Started(data:, ..)) -> {
-          echo "waiting for input"
-          internal.start_raw_shell()
-          process.spawn(fn() { read_input(data) })
+        Ok(actor.Started(data: mpv, ..)) -> {
+          process.spawn(fn() {
+            let assert Ok(_) = process.register(process.self(), ui_mpv_name)
+            handle_ui_control(mpv, ui_mpv)
+          })
+
           Ok(Nil)
         }
       }
@@ -39,28 +50,42 @@ pub fn new(exit: Subject(Nil)) -> Result(Nil, String) {
   }
 }
 
-pub fn toggle_play_pause(socket: Socket) -> Result(Nil, Reason) {
-  tcp.send(socket, "{\"command\":[\"cycle\",\"pause\"]}\n")
-}
-
 fn handle_message(
-  state: State(socket, exit),
-  message: Message,
-) -> actor.Next(State(socket, exit), Message) {
-  case message {
-    KeyPress(Char("q")) -> {
-      process.send(state.exit, Nil)
-      actor.stop()
-    }
-    KeyPress(key) -> {
-      echo "key: " <> string.inspect(key)
+  state: State(socket, mpv_ui, ui_mpv),
+  control: mpv_control.Control,
+) -> actor.Next(State(socket, mpv_ui, ui_mpv), mpv_control.Control) {
+  case control {
+    mpv_control.TogglePlayPause -> {
+      echo "toggling play/pause"
+
+      let _ =
+        result.map_error(mpv_control.toggle_play_pause(state.socket), fn(err) {
+          echo "Could not toggle play/pause: " <> err.details
+        })
+
+      let _ =
+        result.map(mpv_control.get_playback_time(state.socket), fn(playback) {
+          echo "playback: " <> float.to_string(playback.data)
+        })
+
+      process.send(state.mpv_ui, ui_control.Ack)
+
       actor.continue(state)
     }
+    mpv_control.Exit -> {
+      // TODO close sockets
+      actor.stop()
+    }
   }
 }
 
-fn read_input(subject: Subject(Message)) -> Nil {
-  internal.read_input_until_key([]) |> KeyPress |> process.send(subject, _)
+fn handle_ui_control(
+  mpv: Subject(mpv_control.Control),
+  ui_mpv: Subject(mpv_control.Control),
+) {
+  let control = process.receive_forever(ui_mpv)
+  echo "handle_ui_control: " <> string.inspect(control)
+  process.send(mpv, control)
 
-  read_input(subject)
+  handle_ui_control(mpv, ui_mpv)
 }

src/musicplayer.gleam

@@ -1,8 +1,45 @@
-import gleam/erlang/process
+import gleam/erlang/process.{type Name}
+
+import input/input
+import input/key.{type Key}
+import mpv/control as mpv_control
 import mpv/mpv
+import ui/control as ui_control
+import ui/ui
 
 pub fn main() -> Nil {
   let exit = process.new_subject()
-  let assert Ok(_) = mpv.new(exit)
+
+  // `ui_input_keys` is owned by `ui`, this is where input sends keys
+  let ui_input_keys_name: Name(Key) = process.new_name("ui_input_keys")
+  // `ui_input_stream` is owned by `ui`, thi sis where input is streamed
+  let ui_input_stream_name: Name(List(String)) =
+    process.new_name("ui_input_stream")
+
+  // `inject_input` is created by name to allow the `input` process that
+  // owns `read_input` to be able to register and receive from it,
+  //  while the any other processes can use the name reference to
+  // inject input
+
+  // `input_ui_inject`  is owned by `input`, this is where `ui` injects `Key`
+  let input_ui_inject_name: Name(Key) = process.new_name("input_ui_inject_keys")
+
+  // `ui_mpv` is owned by `ui`, this is where `ui` asks `mpv` for things
+  let ui_mpv_name: Name(mpv_control.Control) = process.new_name("ui_mpv")
+  //   `mpv_ui` is owned by mpv and this is where mpv responds to ui
+  let mpv_ui_name: Name(ui_control.Control) = process.new_name("mpv_ui")
+
+  let assert Ok(_) =
+    ui.new(
+      ui_mpv_name,
+      mpv_ui_name,
+      ui_input_keys_name,
+      ui_input_stream_name,
+      exit,
+    )
+
+  let assert Ok(_) = mpv.new(mpv_ui_name, ui_mpv_name)
+  input.new(ui_input_keys_name, ui_input_stream_name, input_ui_inject_name)
+
   process.receive_forever(exit)
 }

src/tcp/reason.gleam

@@ -4,8 +4,6 @@ pub type Reason {
   /// from `send`
   Closed
 
-  Overflow
-
   /// Address already in use
   Eaddrinuse
   /// Cannot assign requested address
@@ -160,7 +158,6 @@ pub type Reason {
 
 pub fn to_string(reason: Reason) -> String {
   case reason {
-    Overflow -> "overflow"
     Closed -> "Connection closed (closed)"
     Eacces -> "Permission denied (eacces)"
     Eaddrinuse -> "Address already in use (eaddrinuse)"

src/ui/control.gleam

@@ -0,0 +1,24 @@
+import input/key.{type Key}
+
+pub type Control {
+  Ack
+
+  TogglePlayPause
+
+  Exit
+}
+
+pub fn from_key(key: Key) -> Result(Control, Nil) {
+  case key {
+    key.Char(char) -> char_control(char)
+    _ -> Error(Nil)
+  }
+}
+
+fn char_control(char: String) -> Result(Control, Nil) {
+  case char {
+    " " -> Ok(TogglePlayPause)
+    "q" -> Ok(Exit)
+    _ -> Error(Nil)
+  }
+}

src/ui/ui.gleam

@@ -0,0 +1,122 @@
+import gleam/erlang/process.{type Name, type Subject}
+import gleam/otp/actor
+import gleam/result
+import gleam/string
+
+import input/key.{type Key}
+import mpv/control as mpv_control
+import ui/control as ui_control
+
+pub type State(ui_mpv, mpv_ui, ui_input_keys, ui_input_stream, exit) {
+  State(
+    ui_mpv: Subject(mpv_control.Control),
+    mpv_ui: Subject(ui_control.Control),
+    ui_input_keys: Subject(Key),
+    ui_input_stream: Subject(List(String)),
+    exit: Subject(Nil),
+  )
+}
+
+pub fn new(
+  ui_mpv_name: Name(mpv_control.Control),
+  mpv_ui_name: Name(ui_control.Control),
+  ui_input_keys_name: Name(Key),
+  ui_input_stream_name: Name(List(String)),
+  exit: Subject(Nil),
+) -> Result(Nil, String) {
+  let ui_mpv: Subject(mpv_control.Control) = process.named_subject(ui_mpv_name)
+  let mpv_ui: Subject(ui_control.Control) = process.named_subject(mpv_ui_name)
+
+  let ui_input_keys: Subject(Key) = process.named_subject(ui_input_keys_name)
+  let ui_input_stream: Subject(List(String)) =
+    process.named_subject(ui_input_stream_name)
+
+  case
+    actor.new(State(ui_mpv, mpv_ui, ui_input_keys, ui_input_stream, exit))
+    |> actor.on_message(handle_message)
+    |> actor.start
+  {
+    Error(start_error) ->
+      Error("Could not start ui: " <> string.inspect(start_error))
+    Ok(actor.Started(data: ui, ..)) -> {
+      echo "ui started"
+
+      process.spawn(fn() {
+        let assert Ok(_) = process.register(process.self(), ui_input_keys_name)
+        handle_key(ui, ui_input_keys)
+      })
+
+      process.spawn(fn() {
+        let assert Ok(_) = process.register(process.self(), mpv_ui_name)
+        handle_mpv_control(ui, mpv_ui)
+      })
+
+      process.spawn(fn() {
+        let assert Ok(_) =
+          process.register(process.self(), ui_input_stream_name)
+        temp_input_stream(ui_input_stream)
+      })
+
+      Ok(Nil)
+    }
+  }
+}
+
+fn handle_message(
+  state: State(ui_mpv, mpv_ui, ui_input_keys, ui_input_stream, exit),
+  control: ui_control.Control,
+) -> actor.Next(
+  State(ui_mpv, mpv_ui, ui_input_keys, ui_input_stream, exit),
+  ui_control.Control,
+) {
+  case control {
+    ui_control.Ack -> {
+      echo "ack! use this to re-render?"
+      actor.continue(state)
+    }
+    ui_control.TogglePlayPause -> {
+      process.send(state.mpv_ui, ui_control.TogglePlayPause)
+      case process.receive(state.mpv_ui, 5000) {
+        Error(_) -> echo "mpv not responding: could not toggle pause :("
+        Ok(_) -> echo "toggled pause"
+      }
+
+      actor.continue(state)
+    }
+    ui_control.Exit -> {
+      // TODO call `mpv` to exit, wait for response
+      process.send(state.exit, Nil)
+      actor.stop()
+    }
+  }
+}
+
+/// `handle_key` listens to a subject onto which `input` will send messages with
+/// parsed `Key`s which will be mapped to `Control`s (if possible)
+fn handle_key(
+  ui: Subject(ui_control.Control),
+  ui_input_keys: Subject(Key),
+) -> Nil {
+  let _ =
+    process.receive_forever(ui_input_keys)
+    |> ui_control.from_key
+    |> result.map(process.send(ui, _))
+
+  handle_key(ui, ui_input_keys)
+}
+
+fn handle_mpv_control(
+  ui: Subject(ui_control.Control),
+  mpv_ui: Subject(ui_control.Control),
+) {
+  let control = process.receive_forever(mpv_ui)
+  process.send(ui, control)
+
+  handle_mpv_control(ui, mpv_ui)
+}
+
+fn temp_input_stream(ui_input_stream: Subject(List(String))) -> Nil {
+  let stream = process.receive_forever(ui_input_stream)
+  echo "input stream: " <> string.inspect(stream)
+  temp_input_stream(ui_input_stream)
+}

test/input/input_test.gleam

@@ -0,0 +1,42 @@
+import gleam/list
+import gleeunit
+
+import input/key.{type Key, Char, csi, esc, input_introducer as ii}
+
+pub fn main() -> Nil {
+  gleeunit.main()
+}
+
+type TestCase {
+  TestCase(input: List(String), expected: Key)
+}
+
+pub fn key_from_list_test() {
+  let base_tests = [TestCase([], key.Continue([]))]
+
+  let char_tests = [TestCase(["c"], Char("c"))]
+
+  let escape_tests = [
+    TestCase([esc, csi], key.Continue([esc, csi])),
+    TestCase([esc], key.Continue([esc])),
+
+    TestCase([esc, csi, "D"], key.Left),
+    TestCase([esc, csi, "C"], key.Right),
+    TestCase([esc, csi, "A"], key.Up),
+    TestCase([esc, csi, "B"], key.Down),
+  ]
+
+  let input_tests = [
+    TestCase([ii], key.Continue([ii])),
+    TestCase([ii, "a"], key.Continue([ii, "a"])),
+    TestCase([ii, "a", "b"], key.Continue([ii, "ab"])),
+    TestCase([ii, "ab", "\u{007F}"], key.Continue([ii, "a"])),
+    TestCase([ii, "ab", "\r"], key.Input("ab")),
+  ]
+
+  let test_cases = [base_tests, char_tests, escape_tests, input_tests]
+
+  list.each(list.flatten(test_cases), fn(tc) {
+    assert tc.expected == key.from_list(tc.input)
+  })
+}

test/mpv/control_test.gleam

@@ -0,0 +1,15 @@
+import gleeunit
+
+import mpv/internal as control_internal
+
+pub fn main() -> Nil {
+  gleeunit.main()
+}
+
+pub fn parse_playback_time_test() {
+  let json_string =
+    "{\"data\":\"123.456789\",\"request_id\":0,\"error\":\"success\"}\n"
+
+  let assert Ok(data) = control_internal.parse_playback_time(json_string)
+  assert data == 123.456789
+}

test/mpv/mpv_test.gleam

@@ -1,29 +0,0 @@
-import gleam/list
-import gleeunit
-
-import mpv/internal.{Char, csi, esc}
-
-pub fn main() -> Nil {
-  gleeunit.main()
-}
-
-type TestCase {
-  TestCase(input: List(String), expected: internal.Key)
-}
-
-pub fn mpv_key_from_list_test() {
-  let test_cases = [
-    TestCase(["c"], Char("c")),
-    TestCase([esc, csi, "D"], internal.Left),
-    TestCase([esc, csi, "C"], internal.Right),
-    TestCase([esc, csi, "A"], internal.Up),
-    TestCase([esc, csi, "B"], internal.Down),
-    TestCase([esc, csi], internal.Continue),
-    TestCase([esc], internal.Continue),
-    TestCase([], internal.Continue),
-  ]
-
-  list.each(test_cases, fn(tc) {
-    assert tc.expected == internal.from_list(tc.input)
-  })
-}

test/ui/ui_test.gleam

@@ -0,0 +1,24 @@
+import gleam/list
+import gleeunit
+
+import input/key.{type Key, Char}
+import ui/control.{type Control}
+
+pub fn main() -> Nil {
+  gleeunit.main()
+}
+
+type TestCase {
+  TestCase(key: Key, expected: Result(Control, Nil))
+}
+
+pub fn control_from_key_test() {
+  let test_cases = [
+    TestCase(Char(" "), Ok(control.TogglePlayPause)),
+    TestCase(Char("q"), Ok(control.Exit)),
+  ]
+
+  list.each(test_cases, fn(tc) {
+    assert tc.expected == control.from_key(tc.key)
+  })
+}