Add musicplayer module that wraps all logic

And add the ability of other modules to listen to either
the final result (a `Key`) or tap into the input as it is read

gleam.toml

@@ -14,6 +14,10 @@ version = "1.0.0"
 
 [dependencies]
 gleam_stdlib = ">= 0.44.0 and < 2.0.0"
+gleam_otp = ">= 1.2.0 and < 2.0.0"
+gleam_erlang = ">= 1.3.0 and < 2.0.0"
+simplifile = ">= 2.3.1 and < 3.0.0"
+gleam_json = ">= 3.1.0 and < 4.0.0"
 
 [dev-dependencies]
 gleeunit = ">= 1.0.0 and < 2.0.0"

manifest.toml

@@ -2,10 +2,19 @@
 # You typically do not need to edit this file
 
 packages = [
+  { name = "filepath", version = "1.1.2", build_tools = ["gleam"], requirements = ["gleam_stdlib"], otp_app = "filepath", source = "hex", outer_checksum = "B06A9AF0BF10E51401D64B98E4B627F1D2E48C154967DA7AF4D0914780A6D40A" },
+  { name = "gleam_erlang", version = "1.3.0", build_tools = ["gleam"], requirements = ["gleam_stdlib"], otp_app = "gleam_erlang", source = "hex", outer_checksum = "1124AD3AA21143E5AF0FC5CF3D9529F6DB8CA03E43A55711B60B6B7B3874375C" },
+  { name = "gleam_json", version = "3.1.0", build_tools = ["gleam"], requirements = ["gleam_stdlib"], otp_app = "gleam_json", source = "hex", outer_checksum = "44FDAA8847BE8FC48CA7A1C089706BD54BADCC4C45B237A992EDDF9F2CDB2836" },
+  { name = "gleam_otp", version = "1.2.0", build_tools = ["gleam"], requirements = ["gleam_erlang", "gleam_stdlib"], otp_app = "gleam_otp", source = "hex", outer_checksum = "BA6A294E295E428EC1562DC1C11EA7530DCB981E8359134BEABC8493B7B2258E" },
   { name = "gleam_stdlib", version = "0.65.0", build_tools = ["gleam"], requirements = [], otp_app = "gleam_stdlib", source = "hex", outer_checksum = "7C69C71D8C493AE11A5184828A77110EB05A7786EBF8B25B36A72F879C3EE107" },
   { name = "gleeunit", version = "1.9.0", build_tools = ["gleam"], requirements = ["gleam_stdlib"], otp_app = "gleeunit", source = "hex", outer_checksum = "DA9553CE58B67924B3C631F96FE3370C49EB6D6DC6B384EC4862CC4AAA718F3C" },
+  { name = "simplifile", version = "2.3.1", build_tools = ["gleam"], requirements = ["filepath", "gleam_stdlib"], otp_app = "simplifile", source = "hex", outer_checksum = "957E0E5B75927659F1D2A1B7B75D7B9BA96FAA8D0C53EA71C4AD9CD0C6B848F6" },
 ]
 
 [requirements]
+gleam_erlang = { version = ">= 1.3.0 and < 2.0.0" }
+gleam_json = { version = ">= 3.1.0 and < 4.0.0" }
+gleam_otp = { version = ">= 1.2.0 and < 2.0.0" }
 gleam_stdlib = { version = ">= 0.44.0 and < 2.0.0" }
 gleeunit = { version = ">= 1.0.0 and < 2.0.0" }
+simplifile = { version = ">= 2.3.1 and < 3.0.0" }

src/musicplayer.gleam

@@ -1,41 +1,32 @@
-import gleam/io
+import gleam/erlang/process.{type Name}
 
