Move all code into musicplayer module

And add the ability of other modules to listen to either
the final result (a `Key`) or tap into the input as it is read

gleam.toml

@@ -14,6 +14,10 @@ version = "1.0.0"
 
 [dependencies]
 gleam_stdlib = ">= 0.44.0 and < 2.0.0"
+gleam_otp = ">= 1.2.0 and < 2.0.0"
+gleam_erlang = ">= 1.3.0 and < 2.0.0"
+simplifile = ">= 2.3.1 and < 3.0.0"
+gleam_json = ">= 3.1.0 and < 4.0.0"
 
 [dev-dependencies]
 gleeunit = ">= 1.0.0 and < 2.0.0"

manifest.toml

@@ -2,10 +2,19 @@
 # You typically do not need to edit this file
 
 packages = [
+  { name = "filepath", version = "1.1.2", build_tools = ["gleam"], requirements = ["gleam_stdlib"], otp_app = "filepath", source = "hex", outer_checksum = "B06A9AF0BF10E51401D64B98E4B627F1D2E48C154967DA7AF4D0914780A6D40A" },
+  { name = "gleam_erlang", version = "1.3.0", build_tools = ["gleam"], requirements = ["gleam_stdlib"], otp_app = "gleam_erlang", source = "hex", outer_checksum = "1124AD3AA21143E5AF0FC5CF3D9529F6DB8CA03E43A55711B60B6B7B3874375C" },
+  { name = "gleam_json", version = "3.1.0", build_tools = ["gleam"], requirements = ["gleam_stdlib"], otp_app = "gleam_json", source = "hex", outer_checksum = "44FDAA8847BE8FC48CA7A1C089706BD54BADCC4C45B237A992EDDF9F2CDB2836" },
+  { name = "gleam_otp", version = "1.2.0", build_tools = ["gleam"], requirements = ["gleam_erlang", "gleam_stdlib"], otp_app = "gleam_otp", source = "hex", outer_checksum = "BA6A294E295E428EC1562DC1C11EA7530DCB981E8359134BEABC8493B7B2258E" },
   { name = "gleam_stdlib", version = "0.65.0", build_tools = ["gleam"], requirements = [], otp_app = "gleam_stdlib", source = "hex", outer_checksum = "7C69C71D8C493AE11A5184828A77110EB05A7786EBF8B25B36A72F879C3EE107" },
   { name = "gleeunit", version = "1.9.0", build_tools = ["gleam"], requirements = ["gleam_stdlib"], otp_app = "gleeunit", source = "hex", outer_checksum = "DA9553CE58B67924B3C631F96FE3370C49EB6D6DC6B384EC4862CC4AAA718F3C" },
+  { name = "simplifile", version = "2.3.1", build_tools = ["gleam"], requirements = ["filepath", "gleam_stdlib"], otp_app = "simplifile", source = "hex", outer_checksum = "957E0E5B75927659F1D2A1B7B75D7B9BA96FAA8D0C53EA71C4AD9CD0C6B848F6" },
 ]
 
 [requirements]
+gleam_erlang = { version = ">= 1.3.0 and < 2.0.0" }
+gleam_json = { version = ">= 3.1.0 and < 4.0.0" }
+gleam_otp = { version = ">= 1.2.0 and < 2.0.0" }
 gleam_stdlib = { version = ">= 0.44.0 and < 2.0.0" }
 gleeunit = { version = ">= 1.0.0 and < 2.0.0" }
+simplifile = { version = ">= 2.3.1 and < 3.0.0" }

src/ipc.gleam

@@ -1,59 +0,0 @@
-import gleam/bytes_tree
-
-pub type Socket
-
-// https://www.erlang.org/doc/apps/kernel/inet#t:address_family/0
-// local socket
-type Local {
-  Local(socket_path: String)
-}
-
-type ModeValue {
-  Binary
-}
-
-type IPCOption {
-  Active(Bool)
-  Mode(ModeValue)
-}
-
-pub type IPCError {
-  IPCError(reason: String)
-}
-
-pub fn connect(socket_path: String) -> Result(Socket, IPCError) {
-  let options = [Mode(Binary), Active(False)]
-
-  // timeout in ms
-  let timeout = 1000
-
-  gen_tcp_connect(Local(socket_path), 0, options, timeout)
-}
-
-pub fn send(socket: Socket, message: String) -> Result(Nil, IPCError) {
-  gen_tcp_send(socket, bytes_tree.from_string(message))
-}
-
-pub fn close(socket: Socket) -> Nil {
-  gen_tcp_close(socket)
-}
-
-// https://www.erlang.org/doc/apps/kernel/gen_tcp.html#connect/4
-@external(erlang, "gen_tcp", "connect")
-fn gen_tcp_connect(
-  address: Local,
-  port: Int,
-  options: List(IPCOption),
-  timeout: Int,
-) -> Result(Socket, IPCError)
-
-// https://www.erlang.org/doc/apps/kernel/gen_tcp.html#send/2
-@external(erlang, "ipc_ffi", "send")
-fn gen_tcp_send(
-  socket: Socket,
-  packet: bytes_tree.BytesTree,
-) -> Result(Nil, IPCError)
-
-// https://www.erlang.org/doc/apps/kernel/gen_tcp.html#close/1
-@external(erlang, "gen_tcp", "close")
-fn gen_tcp_close(socket: Socket) -> Nil

