Add musicplayer module that wraps all logic

And add the ability of other modules to listen to either
the final result (a `Key`) or tap into the input as it is read

src/input/key.gleam

@@ -1,53 +0,0 @@
-import gleam/erlang/atom
-import gleam/list
-
-import input/internal as internal_input
-
-pub type Key {
-  Char(String)
-
-  Left
-  Right
-  Up
-  Down
-
-  Continue
-  Unknown
-}
-
-pub const esc = "\u{001B}"
-
-// control sequence introducer
-pub const csi = "["
-
-pub fn from_list(l: List(String)) -> Key {
-  case l {
-    [e, c, "D"] if e == esc && c == csi -> Left
-    [e, c, "C"] if e == esc && c == csi -> Right
-    [e, c, "A"] if e == esc && c == csi -> Up
-    [e, c, "B"] if e == esc && c == csi -> Down
-
-    [e, c] if e == esc && c == csi -> Continue
-
-    [e] if e == esc -> Continue
-    [char] -> Char(char)
-
-    [] -> Continue
-    _ -> Unknown
-  }
-}
-
-pub fn start_raw_shell() {
-  let no_shell = atom.create("noshell")
-  let raw = atom.create("raw")
-  internal_input.shell_start_interactive(#(no_shell, raw))
-}
-
-pub fn read_input_until_key(l: List(String)) -> Key {
-  let l = internal_input.read_input() |> list.wrap |> list.append(l, _)
-
-  case from_list(l) {
-    Continue -> read_input_until_key(l)
-    k -> k
-  }
-}

src/mpv/mpv.gleam

@@ -1,78 +0,0 @@
-import gleam/erlang/process.{type Subject}
-import gleam/float
-import gleam/otp/actor
-import gleam/result
-import gleam/string
-
-import input/key
-import mpv/control.{type Control}
-import tcp/reason
-import tcp/tcp.{type Socket}
-
-type State(socket, exit) {
-  State(socket: Socket, exit: Subject(Nil))
-}
-
-pub fn new(exit: Subject(Nil)) -> Result(Nil, String) {
-  // TODO start up mvp here, currently hi-jacking `naviterm`s socket
-  let socket_path = "/tmp/naviterm_mpv"
-
-  case tcp.connect(socket_path) {
-    Error(r) -> Error("Could not connect to mpv: " <> reason.to_string(r))
-    Ok(socket) -> {
-      case
-        actor.new(State(socket, exit))
-        |> actor.on_message(handle_message)
-        |> actor.start
-      {
-        Error(start_error) ->
-          Error("Could not start actor: " <> string.inspect(start_error))
-        Ok(actor.Started(data:, ..)) -> {
-          echo "waiting for input"
-          key.start_raw_shell()
-          process.spawn(fn() { read_input(data) })
-          Ok(Nil)
-        }
-      }
-    }
-  }
-}
-
-fn handle_message(
-  state: State(socket, exit),
-  control: Control,
-) -> actor.Next(State(socket, exit), Control) {
-  case control {
-    control.TogglePlayPause -> {
-      echo "toggling play/pause"
-
-      let _ =
-        result.map_error(control.toggle_play_pause(state.socket), fn(err) {
-          echo "Could not toggle play/pause: " <> err.details
-        })
-
-      let _ =
-        result.map(control.get_playback_time(state.socket), fn(playback) {
-          echo "playback: " <> float.to_string(playback.data)
-        })
-
-      actor.continue(state)
-    }
-    control.Exit -> {
-      process.send(state.exit, Nil)
-      actor.stop()
-    }
-  }
-}
-
-fn read_input(subject: Subject(Control)) -> Nil {
-  case
-    key.read_input_until_key([])
-    |> control.from_key
-  {
-    Error(_) -> Nil
-    Ok(control) -> process.send(subject, control)
-  }
-
-  read_input(subject)
-}

src/musicplayer.gleam

@@ -1,8 +1,32 @@
-import gleam/erlang/process
+import gleam/erlang/process.{type Name}
-import mpv/mpv
+
+import musicplayer/input/input
+import musicplayer/input/key.{type Key}
+import musicplayer/mpv/mpv
+import musicplayer/musicplayer
 
 pub fn main() -> Nil {
+  let input_keys_name: Name(Key) = process.new_name("input_keys")
+  let input_stream_name: Name(List(String)) = process.new_name("input_stream")
+
+  // `input_inject` is created by name to allow the `input` process that
+  // owns `read_input` to be able to register and receive from it,
+  //  while the any other processes can use the name reference to
+  // inject input
+  let input_inject_name: Name(Key) = process.new_name("input_inject_keys")
+
+  input.new(input_keys_name, input_stream_name, input_inject_name)
+
+  let assert Ok(mpv) = mpv.new()
+
   let exit = process.new_subject()
-  let assert Ok(_) = mpv.new(exit)
+  let assert Ok(_) =
+    musicplayer.new(
+      mpv,
+      input_keys_name,
+      input_stream_name,
+      input_inject_name,
+      exit,
+    )
   process.receive_forever(exit)
 }

src/musicplayer/control.gleam

@@ -0,0 +1,25 @@
+import musicplayer/input/key.{type Key}
+
+pub type Control {
+  TogglePlayPause
+
+  Search
+
+  Exit
+}
+
+pub fn from_key(key: Key) -> Result(Control, Nil) {
+  case key {
+    key.Char(char) -> char_control(char)
+    _ -> Error(Nil)
+  }
+}
+
+fn char_control(char: String) -> Result(Control, Nil) {
+  case char {
+    " " -> Ok(TogglePlayPause)
+    "q" -> Ok(Exit)
+    "/" -> Ok(Search)
+    _ -> Error(Nil)
+  }
+}

src/musicplayer/input/input.gleam

@@ -0,0 +1,48 @@
+import gleam/erlang/process.{type Name, type Subject}
+
+import musicplayer/input/key.{type Key}
+
+// TODO REWRITE below
+
+/// `new` accepts a list of listeners that are composed of two subjects;
+///   - one to get the final `Key` and
+///   - one to tap the input as it is read from i/o
+/// and
+///   - a subject name that is used to create a `Subject` that other processes
+///     know they can inject a `Key` into the input with
+pub fn new(
+  input_keys_name: Name(Key),
+  input_stream_name: Name(List(String)),
+  input_inject_name: Name(Key),
+) -> Nil {
+  let _ =
+    process.spawn(fn() {
+      let input_keys = process.named_subject(input_keys_name)
+      let input_stream = process.named_subject(input_stream_name)
+      let input_inject = process.named_subject(input_inject_name)
+
+      let assert Ok(_) = process.register(process.self(), input_inject_name)
+
+      read_input(input_keys, input_stream, input_inject)
+    })
+
+  echo "waiting for input"
+  key.start_raw_shell()
+  Nil
+}
+
+fn read_input(
+  input_keys: Subject(Key),
+  input_stream: Subject(List(String)),
+  input_inject: Subject(Key),
+) -> Nil {
+  let buffer = case process.receive(input_inject, 1) {
+    Ok(key.Continue(buffer)) -> buffer
+    Ok(_) | Error(_) -> []
+  }
+
+  key.read_input_until_key(buffer, input_stream)
+  |> process.send(input_keys, _)
+
+  read_input(input_keys, input_stream, input_inject)
+}

src/musicplayer/input/key.gleam

@@ -0,0 +1,79 @@
+import gleam/erlang/atom
+import gleam/erlang/process.{type Subject}
+import gleam/list
+import gleam/string
+
+import musicplayer/input/internal as internal_input
+
+pub type Key {
+  Char(String)
+
+  Input(String)
+  Left
+  Right
+  Up
+  Down
+
+  Continue(buffer: List(String))
+  Unknown
+}
+
+pub const esc = "\u{001B}"
+
+// control sequence introducer
+pub const csi = "["
+
+// input introducer
+pub const input_introducer = "::"
+
+pub fn from_list(l: List(String)) -> Key {
+  case l {
+    [e, c, "D"] if e == esc && c == csi -> Left
+    [e, c, "C"] if e == esc && c == csi -> Right
+    [e, c, "A"] if e == esc && c == csi -> Up
+    [e, c, "B"] if e == esc && c == csi -> Down
+
+    [e, c] if e == esc && c == csi -> Continue(l)
+
+    [ci] | [ci, _] if ci == input_introducer -> Continue(l)
+    [ii, cmd, tail] if ii == input_introducer -> {
+      case tail {
+        // Return
+        "\r" -> Input(cmd)
+        // Backspace
+        "\u{007F}" -> Continue([ii, string.drop_end(cmd, 1)])
+        _ -> Continue([ii, cmd <> tail])
+      }
+    }
+
+    [e] if e == esc -> Continue(l)
+    [char] -> Char(char)
+
+    [] -> Continue([])
+    _ -> Unknown
+  }
+}
+
+pub fn start_raw_shell() {
+  let no_shell = atom.create("noshell")
+  let raw = atom.create("raw")
+  internal_input.shell_start_interactive(#(no_shell, raw))
+}
+
+pub fn read_input_until_key(
+  l: List(String),
+  input_stream: Subject(List(String)),
+) -> Key {
+  case
+    internal_input.read_input()
+    |> list.wrap
+    |> list.append(l, _)
+    |> from_list
+  {
+    Continue(l) -> {
+      process.send(input_stream, l)
+      read_input_until_key(l, input_stream)
+    }
+    k -> k
+  }
+}

src/musicplayer/mpv/control.gleam

@@ -1,36 +1,24 @@
+import gleam/erlang/process.{type Subject}
 import gleam/json
 import gleam/result
 import gleam/string
 
-import input/key.{type Key, Char}
+import musicplayer/mpv/internal as internal_control
-import mpv/internal/control as internal_control
+import musicplayer/tcp/reason.{type Reason}
-import tcp/reason.{type Reason}
+import musicplayer/tcp/tcp.{type Socket}
-import tcp/tcp.{type Socket}
 
 pub type Control {
   TogglePlayPause
-  Exit
+
+  GetPlaybackTime(reply_to: Subject(Result(PlaybackTime, ControlError)))
+
+  Exit(reply_to: Subject(Nil))
 }
 
 pub type ControlError {
   ControlError(details: String)
 }
 
-pub fn from_key(key: Key) -> Result(Control, Nil) {
-  case key {
-    Char(char) -> char_control(char)
-    _ -> Error(Nil)
-  }
-}
-
-fn char_control(char: String) -> Result(Control, Nil) {
-  case char {
-    " " -> Ok(TogglePlayPause)
-    "q" -> Ok(Exit)
-    _ -> Error(Nil)
-  }
-}
-
 pub fn toggle_play_pause(socket: Socket) -> Result(Nil, ControlError) {
   let command =
     json.object([#("command", json.array(["cycle", "pause"], of: json.string))])

src/musicplayer/mpv/mpv.gleam

@@ -0,0 +1,62 @@
+import gleam/erlang/process.{type Subject}
+import gleam/otp/actor
+import gleam/result
+import gleam/string
+
+import musicplayer/mpv/control
+import musicplayer/tcp/reason
+import musicplayer/tcp/tcp.{type Socket}
+
+type State(socket) {
+  State(socket: Socket)
+}
+
+pub fn new() -> Result(Subject(control.Control), String) {
+  // TODO start up mvp here, currently hi-jacking `naviterm`s socket
+  let socket_path = "/tmp/naviterm_mpv"
+
+  case tcp.connect(socket_path) {
+    Error(r) -> Error("Could not connect to mpv: " <> reason.to_string(r))
+    Ok(socket) -> {
+      case
+        actor.new(State(socket))
+        |> actor.on_message(handle_message)
+        |> actor.start
+      {
+        Error(start_error) ->
+          Error("Could not start actor: " <> string.inspect(start_error))
+        Ok(actor.Started(data: mpv, ..)) -> Ok(mpv)
+      }
+    }
+  }
+}
+
+fn handle_message(
+  state: State(socket),
+  control: control.Control,
+) -> actor.Next(State(socket), control.Control) {
+  case control {
+    control.TogglePlayPause -> {
+      echo "mpv: toggling play/pause"
+
+      let _ =
+        result.map_error(control.toggle_play_pause(state.socket), fn(err) {
+          echo "Could not toggle play/pause: " <> err.details
+        })
+
+      actor.continue(state)
+    }
+
+    control.GetPlaybackTime(reply_to) -> {
+      let res = control.get_playback_time(state.socket)
+      process.send(reply_to, res)
+      actor.continue(state)
+    }
+
+    control.Exit(reply_to) -> {
+      tcp.close(state.socket)
+      process.send(reply_to, Nil)
+      actor.stop()
+    }
+  }
+}

src/musicplayer/musicplayer.gleam

@@ -0,0 +1,106 @@
+import gleam/erlang/process.{type Name, type Subject}
+import gleam/float
+import gleam/otp/actor
+import gleam/result
+import gleam/string
+
+import musicplayer/control.{type Control}
+import musicplayer/input/key.{type Key}
+import musicplayer/mpv/control as mpv_control
+
+type State(mpv, input_inject, exit) {
+  State(
+    mpv: Subject(mpv_control.Control),
+    input_inject: Subject(Key),
+    exit: Subject(Nil),
+  )
+}
+
+pub fn new(
+  mpv: Subject(mpv_control.Control),
+  input_keys_name: Name(Key),
+  input_stream_name: Name(List(String)),
+  input_inject_name: Name(Key),
+  exit: Subject(Nil),
+) -> Result(Nil, String) {
+  let input_keys = process.named_subject(input_keys_name)
+  let input_stream = process.named_subject(input_stream_name)
+  let input_inject = process.named_subject(input_inject_name)
+
+  case
+    actor.new(State(mpv, input_inject, exit))
+    |> actor.on_message(handle_message)
+    |> actor.start
+  {
+    Error(start_error) ->
+      Error("Could not start actor: " <> string.inspect(start_error))
+    Ok(actor.Started(data: musicplayer, ..)) -> {
+      process.spawn(fn() {
+        let assert Ok(_) = process.register(process.self(), input_keys_name)
+        handle_key(musicplayer, input_keys)
+      })
+
+      process.spawn(fn() {
+        let assert Ok(_) = process.register(process.self(), input_stream_name)
+        temp_input_stream(input_stream)
+      })
+
+      Ok(Nil)
+    }
+  }
+}
+
+fn handle_message(
+  state: State(mpv, input_inject, exit),
+  control: Control,
+) -> actor.Next(State(mpv, input_inject, exit), Control) {
+  case control {
+    control.Search -> {
+      process.send(state.input_inject, key.Continue([key.input_introducer]))
+
+      actor.continue(state)
+    }
+    control.TogglePlayPause -> {
+      echo "toggling play/pause"
+
+      process.send(state.mpv, mpv_control.TogglePlayPause)
+
+      case
+        process.call(state.mpv, 1000, fn(reply_to) {
+          mpv_control.GetPlaybackTime(reply_to)
+        })
+      {
+        Error(err) -> echo "! could not get playbackTime: " <> err.details
+        Ok(mpv_control.PlaybackTime(data: playback_time)) ->
+          echo "playbacktime from mpv: " <> float.to_string(playback_time)
+      }
+
+      actor.continue(state)
+    }
+    control.Exit -> {
+      // Close socket to `mpv`
+      process.call(state.mpv, 1000, fn(reply_to) { mpv_control.Exit(reply_to) })
+
+      // End main process
+      process.send(state.exit, Nil)
+      actor.stop()
+    }
+  }
+}
+
+/// `handle_key` listens to a subject onto which `input` will send messages with
+/// parsed `Key`s which will be mapped to `Control`s (if possible)
+fn handle_key(musicplayer: Subject(Control), input_keys: Subject(Key)) -> Nil {
+  let _ =
+    process.receive_forever(input_keys)
+    |> control.from_key
+    |> result.map(process.send(musicplayer, _))
+
+  handle_key(musicplayer, input_keys)
+}
+
+fn temp_input_stream(input_stream: Subject(List(String))) -> Nil {
+  let stream = process.receive_forever(input_stream)
+  echo "input stream: " <> string.inspect(stream)
+  temp_input_stream(input_stream)
+}

src/musicplayer/tcp/tcp.gleam

@@ -2,7 +2,7 @@ import gleam/bit_array
 import gleam/erlang/atom
 import gleam/result
 
-import tcp/reason.{type Reason}
+import musicplayer/tcp/reason.{type Reason}
 
 pub type Socket
 

test/echo_server.gleam

@@ -4,8 +4,8 @@ import gleam/otp/actor
 import gleam/result
 import gleam/string
 
-import tcp/reason.{type Reason}
+import musicplayer/tcp/reason.{type Reason}
-import tcp/tcp
+import musicplayer/tcp/tcp
 
 pub type Message {
   Shutdown

test/input/input_test.gleam

@@ -1,29 +0,0 @@
-import gleam/list
-import gleeunit
-
-import input/key.{type Key, Char, csi, esc}
-
-pub fn main() -> Nil {
-  gleeunit.main()
-}
-
-type TestCase {
-  TestCase(input: List(String), expected: Key)
-}
-
-pub fn key_from_list_test() {
-  let test_cases = [
-    TestCase(["c"], Char("c")),
-    TestCase([esc, csi, "D"], key.Left),
-    TestCase([esc, csi, "C"], key.Right),
-    TestCase([esc, csi, "A"], key.Up),
-    TestCase([esc, csi, "B"], key.Down),
-    TestCase([esc, csi], key.Continue),
-    TestCase([esc], key.Continue),
-    TestCase([], key.Continue),
-  ]
-
-  list.each(test_cases, fn(tc) {
-    assert tc.expected == key.from_list(tc.input)
-  })
-}

test/musicplayer/control_test.gleam

@@ -1,9 +1,8 @@
 import gleam/list
 import gleeunit
 
-import input/key.{type Key, Char}
+import musicplayer/control.{type Control}
-import mpv/control.{type Control}
+import musicplayer/input/key.{type Key, Char}
-import mpv/internal/control as control_internal
 
 pub fn main() -> Nil {
   gleeunit.main()
@@ -23,11 +22,3 @@ pub fn control_from_key_test() {
     assert tc.expected == control.from_key(tc.key)
   })
 }
-
-pub fn parse_playback_time_test() {
-  let json_string =
-    "{\"data\":\"123.456789\",\"request_id\":0,\"error\":\"success\"}\n"
-
-  let assert Ok(data) = control_internal.parse_playback_time(json_string)
-  assert data == 123.456789
-}

test/musicplayer/input/input_test.gleam

@@ -0,0 +1,42 @@
+import gleam/list
+import gleeunit
+
+import musicplayer/input/key.{type Key, Char, csi, esc, input_introducer as ii}
+
+pub fn main() -> Nil {
+  gleeunit.main()
+}
+
+type TestCase {
+  TestCase(input: List(String), expected: Key)
+}
+
+pub fn key_from_list_test() {
+  let base_tests = [TestCase([], key.Continue([]))]
+
+  let char_tests = [TestCase(["c"], Char("c"))]
+
+  let escape_tests = [
+    TestCase([esc, csi], key.Continue([esc, csi])),
+    TestCase([esc], key.Continue([esc])),
+
+    TestCase([esc, csi, "D"], key.Left),
+    TestCase([esc, csi, "C"], key.Right),
+    TestCase([esc, csi, "A"], key.Up),
+    TestCase([esc, csi, "B"], key.Down),
+  ]
+
+  let input_tests = [
+    TestCase([ii], key.Continue([ii])),
+    TestCase([ii, "a"], key.Continue([ii, "a"])),
+    TestCase([ii, "a", "b"], key.Continue([ii, "ab"])),
+    TestCase([ii, "ab", "\u{007F}"], key.Continue([ii, "a"])),
+    TestCase([ii, "ab", "\r"], key.Input("ab")),
+  ]
+
+  let test_cases = [base_tests, char_tests, escape_tests, input_tests]
+
+  list.each(list.flatten(test_cases), fn(tc) {
+    assert tc.expected == key.from_list(tc.input)
+  })
+}

test/musicplayer/mpv/mpv_test.gleam

@@ -0,0 +1,15 @@
+import gleeunit
+
+import musicplayer/mpv/internal as control_internal
+
+pub fn main() -> Nil {
+  gleeunit.main()
+}
+
+pub fn parse_playback_time_test() {
+  let json_string =
+    "{\"data\":\"123.456789\",\"request_id\":0,\"error\":\"success\"}\n"
+
+  let assert Ok(data) = control_internal.parse_playback_time(json_string)
+  assert data == 123.456789
+}

test/musicplayer/tcp/tcp_test.gleam

@@ -3,7 +3,7 @@ import gleeunit
 import simplifile
 
 import echo_server
-import tcp/tcp
+import musicplayer/tcp/tcp
 
 pub fn main() -> Nil {
   gleeunit.main()