-import tcp/reason
+import musicplayer/input/input
-import tcp/tcp
+import musicplayer/input/key.{type Key}
+import musicplayer/mpv/mpv
+import musicplayer/musicplayer
 
 pub fn main() -> Nil {
-  let socket_path = "/tmp/musicplayer.sock"
+  let input_keys_name: Name(Key) = process.new_name("input_keys")
+  let input_stream_name: Name(List(String)) = process.new_name("input_stream")
 
-  case tcp.connect(socket_path) {
+  // `input_inject` is created by name to allow the `input` process that
-    Error(r) ->
+  // owns `read_input` to be able to register and receive from it,
-      io.println("Failed to connect to socket: " <> reason.to_string(r))
+  //  while the any other processes can use the name reference to
-    Ok(socket) -> {
+  // inject input
-      io.println("connected")
+  let input_inject_name: Name(Key) = process.new_name("input_inject_keys")
 
-      let messages = ["hello, \n", "world!\n"]
+  input.new(input_keys_name, input_stream_name, input_inject_name)
 
-      messages |> send_messages(socket, _)
+  let assert Ok(mpv) = mpv.new()
 
-      io.println("closing")
+  let exit = process.new_subject()
-      tcp.close(socket)
+  let assert Ok(_) =
-    }
+    musicplayer.new(
-  }
+      mpv,
-}
+      input_keys_name,
-
+      input_stream_name,
-fn send_messages(socket: tcp.Socket, messages: List(String)) -> Nil {
+      input_inject_name,
-  case messages {
+      exit,
-    [] -> Nil
+    )
-    [message, ..rest] -> {
+  process.receive_forever(exit)
-      send_message(socket, message)
-      send_messages(socket, rest)
-    }
-  }
-}
-
-fn send_message(socket: tcp.Socket, message: String) -> Nil {
-  case tcp.send(socket, message) {
-    Error(r) ->
-      io.println("Failed to send message to socket: " <> reason.to_string(r))
-    Ok(_) -> io.println("Sent message to socket")
-  }
 }

src/musicplayer/control.gleam

@@ -0,0 +1,25 @@
+import musicplayer/input/key.{type Key}
+
+pub type Control {
+  TogglePlayPause
+
+  Search
+
+  Exit
+}
+
+pub fn from_key(key: Key) -> Result(Control, Nil) {
+  case key {
+    key.Char(char) -> char_control(char)
+    _ -> Error(Nil)
+  }
+}
+
+fn char_control(char: String) -> Result(Control, Nil) {
+  case char {
+    " " -> Ok(TogglePlayPause)
+    "q" -> Ok(Exit)
+    "/" -> Ok(Search)
+    _ -> Error(Nil)
+  }
+}

src/musicplayer/input/input.gleam

@@ -0,0 +1,48 @@
+import gleam/erlang/process.{type Name, type Subject}
+
+import musicplayer/input/key.{type Key}
+
+// TODO REWRITE below
+
+/// `new` accepts a list of listeners that are composed of two subjects;
+///   - one to get the final `Key` and
+///   - one to tap the input as it is read from i/o
+/// and
+///   - a subject name that is used to create a `Subject` that other processes
+///     know they can inject a `Key` into the input with
+pub fn new(
+  input_keys_name: Name(Key),
+  input_stream_name: Name(List(String)),
+  input_inject_name: Name(Key),
+) -> Nil {
+  let _ =
+    process.spawn(fn() {
+      let input_keys = process.named_subject(input_keys_name)
+      let input_stream = process.named_subject(input_stream_name)
+      let input_inject = process.named_subject(input_inject_name)
+
+      let assert Ok(_) = process.register(process.self(), input_inject_name)
+
+      read_input(input_keys, input_stream, input_inject)
+    })
+
+  echo "waiting for input"
+  key.start_raw_shell()
+  Nil
+}
+
+fn read_input(
+  input_keys: Subject(Key),
+  input_stream: Subject(List(String)),
+  input_inject: Subject(Key),
+) -> Nil {
+  let buffer = case process.receive(input_inject, 1) {
+    Ok(key.Continue(buffer)) -> buffer
+    Ok(_) | Error(_) -> []
+  }
+
+  key.read_input_until_key(buffer, input_stream)
+  |> process.send(input_keys, _)
+
+  read_input(input_keys, input_stream, input_inject)
+}

src/musicplayer/input/internal.gleam