src/ipc_ffi.erl

@@ -1,8 +0,0 @@
--module(ipc_ffi).
--export([send/2]).
-
-send(Socket, Packet) ->
-  case gen_tcp:send(Socket, Packet) of
-    ok -> {ok, nil};
-    Res -> Res
-  end.

src/musicplayer.gleam

@@ -1,37 +1,22 @@
-import gleam/io
-import ipc
+import gleam/erlang/process.{type Name}
+
+import musicplayer/input/input.{type Listener}
+import musicplayer/input/key.{type Key}
+import musicplayer/mpv/mpv
 
 pub fn main() -> Nil {
-  let socket_path = "/tmp/musicplayer.sock"
+  let exit = process.new_subject()
 
-  case ipc.connect(socket_path) {
-    Error(err) -> io.println("Failed to connect to socket: " <> err.reason)
-    Ok(socket) -> {
-      io.println("connected")
+  // `inject_input` is created by name to allow the `input` process that
+  // owns `read_input` to be able to register and receive from it,
+  //  while the any other processes can use the name reference to
+  // inject input
+  let inject_input_name: Name(Key) = process.new_name("inject_input")
 
-      let messages = ["hello, \n", "world!\n"]
+  let assert Ok(mpv_listener) = mpv.new(exit)
 
-      messages |> send_messages(socket, _)
+  let listeners: List(Listener) = [mpv_listener]
 
-      io.println("closing")
-      ipc.close(socket)
-    }
-  }
-}
-
-fn send_messages(socket: ipc.Socket, messages: List(String)) -> Nil {
-  case messages {
-    [] -> Nil
-    [message, ..rest] -> {
-      send_message(socket, message)
-      send_messages(socket, rest)
-    }
-  }
-}
-
-fn send_message(socket: ipc.Socket, message: String) -> Nil {
-  case ipc.send(socket, message) {
-    Error(err) -> io.println("Failed to send message to socket: " <> err.reason)
-    Ok(_) -> io.println("Sent message to socket")
-  }
+  input.new(listeners, inject_input_name)
+  process.receive_forever(exit)
 }

src/musicplayer/input/input.gleam

@@ -0,0 +1,59 @@
+import gleam/erlang/process.{type Name, type Subject}
+import gleam/list
+import gleam/option.{type Option, None, Some}
+
+import musicplayer/input/key.{type Key}
+
+pub type Listener {
+  InputListener(final: Subject(Key), tap: Option(Subject(List(String))))
+}
+
+/// `new` accepts a list of listeners that are composed of two subjects;
+///   - one to get the final `Key` and
+///   - one to tap the input as it is read from i/o
+/// and
+///   - a subject name that is used to create a `Subject` that other processes
+///     know they can inject a `Key` into the input with
+pub fn new(listeners: List(Listener), inject_input_name: Name(Key)) -> Nil {
+  let _ =
+    process.spawn(fn() {
+      let inject_input: Subject(Key) = process.named_subject(inject_input_name)
+      let assert Ok(_) = process.register(process.self(), inject_input_name)
+
+      // Extract all finals and taps (that are defined)
+      let #(finals, taps) =
+        list.fold(listeners, #([], []), fn(acc, listener) {
+          let #(finals, taps) = acc
+
+          let finals = [listener.final, ..finals]
+
+          let taps = case listener.tap {
+            Some(t) -> [t, ..taps]
+            None -> taps
+          }
+
+          #(finals, taps)
+        })
+
+      read_input(finals, taps, inject_input)
+    })
+
+  Nil
+}
+
+fn read_input(
+  finals: List(Subject(Key)),
+  taps: List(Subject(List(String))),
+  inject_input: Subject(Key),
+) -> Nil {
+  let buffer = case process.receive(inject_input, 1) {
+    Ok(key.Continue(buffer)) -> buffer
+    Ok(_) | Error(_) -> []
+  }
+
+  let _ =
+    key.read_input_until_key(buffer, taps)
+    |> fn(k) { list.each(finals, process.send(_, k)) }
+
+  read_input(finals, taps, inject_input)
+}

src/musicplayer/input/internal.gleam

@@ -0,0 +1,15 @@
+import gleam/erlang/atom
+
+pub fn read_input() -> String {
+  io_get_chars("", 1)
+}
+
+pub type NotUsed
+
+// https://www.erlang.org/doc/apps/stdlib/shell.html#start_interactive/1
+@external(erlang, "shell", "start_interactive")
+pub fn shell_start_interactive(options: #(atom.Atom, atom.Atom)) -> NotUsed
+
+// https://www.erlang.org/doc/apps/stdlib/io.html#get_chars/2
+@external(erlang, "io", "get_chars")
+fn io_get_chars(prompt: String, count: Int) -> String

src/musicplayer/input/key.gleam

@@ -0,0 +1,79 @@
+import gleam/erlang/atom
+import gleam/erlang/process.{type Subject}
+import gleam/list
+import gleam/string
+
+import musicplayer/input/internal as internal_input
+
+pub type Key {
+  Char(String)
+
+  Input(String)
+  Left
+  Right
+  Up
+  Down
+
+  Continue(buffer: List(String))
+  Unknown
+}
+
+pub const esc = "\u{001B}"
+
+// control sequence introducer
+pub const csi = "["
+
+// input introducer
+pub const input_introducer = "::"
+
+pub fn from_list(l: List(String)) -> Key {
+  case l {
+    [e, c, "D"] if e == esc && c == csi -> Left
+    [e, c, "C"] if e == esc && c == csi -> Right
+    [e, c, "A"] if e == esc && c == csi -> Up
+    [e, c, "B"] if e == esc && c == csi -> Down
+
+    [e, c] if e == esc && c == csi -> Continue(l)
+
+    [ci] | [ci, _] if ci == input_introducer -> Continue(l)
+    [ii, cmd, tail] if ii == input_introducer -> {
+      case tail {
+        // Return
+        "\r" -> Input(cmd)
+        // Backspace
+        "\u{007F}" -> Continue([ii, string.drop_end(cmd, 1)])
+        _ -> Continue([ii, cmd <> tail])
+      }
+    }
+
+    [e] if e == esc -> Continue(l)
+    [char] -> Char(char)
+
+    [] -> Continue([])
+    _ -> Unknown
+  }
+}
+
+pub fn start_raw_shell() {
+  let no_shell = atom.create("noshell")
+  let raw = atom.create("raw")
+  internal_input.shell_start_interactive(#(no_shell, raw))
+}
+
+pub fn read_input_until_key(
+  l: List(String),
+  taps: List(Subject(List(String))),
+) -> Key {
+  case
+    internal_input.read_input()
+    |> list.wrap
+    |> list.append(l, _)
+    |> from_list
+  {
+    Continue(l) -> {
+      list.each(taps, process.send(_, l))
+      read_input_until_key(l, taps)
+    }
+    k -> k
+  }
+}

src/musicplayer/mpv/control.gleam

@@ -0,0 +1,74 @@
+import gleam/json
+import gleam/result
+import gleam/string
+
+import musicplayer/input/key.{type Key}
+import musicplayer/mpv/internal as internal_control
+import musicplayer/tcp/reason.{type Reason}
+import musicplayer/tcp/tcp.{type Socket}
+
+pub type Control {
+  TogglePlayPause
+
+  Exit
+}
+
+pub type ControlError {
+  ControlError(details: String)
+}
+
+pub fn from_key(key: Key) -> Result(Control, Nil) {
+  case key {
+    key.Char(char) -> char_control(char)
+    _ -> Error(Nil)
+  }
+}
+
+fn char_control(char: String) -> Result(Control, Nil) {
+  case char {
+    " " -> Ok(TogglePlayPause)
+    "q" -> Ok(Exit)
+    _ -> Error(Nil)
+  }
+}
+
+pub fn toggle_play_pause(socket: Socket) -> Result(Nil, ControlError) {
+  let command =
+    json.object([#("command", json.array(["cycle", "pause"], of: json.string))])
+
+  case send_command(socket, command) {
+    Error(r) -> Error(ControlError(reason.to_string(r)))
+    Ok(_) -> Ok(Nil)
+  }
+}
+
+// https://mpv.io/manual/master/#command-interface-playback-time
+pub type PlaybackTime {
+  PlaybackTime(data: Float)
+}
+
+pub fn get_playback_time(socket: Socket) -> Result(PlaybackTime, ControlError) {
+  let command =
+    json.object([
+      #(
+        "command",
+        json.array(["get_property_string", "playback-time"], of: json.string),
+      ),
+    ])
+
+  case send_command(socket, command) {
+    Error(r) -> Error(ControlError(reason.to_string(r)))
+    Ok(json_string) ->
+      case internal_control.parse_playback_time(json_string) {
+        Error(e) -> Error(ControlError(string.inspect(e)))
+        Ok(data) -> Ok(PlaybackTime(data))
+      }
+  }
+}
+
+fn send_command(socket: Socket, command: json.Json) -> Result(String, Reason) {
+  result.try(tcp.send(socket, json.to_string(command) <> "\n"), fn(_) {
+    let timeout_ms = 10_000
+    tcp.receive(socket, timeout_ms)
+  })
+}

src/musicplayer/mpv/internal.gleam

@@ -0,0 +1,25 @@
+import gleam/dynamic/decode
+import gleam/float
+import gleam/json
+import gleam/string
+
+pub fn parse_playback_time(
+  json_string: String,
+) -> Result(Float, json.DecodeError) {
+  let decoder = {
+    let float_dececoder = fn(data_string) {
+      case float.parse(data_string) {
+        Error(_) -> decode.failure(0.0, "data")
+        Ok(float_value) -> decode.success(float_value)
+      }
+    }
+    use data <- decode.field(
+      "data",
+      decode.then(decode.string, float_dececoder),
+    )
+
+    decode.success(data)
+  }
+
+  json.parse(from: string.trim(json_string), using: decoder)
+}

src/musicplayer/mpv/mpv.gleam

@@ -0,0 +1,89 @@
+import gleam/erlang/process.{type Subject}
+import gleam/float
+import gleam/option.{None}
+import gleam/otp/actor
+import gleam/result
+import gleam/string
+
+import musicplayer/input/input.{type Listener, InputListener}
+import musicplayer/input/key.{type Key}
+import musicplayer/mpv/control.{type Control}
+import musicplayer/tcp/reason
+import musicplayer/tcp/tcp.{type Socket}
+
+type State(socket, exit) {
+  State(socket: Socket, exit: Subject(Nil))
+}
+
+pub fn new(exit: Subject(Nil)) -> Result(Listener, String) {
+  // TODO start up mvp here, currently hi-jacking `naviterm`s socket
+  let socket_path = "/tmp/naviterm_mpv"
+
+  case tcp.connect(socket_path) {
+    Error(r) -> Error("Could not connect to mpv: " <> reason.to_string(r))
+    Ok(socket) -> {
+      let final_input_name = process.new_name("mpv_final_input")
+      let final_input: Subject(Key) = process.named_subject(final_input_name)
+
+      case
+        actor.new(State(socket, exit))
+        |> actor.on_message(handle_message)
+        |> actor.start
+      {
+        Error(start_error) ->
+          Error("Could not start actor: " <> string.inspect(start_error))
+        Ok(actor.Started(data:, ..)) -> {
+          echo "waiting for input"
+          key.start_raw_shell()
+
+          process.spawn(fn() {
+            let assert Ok(_) =
+              process.register(process.self(), final_input_name)
+
+            handle_key(final_input, data)
+          })
+
+          Ok(InputListener(final: final_input, tap: None))
+        }
+      }
+    }
+  }
+}
+
+fn handle_message(
+  state: State(socket, exit),
+  control: Control,
+) -> actor.Next(State(socket, exit), Control) {
+  case control {
+    control.TogglePlayPause -> {
+      echo "toggling play/pause"
+
+      let _ =
+        result.map_error(control.toggle_play_pause(state.socket), fn(err) {
+          echo "Could not toggle play/pause: " <> err.details
+        })
+
+      let _ =
+        result.map(control.get_playback_time(state.socket), fn(playback) {
+          echo "playback: " <> float.to_string(playback.data)
+        })
+
+      actor.continue(state)
+    }
+    control.Exit -> {
+      process.send(state.exit, Nil)
+      actor.stop()
+    }
+  }
+}
+
+/// `handle_key` listens to a subject onto which `input` will send messages with
+/// parsed `Key`s which will be mapped to `Control`s (if possible)
+fn handle_key(final_input: Subject(Key), subject: Subject(Control)) -> Nil {
+  let _ =
+    process.receive_forever(final_input)
+    |> control.from_key
+    |> result.map(process.send(subject, _))
+
+  handle_key(final_input, subject)
+}

src/musicplayer/tcp/reason.gleam

@@ -0,0 +1,240 @@
+pub type Reason {
+  /// from `connect`
+  Timeout
+  /// from `send`
+  Closed
+
+  /// Address already in use
+  Eaddrinuse
+  /// Cannot assign requested address
+  Eaddrnotavail
+  /// Address family not supported by protocol family
+  Eafnosupport
+  /// Operation already in progress
+  Ealready
+  /// Software caused connection abort
+  Econnaborted
+  /// Connection refused
+  Econnrefused
+  /// Connection reset by peer
+  Econnreset
+  /// Destination address required
+  Edestaddrreq
+  /// Host is down
+  Ehostdown
+  /// Host is unreachable
+  Ehostunreach
+  /// Operation now in progress
+  Einprogress
+  /// Socket is already connected
+  Eisconn
+  /// Message too long
+  Emsgsize
+  /// Network is down
+  Enetdown
+  /// Network is unreachable
+  Enetunreach
+  /// Package not installed
+  Enopkg
+  /// Bad protocol option
+  Enoprotoopt
+  /// Socket is not connected
+  Enotconn
+  /// Inappropriate device for ioctl
+  Enotty
+  /// Socket operation on non-socket
+  Enotsock
+  /// Protocol error
+  Eproto
+  /// Protocol not supported
+  Eprotonosupport
+  /// Wrong protocol type for socket
+  Eprototype
+  /// Socket type not supported
+  Esocktnosupport
+  /// Connection timed out
+  Etimedout
+  /// Operation would block
+  Ewouldblock
+  /// Invalid exchange
+  Exbadport
+  /// Invalid sequence number
+  Exbadseq
+  /// Permission denied
+  Eacces
+  /// Resource temporarily unavailable
+  Eagain
+  /// Bad file number
+  Ebadf
+  /// Not a data message
+  Ebadmsg
+  /// File busy
+  Ebusy
+  /// Resource deadlock avoided
+  Edeadlk
+  /// Resource deadlock avoided
+  Edeadlock
+  /// Disk quota exceeded
+  Edquot
+  /// File already exists
+  Eexist
+  /// Bad address in system call argument
+  Efault
+  /// File too large
+  Efbig
+  /// Inappropriate file type or format
+  Eftype
+  /// Interrupted system call
+  Eintr
+  /// Invalid argument
+  Einval
+  /// I/O error
+  Eio
+  /// Illegal operation on a directory
+  Eisdir
+  /// Too many levels of symbolic links
+  Eloop
+  /// Too many open files
+  Emfile
+  /// Too many links
+  Emlink
+  /// Multihop attempted
+  Emultihop
+  /// Filename too long
+  Enametoolong
+  /// File table overflow
+  Enfile
+  /// No buffer space available
+  Enobufs
+  /// No such device
+  Enodev
+  /// No locks available
+  Enolck
+  /// Link has been severed
+  Enolink
+  /// No such file or directory
+  Enoent
+  /// Not enough memory
+  Enomem
+  /// No space left on device
+  Enospc
+  /// Out of stream resources or not a stream device
+  Enosr
+  /// Not a stream device
+  Enostr
+  /// Function not implemented
+  Enosys
+  /// Block device required
+  Enotblk
+  /// Not a directory
+  Enotdir
+  /// Operation not supported
+  Enotsup
+  /// No such device or address
+  Enxio
+  /// Operation not supported on socket
+  Eopnotsupp
+  /// Value too large for defined data type
+  Eoverflow
+  /// Not owner
+  Eperm
+  /// Broken pipe
+  Epipe
+  /// Math result unrepresentable
+  Erange
+  /// Read-only filesystem
+  Erofs
+  /// Invalid seek
+  Espipe
+  /// No such process
+  Esrch
+  /// Stale remote file handle
+  Estale
+  /// Text file or pseudo-device busy
+  Etxtbsy
+  /// Cross-device link
+  Exdev
+}
+
+pub fn to_string(reason: Reason) -> String {
+  case reason {
+    Closed -> "Connection closed (closed)"
+    Eacces -> "Permission denied (eacces)"
+    Eaddrinuse -> "Address already in use (eaddrinuse)"
+    Eaddrnotavail -> "Cannot assign requested address (eaddrnotavail)"
+    Eafnosupport ->
+      "Address family not supported by protocol family (eafnosupport)"
+    Eagain -> "Resource temporarily unavailable (eagain)"
+    Ealready -> "Operation already in progress (ealready)"
+    Ebadf -> "Bad file number (ebadf)"
+    Ebadmsg -> "Not a data message (ebadmsg)"
+    Ebusy -> "File busy (ebusy)"
+    Econnaborted -> "Software caused connection abort (econnaborted)"
+    Econnrefused -> "Connection refused (econnrefused)"
+    Econnreset -> "Connection reset by peer (econnreset)"
+    Edeadlk -> "Resource deadlock avoided (edeadlk)"
+    Edeadlock -> "Resource deadlock avoided (edeadlock)"
+    Edestaddrreq -> "Destination address required (edestaddrreq)"
+    Edquot -> "Disk quota exceeded (edquot)"
+    Eexist -> "File already exists (eexist)"
+    Efault -> "Bad address in system call argument (efault)"
+    Efbig -> "File too large (efbig)"
+    Eftype -> "Inappropriate file type or format (eftype)"
+    Ehostdown -> "Host is down (ehostdown)"
+    Ehostunreach -> "Host is unreachable (ehostunreach)"
+    Einprogress -> "Operation now in progress (einprogress)"
+    Eintr -> "Interrupted system call (eintr)"
+    Einval -> "Invalid argument (einval)"
+    Eio -> "I/O error (eio)"
+    Eisconn -> "Socket is already connected (eisconn)"
+    Eisdir -> "Illegal operation on a directory (eisdir)"
+    Eloop -> "Too many levels of symbolic links (eloop)"
+    Emfile -> "Too many open files (emfile)"
+    Emlink -> "Too many links (emlink)"
+    Emsgsize -> "Message too long (emsgsize)"
+    Emultihop -> "Multihop attempted (emultihop)"
+    Enametoolong -> "Filename too long (enametoolong)"
+    Enetdown -> "Network is down (enetdown)"
+    Enetunreach -> "Network is unreachable (enetunreach)"
+    Enfile -> "File table overflow (enfile)"
+    Enobufs -> "No buffer space available (enobufs)"
+    Enodev -> "No such device (enodev)"
+    Enoent -> "No such file or directory (enoent)"
+    Enolck -> "No locks available (enolck)"
+    Enolink -> "Link has been severed (enolink)"
+    Enomem -> "Not enough memory (enomem)"
+    Enopkg -> "Package not installed (enopkg)"
+    Enoprotoopt -> "Bad protocol option (enoprotoopt)"
+    Enospc -> "No space left on device (enospc)"
+    Enosr -> "Out of stream resources or not a stream device (enosr)"
+    Enostr -> "Not a stream device (enostr)"
+    Enosys -> "Function not implemented (enosys)"
+    Enotblk -> "Block device required (enotblk)"
+    Enotconn -> "Socket is not connected (enotconn)"
+    Enotdir -> "Not a directory (enotdir)"
+    Enotsock -> "Socket operation on non-socket (enotsock)"
+    Enotsup -> "Operation not supported (enotsup)"
+    Enotty -> "Inappropriate device for ioctl (enotty)"
+    Enxio -> "No such device or address (enxio)"
+    Eopnotsupp -> "Operation not supported on socket (eopnotsupp)"
+    Eoverflow -> "Value too large for defined data type (eoverflow)"
+    Eperm -> "Not owner (eperm)"
+    Epipe -> "Broken pipe (epipe)"
+    Eproto -> "Protocol error (eproto)"
+    Eprotonosupport -> "Protocol not supported (eprotonosupport)"
+    Eprototype -> "Wrong protocol type for socket (eprototype)"
+    Erange -> "Math result unrepresentable (erange)"
+    Erofs -> "Read-only filesystem (erofs)"
+    Esocktnosupport -> "Socket type not supported (esocktnosupport)"
+    Espipe -> "Invalid seek (espipe)"
+    Esrch -> "No such process (esrch)"
+    Estale -> "Stale remote file handle (estale)"
+    Etimedout -> "Connection timed out (etimedout)"
+    Etxtbsy -> "Text file or pseudo-device busy (etxtbsy)"
+    Ewouldblock -> "Operation would block (ewouldblock)"
+    Exbadport -> "Invalid exchange (exbadport)"
+    Exbadseq -> "Invalid sequence number (exbadseq)"
+    Exdev -> "Cross-device link (exdev)"
+    Timeout -> "Operation timed out (timeout)"
+  }
+}

src/musicplayer/tcp/tcp.gleam

@@ -0,0 +1,117 @@
+import gleam/bit_array
+import gleam/erlang/atom
+import gleam/result
+
+import musicplayer/tcp/reason.{type Reason}
+
+pub type Socket
+
+// https://www.erlang.org/doc/apps/kernel/inet#t:address_family/0
+// local socket
+type Local {
+  Local(socket_path: String)
+}
+
+type ModeValue {
+  Binary
+}
+
+type TCPOption {
+  Active(Bool)
+  Mode(ModeValue)
+  Reuseaddr(Bool)
+  Ifaddr(Local)
+  ExitOnClose(Bool)
+}
+
+pub fn listen(socket_path: String) -> Result(Socket, Reason) {
+  let options = [
+    Mode(Binary),
+    Active(False),
+    Reuseaddr(True),
+    Ifaddr(Local(socket_path)),
+    ExitOnClose(False),
+  ]
+  // port zero with `local` address
+  let port = 0
+
+  gen_tcp_listen(port, options)
+}
+
+pub fn accept(listen_socket: Socket) -> Result(Socket, Reason) {
+  gen_tcp_accept(listen_socket)
+}
+
+pub fn receive(socket: Socket, timeout: Int) -> Result(String, Reason) {
+  // Get all bytes
+  let length = 0
+
+  use bits <- result.try(gen_tcp_recv(socket, length, timeout))
+  case bits |> bit_array.to_string {
+    // TODO what error is best?
+    Error(_) -> Error(reason.Ebadmsg)
+    Ok(s) -> Ok(s)
+  }
+}
+
+pub fn connect(socket_path: String) -> Result(Socket, Reason) {
+  let options = [Mode(Binary), Active(False)]
+
+  // port zero with `local` address
+  let port = 0
+
+  // timeout in ms
+  let timeout = 1000
+
+  gen_tcp_connect(Local(socket_path), port, options, timeout)
+}
+
+pub fn send(socket: Socket, message: String) -> Result(Nil, Reason) {
+  gen_tcp_send(socket, bit_array.from_string(message))
+}
+
+pub fn close(socket: Socket) -> Nil {
+  gen_tcp_close(socket)
+}
+
+pub fn shutdown(socket: Socket) -> Result(Nil, Reason) {
+  let how = atom.create("write")
+  gen_tcp_shutdown(socket, how)
+}
+
+// https://www.erlang.org/doc/apps/kernel/gen_tcp.html#listen/2
+@external(erlang, "gen_tcp", "listen")
+fn gen_tcp_listen(port: Int, option: List(TCPOption)) -> Result(Socket, Reason)
+
+// https://www.erlang.org/doc/apps/kernel/gen_tcp.html#accept/1
+@external(erlang, "gen_tcp", "accept")
+fn gen_tcp_accept(listen_socket: Socket) -> Result(Socket, Reason)
+
+// https://www.erlang.org/doc/apps/kernel/gen_tcp.html#recv/3
+@external(erlang, "gen_tcp", "recv")
+fn gen_tcp_recv(
+  socket: Socket,
+  length: Int,
+  timeout: Int,
+) -> Result(BitArray, Reason)
+
+// https://www.erlang.org/doc/apps/kernel/gen_tcp.html#connect/4
+@external(erlang, "gen_tcp", "connect")
+fn gen_tcp_connect(
+  address: Local,
+  port: Int,
+  options: List(TCPOption),
+  timeout: Int,
+) -> Result(Socket, Reason)
+
+// https://www.erlang.org/doc/apps/kernel/gen_tcp.html#send/2
+@external(erlang, "tcp_ffi", "send")
+fn gen_tcp_send(socket: Socket, packet: BitArray) -> Result(Nil, Reason)
+
+// https://www.erlang.org/doc/apps/kernel/gen_tcp.html#close/1
+@external(erlang, "gen_tcp", "close")
+fn gen_tcp_close(socket: Socket) -> Nil
+
+// https://www.erlang.org/doc/apps/kernel/gen_tcp.html#shutdown/2
+@external(erlang, "tcp_ffi", "shutdown")
+fn gen_tcp_shutdown(socket: Socket, how: atom.Atom) -> Result(Nil, Reason)

src/musicplayer/tcp/tcp_ffi.erl

@@ -0,0 +1,14 @@
+-module(tcp_ffi).
+-export([send/2, shutdown/2]).
+
+send(Socket, Packet) ->
+  case gen_tcp:send(Socket, Packet) of
+    ok -> {ok, nil};
+    Res -> Res
+  end.
+
+shutdown(Socket, How) ->
+  case gen_tcp:shutdown(Socket, How) of
+    ok -> {ok, nil};
+    Res -> Res
+  end.

test/echo_server.gleam

@@ -0,0 +1,81 @@
+import gleam/erlang/process.{type Subject}
+import gleam/io
+import gleam/otp/actor
+import gleam/result
+import gleam/string
+
+import musicplayer/tcp/reason.{type Reason}
+import musicplayer/tcp/tcp
+
+pub type Message {
+  Shutdown
+  ReadyToAccept(subject: Subject(Message), listen_socket: tcp.Socket)
+}
+
+pub fn new(socket_path: String) -> Result(tcp.Socket, String) {
+  let server = actor.new(Nil) |> actor.on_message(handle_message) |> actor.start
+
+  case tcp.listen(socket_path), server {
+    Error(r), _ -> Error(reason.to_string(r))
+    _, Error(start_error) ->
+      case start_error {
+        actor.InitExited(_) -> Error("InitExited")
+        actor.InitFailed(_) -> Error("InitFailed")
+        actor.InitTimeout -> Error("InitTimeout")
+      }
+    Ok(listen_socket), Ok(b) -> {
+      let subject = b.data
+      actor.send(subject, ReadyToAccept(subject, listen_socket))
+      Ok(listen_socket)
+    }
+  }
+}
+
+fn handle_message(_: Nil, message: Message) -> actor.Next(Nil, Message) {
+  case message {
+    Shutdown -> actor.stop()
+
+    ReadyToAccept(subject, listen_socket) -> {
+      case tcp.accept(listen_socket) {
+        Error(r) ->
+          actor.stop_abnormal(
+            "Could not accept connection :" <> reason.to_string(r),
+          )
+        Ok(socket) -> {
+          case receive_from_connection(socket) {
+            Error(r) ->
+              io.println_error(
+                "Failed to receive from connection :" <> reason.to_string(r),
+              )
+            Ok(_) -> Nil
+          }
+
+          actor.send(subject, ReadyToAccept(subject, listen_socket))
+          actor.continue(Nil)
+        }
+      }
+    }
+  }
+}
+
+fn receive_from_connection(socket: tcp.Socket) -> Result(Nil, Reason) {
+  result.try(receive_until_closed(socket, ""), fn(data) {
+    let _ = tcp.send(socket, data)
+    tcp.close(socket)
+    Ok(Nil)
+  })
+}
+
+fn receive_until_closed(
+  socket: tcp.Socket,
+  result: String,
+) -> Result(String, Reason) {
+  case tcp.receive(socket, 10_000) {
+    Error(reason.Closed) -> Ok(result)
+    Error(err) -> Error(err)
+    Ok(data) -> {
+      let result = data |> string.append(result, _)
+      receive_until_closed(socket, result)
+    }
+  }
+}

test/musicplayer/input/input_test.gleam

@@ -0,0 +1,42 @@
+import gleam/list
+import gleeunit
+
+import musicplayer/input/key.{type Key, Char, csi, esc, input_introducer as ii}
+
+pub fn main() -> Nil {
+  gleeunit.main()
+}
+
+type TestCase {
+  TestCase(input: List(String), expected: Key)
+}
+
+pub fn key_from_list_test() {
+  let base_tests = [TestCase([], key.Continue([]))]
+
+  let char_tests = [TestCase(["c"], Char("c"))]
+
+  let escape_tests = [
+    TestCase([esc, csi], key.Continue([esc, csi])),
+    TestCase([esc], key.Continue([esc])),
+
+    TestCase([esc, csi, "D"], key.Left),
+    TestCase([esc, csi, "C"], key.Right),
+    TestCase([esc, csi, "A"], key.Up),
+    TestCase([esc, csi, "B"], key.Down),
+  ]
+
+  let input_tests = [
+    TestCase([ii], key.Continue([ii])),
+    TestCase([ii, "a"], key.Continue([ii, "a"])),
+    TestCase([ii, "a", "b"], key.Continue([ii, "ab"])),
+    TestCase([ii, "ab", "\u{007F}"], key.Continue([ii, "a"])),
+    TestCase([ii, "ab", "\r"], key.Input("ab")),
+  ]
+
+  let test_cases = [base_tests, char_tests, escape_tests, input_tests]
+
+  list.each(list.flatten(test_cases), fn(tc) {
+    assert tc.expected == key.from_list(tc.input)
+  })
+}

test/musicplayer/mpv/control_test.gleam

@@ -0,0 +1,33 @@
+import gleam/list
+import gleeunit
+
+import musicplayer/input/key.{type Key, Char}
+import musicplayer/mpv/control.{type Control}
+import musicplayer/mpv/internal as control_internal
+
+pub fn main() -> Nil {
+  gleeunit.main()
+}
+
+type TestCase {
+  TestCase(key: Key, expected: Result(Control, Nil))
+}
+
+pub fn control_from_key_test() {
+  let test_cases = [
+    TestCase(Char(" "), Ok(control.TogglePlayPause)),
+    TestCase(Char("q"), Ok(control.Exit)),
+  ]
+
+  list.each(test_cases, fn(tc) {
+    assert tc.expected == control.from_key(tc.key)
+  })
+}
+
+pub fn parse_playback_time_test() {
+  let json_string =
+    "{\"data\":\"123.456789\",\"request_id\":0,\"error\":\"success\"}\n"
+
+  let assert Ok(data) = control_internal.parse_playback_time(json_string)
+  assert data == 123.456789
+}

test/musicplayer/tcp/tcp_test.gleam

@@ -0,0 +1,30 @@
+import gleam/list
+import gleeunit
+import simplifile
+
+import echo_server
+import musicplayer/tcp/tcp
+
+pub fn main() -> Nil {
+  gleeunit.main()
+}
+
+pub fn tcp_send_shutdown_receive_test() {
+  let socket_path = "/tmp/musicplayer-test.sock"
+
+  let assert Ok(_) = echo_server.new(socket_path)
+  let assert Ok(socket) = tcp.connect(socket_path)
+
+  let messages = ["hello, ", "world!\n"]
+  list.each(messages, fn(message) {
+    let assert Ok(_) = tcp.send(socket, message)
+  })
+
+  let assert Ok(_) = tcp.shutdown(socket)
+
+  let timeout_ms = 100
+  assert Ok("hello, world!\n") == tcp.receive(socket, timeout_ms)
+
+  // TODO find better way to always do cleanup
+  simplifile.delete(socket_path)
+}

test/musicplayer_test.gleam

@@ -3,11 +3,3 @@ import gleeunit
 pub fn main() -> Nil {
   gleeunit.main()
 }
-
-// gleeunit test functions end in `_test`
-pub fn hello_world_test() {
-  let name = "Joe"
-  let greeting = "Hello, " <> name <> "!"
-
-  assert greeting == "Hello, Joe!"
-}