@@ -0,0 +1,15 @@
+import gleam/erlang/atom
+
+pub fn read_input() -> String {
+  io_get_chars("", 1)
+}
+
+pub type NotUsed
+
+// https://www.erlang.org/doc/apps/stdlib/shell.html#start_interactive/1
+@external(erlang, "shell", "start_interactive")
+pub fn shell_start_interactive(options: #(atom.Atom, atom.Atom)) -> NotUsed
+
+// https://www.erlang.org/doc/apps/stdlib/io.html#get_chars/2
+@external(erlang, "io", "get_chars")
+fn io_get_chars(prompt: String, count: Int) -> String

src/musicplayer/input/key.gleam

@@ -0,0 +1,79 @@
+import gleam/erlang/atom
+import gleam/erlang/process.{type Subject}
+import gleam/list
+import gleam/string
+
+import musicplayer/input/internal as internal_input
+
+pub type Key {
+  Char(String)
+
+  Input(String)
+  Left
+  Right
+  Up
+  Down
+
+  Continue(buffer: List(String))
+  Unknown
+}
+
+pub const esc = "\u{001B}"
+
+// control sequence introducer
+pub const csi = "["
+
+// input introducer
+pub const input_introducer = "::"
+
+pub fn from_list(l: List(String)) -> Key {
+  case l {
+    [e, c, "D"] if e == esc && c == csi -> Left
+    [e, c, "C"] if e == esc && c == csi -> Right
+    [e, c, "A"] if e == esc && c == csi -> Up
+    [e, c, "B"] if e == esc && c == csi -> Down
+
+    [e, c] if e == esc && c == csi -> Continue(l)
+
+    [ci] | [ci, _] if ci == input_introducer -> Continue(l)
+    [ii, cmd, tail] if ii == input_introducer -> {
+      case tail {
+        // Return
+        "\r" -> Input(cmd)
+        // Backspace
+        "\u{007F}" -> Continue([ii, string.drop_end(cmd, 1)])
+        _ -> Continue([ii, cmd <> tail])
+      }
+    }
+
+    [e] if e == esc -> Continue(l)
+    [char] -> Char(char)
+
+    [] -> Continue([])
+    _ -> Unknown
+  }
+}
+
+pub fn start_raw_shell() {
+  let no_shell = atom.create("noshell")
+  let raw = atom.create("raw")
+  internal_input.shell_start_interactive(#(no_shell, raw))
+}
+
+pub fn read_input_until_key(
+  l: List(String),
+  input_stream: Subject(List(String)),
+) -> Key {
+  case
+    internal_input.read_input()
+    |> list.wrap
+    |> list.append(l, _)
+    |> from_list
+  {
+    Continue(l) -> {
+      process.send(input_stream, l)
+      read_input_until_key(l, input_stream)
+    }
+    k -> k
+  }
+}

src/musicplayer/mpv/control.gleam

@@ -0,0 +1,61 @@
+import gleam/erlang/process.{type Subject}
+import gleam/json
+import gleam/result
+import gleam/string
+
+import musicplayer/mpv/internal as internal_control
+import musicplayer/tcp/reason.{type Reason}
+import musicplayer/tcp/tcp.{type Socket}
+
+pub type Control {
+  TogglePlayPause
+
+  GetPlaybackTime(reply_to: Subject(Result(PlaybackTime, ControlError)))
+
+  Exit(reply_to: Subject(Nil))
+}
+
+pub type ControlError {
+  ControlError(details: String)
+}
+
+pub fn toggle_play_pause(socket: Socket) -> Result(Nil, ControlError) {
+  let command =
+    json.object([#("command", json.array(["cycle", "pause"], of: json.string))])
+
+  case send_command(socket, command) {
+    Error(r) -> Error(ControlError(reason.to_string(r)))
+    Ok(_) -> Ok(Nil)
+  }
+}
+
+// https://mpv.io/manual/master/#command-interface-playback-time
+pub type PlaybackTime {
+  PlaybackTime(data: Float)
+}
+
+pub fn get_playback_time(socket: Socket) -> Result(PlaybackTime, ControlError) {
+  let command =
+    json.object([
+      #(
+        "command",
+        json.array(["get_property_string", "playback-time"], of: json.string),
+      ),
+    ])
+
+  case send_command(socket, command) {
+    Error(r) -> Error(ControlError(reason.to_string(r)))
+    Ok(json_string) ->
+      case internal_control.parse_playback_time(json_string) {
+        Error(e) -> Error(ControlError(string.inspect(e)))
+        Ok(data) -> Ok(PlaybackTime(data))
+      }
+  }
+}
+
+fn send_command(socket: Socket, command: json.Json) -> Result(String, Reason) {
+  result.try(tcp.send(socket, json.to_string(command) <> "\n"), fn(_) {
+    let timeout_ms = 10_000
+    tcp.receive(socket, timeout_ms)
+  })
+}

src/musicplayer/mpv/internal.gleam

@@ -0,0 +1,25 @@
+import gleam/dynamic/decode
+import gleam/float
+import gleam/json
+import gleam/string
+
+pub fn parse_playback_time(
+  json_string: String,
+) -> Result(Float, json.DecodeError) {
+  let decoder = {
+    let float_dececoder = fn(data_string) {
+      case float.parse(data_string) {
+        Error(_) -> decode.failure(0.0, "data")
+        Ok(float_value) -> decode.success(float_value)
+      }
+    }
+    use data <- decode.field(
+      "data",
+      decode.then(decode.string, float_dececoder),
+    )
+
+    decode.success(data)
+  }
+
+  json.parse(from: string.trim(json_string), using: decoder)
+}

src/musicplayer/mpv/mpv.gleam

@@ -0,0 +1,62 @@
+import gleam/erlang/process.{type Subject}
+import gleam/otp/actor
+import gleam/result
+import gleam/string
+
+import musicplayer/mpv/control
+import musicplayer/tcp/reason
+import musicplayer/tcp/tcp.{type Socket}
+
+type State(socket) {
+  State(socket: Socket)
+}
+
+pub fn new() -> Result(Subject(control.Control), String) {
+  // TODO start up mvp here, currently hi-jacking `naviterm`s socket
+  let socket_path = "/tmp/naviterm_mpv"
+
+  case tcp.connect(socket_path) {
+    Error(r) -> Error("Could not connect to mpv: " <> reason.to_string(r))
+    Ok(socket) -> {
+      case
+        actor.new(State(socket))
+        |> actor.on_message(handle_message)
+        |> actor.start
+      {
+        Error(start_error) ->
+          Error("Could not start actor: " <> string.inspect(start_error))
+        Ok(actor.Started(data: mpv, ..)) -> Ok(mpv)
+      }
+    }
+  }
+}
+
+fn handle_message(
+  state: State(socket),
+  control: control.Control,
+) -> actor.Next(State(socket), control.Control) {
+  case control {
+    control.TogglePlayPause -> {
+      echo "mpv: toggling play/pause"
+
+      let _ =
+        result.map_error(control.toggle_play_pause(state.socket), fn(err) {
+          echo "Could not toggle play/pause: " <> err.details
+        })
+
+      actor.continue(state)
+    }
+
+    control.GetPlaybackTime(reply_to) -> {
+      let res = control.get_playback_time(state.socket)
+      process.send(reply_to, res)
+      actor.continue(state)
+    }
+
+    control.Exit(reply_to) -> {
+      tcp.close(state.socket)
+      process.send(reply_to, Nil)
+      actor.stop()
+    }
+  }
+}

src/musicplayer/musicplayer.gleam

@@ -0,0 +1,106 @@
+import gleam/erlang/process.{type Name, type Subject}
+import gleam/float
+import gleam/otp/actor
+import gleam/result
+import gleam/string
+
+import musicplayer/control.{type Control}
+import musicplayer/input/key.{type Key}
+import musicplayer/mpv/control as mpv_control
+
+type State(mpv, input_inject, exit) {
+  State(
+    mpv: Subject(mpv_control.Control),
+    input_inject: Subject(Key),
+    exit: Subject(Nil),
+  )
+}
+
+pub fn new(
+  mpv: Subject(mpv_control.Control),
+  input_keys_name: Name(Key),
+  input_stream_name: Name(List(String)),
+  input_inject_name: Name(Key),
+  exit: Subject(Nil),
+) -> Result(Nil, String) {
+  let input_keys = process.named_subject(input_keys_name)
+  let input_stream = process.named_subject(input_stream_name)
+  let input_inject = process.named_subject(input_inject_name)
+
+  case
+    actor.new(State(mpv, input_inject, exit))
+    |> actor.on_message(handle_message)
+    |> actor.start
+  {
+    Error(start_error) ->
+      Error("Could not start actor: " <> string.inspect(start_error))
+    Ok(actor.Started(data: musicplayer, ..)) -> {
+      process.spawn(fn() {
+        let assert Ok(_) = process.register(process.self(), input_keys_name)
+        handle_key(musicplayer, input_keys)
+      })
+
+      process.spawn(fn() {
+        let assert Ok(_) = process.register(process.self(), input_stream_name)
+        temp_input_stream(input_stream)
+      })
+
+      Ok(Nil)
+    }
+  }
+}
+
+fn handle_message(
+  state: State(mpv, input_inject, exit),
+  control: Control,
+) -> actor.Next(State(mpv, input_inject, exit), Control) {
+  case control {
+    control.Search -> {
+      process.send(state.input_inject, key.Continue([key.input_introducer]))
+
+      actor.continue(state)
+    }
+    control.TogglePlayPause -> {
+      echo "toggling play/pause"
+
+      process.send(state.mpv, mpv_control.TogglePlayPause)
+
+      case
+        process.call(state.mpv, 1000, fn(reply_to) {
+          mpv_control.GetPlaybackTime(reply_to)
+        })
+      {
+        Error(err) -> echo "! could not get playbackTime: " <> err.details
+        Ok(mpv_control.PlaybackTime(data: playback_time)) ->
+          echo "playbacktime from mpv: " <> float.to_string(playback_time)
+      }
+
+      actor.continue(state)
+    }
+    control.Exit -> {
+      // Close socket to `mpv`
+      process.call(state.mpv, 1000, fn(reply_to) { mpv_control.Exit(reply_to) })
+
+      // End main process
+      process.send(state.exit, Nil)
+      actor.stop()
+    }
+  }
+}
+
+/// `handle_key` listens to a subject onto which `input` will send messages with
+/// parsed `Key`s which will be mapped to `Control`s (if possible)
+fn handle_key(musicplayer: Subject(Control), input_keys: Subject(Key)) -> Nil {
+  let _ =
+    process.receive_forever(input_keys)
+    |> control.from_key
+    |> result.map(process.send(musicplayer, _))
+
+  handle_key(musicplayer, input_keys)
+}
+
+fn temp_input_stream(input_stream: Subject(List(String))) -> Nil {
+  let stream = process.receive_forever(input_stream)
+  echo "input stream: " <> string.inspect(stream)
+  temp_input_stream(input_stream)
+}

src/musicplayer/tcp/tcp.gleam

@@ -0,0 +1,117 @@
+import gleam/bit_array
+import gleam/erlang/atom
+import gleam/result
+
+import musicplayer/tcp/reason.{type Reason}
+
+pub type Socket
+
+// https://www.erlang.org/doc/apps/kernel/inet#t:address_family/0
+// local socket
+type Local {
+  Local(socket_path: String)
+}
+
+type ModeValue {
+  Binary
+}
+
+type TCPOption {
+  Active(Bool)
+  Mode(ModeValue)
+  Reuseaddr(Bool)
+  Ifaddr(Local)
+  ExitOnClose(Bool)
+}
+
+pub fn listen(socket_path: String) -> Result(Socket, Reason) {
+  let options = [
+    Mode(Binary),
+    Active(False),
+    Reuseaddr(True),
+    Ifaddr(Local(socket_path)),
+    ExitOnClose(False),
+  ]
+  // port zero with `local` address
+  let port = 0
+
+  gen_tcp_listen(port, options)
+}
+
+pub fn accept(listen_socket: Socket) -> Result(Socket, Reason) {
+  gen_tcp_accept(listen_socket)
+}
+
+pub fn receive(socket: Socket, timeout: Int) -> Result(String, Reason) {
+  // Get all bytes
+  let length = 0
+
+  use bits <- result.try(gen_tcp_recv(socket, length, timeout))
+  case bits |> bit_array.to_string {
+    // TODO what error is best?
+    Error(_) -> Error(reason.Ebadmsg)
+    Ok(s) -> Ok(s)
+  }
+}
+
+pub fn connect(socket_path: String) -> Result(Socket, Reason) {
+  let options = [Mode(Binary), Active(False)]
+
+  // port zero with `local` address
+  let port = 0
+
+  // timeout in ms
+  let timeout = 1000
+
+  gen_tcp_connect(Local(socket_path), port, options, timeout)
+}
+
+pub fn send(socket: Socket, message: String) -> Result(Nil, Reason) {
+  gen_tcp_send(socket, bit_array.from_string(message))
+}
+
+pub fn close(socket: Socket) -> Nil {
+  gen_tcp_close(socket)
+}
+
+pub fn shutdown(socket: Socket) -> Result(Nil, Reason) {
+  let how = atom.create("write")
+  gen_tcp_shutdown(socket, how)
+}
+
+// https://www.erlang.org/doc/apps/kernel/gen_tcp.html#listen/2
+@external(erlang, "gen_tcp", "listen")
+fn gen_tcp_listen(port: Int, option: List(TCPOption)) -> Result(Socket, Reason)
+
+// https://www.erlang.org/doc/apps/kernel/gen_tcp.html#accept/1
+@external(erlang, "gen_tcp", "accept")
+fn gen_tcp_accept(listen_socket: Socket) -> Result(Socket, Reason)
+
+// https://www.erlang.org/doc/apps/kernel/gen_tcp.html#recv/3
+@external(erlang, "gen_tcp", "recv")
+fn gen_tcp_recv(
+  socket: Socket,
+  length: Int,
+  timeout: Int,
+) -> Result(BitArray, Reason)
+
+// https://www.erlang.org/doc/apps/kernel/gen_tcp.html#connect/4
+@external(erlang, "gen_tcp", "connect")
+fn gen_tcp_connect(
+  address: Local,
+  port: Int,
+  options: List(TCPOption),
+  timeout: Int,
+) -> Result(Socket, Reason)
+
+// https://www.erlang.org/doc/apps/kernel/gen_tcp.html#send/2
+@external(erlang, "tcp_ffi", "send")
+fn gen_tcp_send(socket: Socket, packet: BitArray) -> Result(Nil, Reason)
+
+// https://www.erlang.org/doc/apps/kernel/gen_tcp.html#close/1
+@external(erlang, "gen_tcp", "close")
+fn gen_tcp_close(socket: Socket) -> Nil
+
+// https://www.erlang.org/doc/apps/kernel/gen_tcp.html#shutdown/2
+@external(erlang, "tcp_ffi", "shutdown")
+fn gen_tcp_shutdown(socket: Socket, how: atom.Atom) -> Result(Nil, Reason)

src/musicplayer/tcp/tcp_ffi.erl

@@ -0,0 +1,14 @@
+-module(tcp_ffi).
+-export([send/2, shutdown/2]).
+
+send(Socket, Packet) ->
+  case gen_tcp:send(Socket, Packet) of
+    ok -> {ok, nil};
+    Res -> Res
+  end.
+
+shutdown(Socket, How) ->
+  case gen_tcp:shutdown(Socket, How) of
+    ok -> {ok, nil};
+    Res -> Res
+  end.

src/tcp/tcp.gleam

@@ -1,57 +0,0 @@
-import gleam/bytes_tree
-
-import tcp/reason.{type Reason}
-
-pub type Socket
-
-// https://www.erlang.org/doc/apps/kernel/inet#t:address_family/0
-// local socket
-type Local {
-  Local(socket_path: String)
-}
-
-type ModeValue {
-  Binary
-}
-
-type TCPOption {
-  Active(Bool)
-  Mode(ModeValue)
-}
-
-pub fn connect(socket_path: String) -> Result(Socket, Reason) {
-  let options = [Mode(Binary), Active(False)]
-
-  // timeout in ms
-  let timeout = 1000
-
-  gen_tcp_connect(Local(socket_path), 0, options, timeout)
-}
-
-pub fn send(socket: Socket, message: String) -> Result(Nil, Reason) {
-  gen_tcp_send(socket, bytes_tree.from_string(message))
-}
-
-pub fn close(socket: Socket) -> Nil {
-  gen_tcp_close(socket)
-}
-
-// https://www.erlang.org/doc/apps/kernel/gen_tcp.html#connect/4
-@external(erlang, "gen_tcp", "connect")
-fn gen_tcp_connect(
-  address: Local,
-  port: Int,
-  options: List(TCPOption),
-  timeout: Int,
-) -> Result(Socket, Reason)
-
-// https://www.erlang.org/doc/apps/kernel/gen_tcp.html#send/2
-@external(erlang, "tcp_ffi", "send")
-fn gen_tcp_send(
-  socket: Socket,
-  packet: bytes_tree.BytesTree,
-) -> Result(Nil, Reason)
-
-// https://www.erlang.org/doc/apps/kernel/gen_tcp.html#close/1
-@external(erlang, "gen_tcp", "close")
-fn gen_tcp_close(socket: Socket) -> Nil

src/tcp/tcp_ffi.erl

@@ -1,8 +0,0 @@
--module(tcp_ffi).
--export([send/2]).
-
-send(Socket, Packet) ->
-  case gen_tcp:send(Socket, Packet) of
-    ok -> {ok, nil};
-    Res -> Res
-  end.

test/echo_server.gleam

@@ -0,0 +1,81 @@
+import gleam/erlang/process.{type Subject}
+import gleam/io
+import gleam/otp/actor
+import gleam/result
+import gleam/string
+
+import musicplayer/tcp/reason.{type Reason}
+import musicplayer/tcp/tcp
+
+pub type Message {
+  Shutdown
+  ReadyToAccept(subject: Subject(Message), listen_socket: tcp.Socket)
+}
+
+pub fn new(socket_path: String) -> Result(tcp.Socket, String) {
+  let server = actor.new(Nil) |> actor.on_message(handle_message) |> actor.start
+
+  case tcp.listen(socket_path), server {
+    Error(r), _ -> Error(reason.to_string(r))
+    _, Error(start_error) ->
+      case start_error {
+        actor.InitExited(_) -> Error("InitExited")
+        actor.InitFailed(_) -> Error("InitFailed")
+        actor.InitTimeout -> Error("InitTimeout")
+      }
+    Ok(listen_socket), Ok(b) -> {
+      let subject = b.data
+      actor.send(subject, ReadyToAccept(subject, listen_socket))
+      Ok(listen_socket)
+    }
+  }
+}
+
+fn handle_message(_: Nil, message: Message) -> actor.Next(Nil, Message) {
+  case message {
+    Shutdown -> actor.stop()
+
+    ReadyToAccept(subject, listen_socket) -> {
+      case tcp.accept(listen_socket) {
+        Error(r) ->
+          actor.stop_abnormal(
+            "Could not accept connection :" <> reason.to_string(r),
+          )
+        Ok(socket) -> {
+          case receive_from_connection(socket) {
+            Error(r) ->
+              io.println_error(
+                "Failed to receive from connection :" <> reason.to_string(r),
+              )
+            Ok(_) -> Nil
+          }
+
+          actor.send(subject, ReadyToAccept(subject, listen_socket))
+          actor.continue(Nil)
+        }
+      }
+    }
+  }
+}
+
+fn receive_from_connection(socket: tcp.Socket) -> Result(Nil, Reason) {
+  result.try(receive_until_closed(socket, ""), fn(data) {
+    let _ = tcp.send(socket, data)
+    tcp.close(socket)
+    Ok(Nil)
+  })
+}
+
+fn receive_until_closed(
+  socket: tcp.Socket,
+  result: String,
+) -> Result(String, Reason) {
+  case tcp.receive(socket, 10_000) {
+    Error(reason.Closed) -> Ok(result)
+    Error(err) -> Error(err)
+    Ok(data) -> {
+      let result = data |> string.append(result, _)
+      receive_until_closed(socket, result)
+    }
+  }
+}

test/musicplayer/control_test.gleam

@@ -0,0 +1,24 @@
+import gleam/list
+import gleeunit
+
+import musicplayer/control.{type Control}
+import musicplayer/input/key.{type Key, Char}
+
+pub fn main() -> Nil {
+  gleeunit.main()
+}
+
+type TestCase {
+  TestCase(key: Key, expected: Result(Control, Nil))
+}
+
+pub fn control_from_key_test() {
+  let test_cases = [
+    TestCase(Char(" "), Ok(control.TogglePlayPause)),
+    TestCase(Char("q"), Ok(control.Exit)),
+  ]
+
+  list.each(test_cases, fn(tc) {
+    assert tc.expected == control.from_key(tc.key)
+  })
+}

test/musicplayer/input/input_test.gleam

@@ -0,0 +1,42 @@
+import gleam/list
+import gleeunit
+
+import musicplayer/input/key.{type Key, Char, csi, esc, input_introducer as ii}
+
+pub fn main() -> Nil {
+  gleeunit.main()
+}
+
+type TestCase {
+  TestCase(input: List(String), expected: Key)
+}
+
+pub fn key_from_list_test() {
+  let base_tests = [TestCase([], key.Continue([]))]
+
+  let char_tests = [TestCase(["c"], Char("c"))]
+
+  let escape_tests = [
+    TestCase([esc, csi], key.Continue([esc, csi])),
+    TestCase([esc], key.Continue([esc])),
+
+    TestCase([esc, csi, "D"], key.Left),
+    TestCase([esc, csi, "C"], key.Right),
+    TestCase([esc, csi, "A"], key.Up),
+    TestCase([esc, csi, "B"], key.Down),
+  ]
+
+  let input_tests = [
+    TestCase([ii], key.Continue([ii])),
+    TestCase([ii, "a"], key.Continue([ii, "a"])),
+    TestCase([ii, "a", "b"], key.Continue([ii, "ab"])),
+    TestCase([ii, "ab", "\u{007F}"], key.Continue([ii, "a"])),
+    TestCase([ii, "ab", "\r"], key.Input("ab")),
+  ]
+
+  let test_cases = [base_tests, char_tests, escape_tests, input_tests]
+
+  list.each(list.flatten(test_cases), fn(tc) {
+    assert tc.expected == key.from_list(tc.input)
+  })
+}

test/musicplayer/mpv/mpv_test.gleam

@@ -0,0 +1,15 @@
+import gleeunit
+
+import musicplayer/mpv/internal as control_internal
+
+pub fn main() -> Nil {
+  gleeunit.main()
+}
+
+pub fn parse_playback_time_test() {
+  let json_string =
+    "{\"data\":\"123.456789\",\"request_id\":0,\"error\":\"success\"}\n"
+
+  let assert Ok(data) = control_internal.parse_playback_time(json_string)
+  assert data == 123.456789
+}

test/musicplayer/tcp/tcp_test.gleam

@@ -0,0 +1,30 @@
+import gleam/list
+import gleeunit
+import simplifile
+
+import echo_server
+import musicplayer/tcp/tcp
+
+pub fn main() -> Nil {
+  gleeunit.main()
+}
+
+pub fn tcp_send_shutdown_receive_test() {
+  let socket_path = "/tmp/musicplayer-test.sock"
+
+  let assert Ok(_) = echo_server.new(socket_path)
+  let assert Ok(socket) = tcp.connect(socket_path)
+
+  let messages = ["hello, ", "world!\n"]
+  list.each(messages, fn(message) {
+    let assert Ok(_) = tcp.send(socket, message)
+  })
+
+  let assert Ok(_) = tcp.shutdown(socket)
+
+  let timeout_ms = 100
+  assert Ok("hello, world!\n") == tcp.receive(socket, timeout_ms)
+
+  // TODO find better way to always do cleanup
+  simplifile.delete(socket_path)
+}

test/musicplayer_test.gleam

@@ -3,11 +3,3 @@ import gleeunit
 pub fn main() -> Nil {
   gleeunit.main()
 }
-
-// gleeunit test functions end in `_test`
-pub fn hello_world_test() {
-  let name = "Joe"
-  let greeting = "Hello, " <> name <> "!"
-
-  assert greeting == "Hello, Joe!"
-}