Move styling to style and add Border type

By forwarding all `Key`s to the agent and allow it to decide what should
be done, instead of converting the `Key` to a `Control` and then decide
what should be done

gleam.toml

@@ -18,6 +18,7 @@ gleam_otp = ">= 1.2.0 and < 2.0.0"
 gleam_erlang = ">= 1.3.0 and < 2.0.0"
 simplifile = ">= 2.3.1 and < 3.0.0"
 gleam_json = ">= 3.1.0 and < 4.0.0"
+gleam_time = ">= 1.6.0 and < 2.0.0"
 
 [dev-dependencies]
 gleeunit = ">= 1.0.0 and < 2.0.0"

manifest.toml

@@ -7,6 +7,7 @@ packages = [
   { name = "gleam_json", version = "3.1.0", build_tools = ["gleam"], requirements = ["gleam_stdlib"], otp_app = "gleam_json", source = "hex", outer_checksum = "44FDAA8847BE8FC48CA7A1C089706BD54BADCC4C45B237A992EDDF9F2CDB2836" },
   { name = "gleam_otp", version = "1.2.0", build_tools = ["gleam"], requirements = ["gleam_erlang", "gleam_stdlib"], otp_app = "gleam_otp", source = "hex", outer_checksum = "BA6A294E295E428EC1562DC1C11EA7530DCB981E8359134BEABC8493B7B2258E" },
   { name = "gleam_stdlib", version = "0.65.0", build_tools = ["gleam"], requirements = [], otp_app = "gleam_stdlib", source = "hex", outer_checksum = "7C69C71D8C493AE11A5184828A77110EB05A7786EBF8B25B36A72F879C3EE107" },
+  { name = "gleam_time", version = "1.6.0", build_tools = ["gleam"], requirements = ["gleam_stdlib"], otp_app = "gleam_time", source = "hex", outer_checksum = "0DF3834D20193F0A38D0EB21F0A78D48F2EC276C285969131B86DF8D4EF9E762" },
   { name = "gleeunit", version = "1.9.0", build_tools = ["gleam"], requirements = ["gleam_stdlib"], otp_app = "gleeunit", source = "hex", outer_checksum = "DA9553CE58B67924B3C631F96FE3370C49EB6D6DC6B384EC4862CC4AAA718F3C" },
   { name = "simplifile", version = "2.3.1", build_tools = ["gleam"], requirements = ["filepath", "gleam_stdlib"], otp_app = "simplifile", source = "hex", outer_checksum = "957E0E5B75927659F1D2A1B7B75D7B9BA96FAA8D0C53EA71C4AD9CD0C6B848F6" },
 ]
@@ -16,5 +17,6 @@ gleam_erlang = { version = ">= 1.3.0 and < 2.0.0" }
 gleam_json = { version = ">= 3.1.0 and < 4.0.0" }
 gleam_otp = { version = ">= 1.2.0 and < 2.0.0" }
 gleam_stdlib = { version = ">= 0.44.0 and < 2.0.0" }
+gleam_time = { version = ">= 1.6.0 and < 2.0.0" }
 gleeunit = { version = ">= 1.0.0 and < 2.0.0" }
 simplifile = { version = ">= 2.3.1 and < 3.0.0" }

src/mpv/mpv.gleam

@@ -1,123 +0,0 @@
-import gleam/erlang/process.{type Subject}
-import gleam/float
-import gleam/otp/actor
-import gleam/result
-import gleam/string
-
-import input/key.{type Key}
-import mpv/control.{type Control}
-import tcp/reason
-import tcp/tcp.{type Socket}
-
-type State(socket, inject_input, tap_input, exit) {
-  State(
-    socket: Socket,
-    inject_input: Subject(Key),
-    tap_input: Subject(List(String)),
-    exit: Subject(Nil),
-  )
-}
-
-pub fn new(exit: Subject(Nil)) -> Result(Nil, String) {
-  // TODO start up mvp here, currently hi-jacking `naviterm`s socket
-  let socket_path = "/tmp/naviterm_mpv"
-
-  case tcp.connect(socket_path) {
-    Error(r) -> Error("Could not connect to mpv: " <> reason.to_string(r))
-    Ok(socket) -> {
-      // `inject_input` is created by name to allow the process that
-      // owns `read_input` to be able to register it, while the agent
-      // also have a reference to it to be able to inject input
-      let inject_input_name = process.new_name("inject_input")
-      let inject_input = process.named_subject(inject_input_name)
-
-      let tap_input_name = process.new_name("tap_input")
-      let tap_input = process.named_subject(tap_input_name)
-
-      case
-        actor.new(State(socket, inject_input, tap_input, exit))
-        |> actor.on_message(handle_message)
-        |> actor.start
-      {
-        Error(start_error) ->
-          Error("Could not start actor: " <> string.inspect(start_error))
-        Ok(actor.Started(data:, ..)) -> {
-          echo "waiting for input"
-          key.start_raw_shell()
-
-          process.spawn(fn() {
-            let assert Ok(_) =
-              process.register(process.self(), inject_input_name)
-
-            read_input(data, inject_input, tap_input)
-          })
-
-          process.spawn(fn() {
-            let assert Ok(_) = process.register(process.self(), tap_input_name)
-
-            input_output_loop(tap_input)
-          })
-
-          Ok(Nil)
-        }
-      }
-    }
-  }
-}
-
-fn handle_message(
-  state: State(socket, inject, input_output, exit),
-  control: Control,
-) -> actor.Next(State(socket, inject, input_output, exit), Control) {
-  case control {
-    control.Search -> {
-      process.send(state.inject_input, key.Continue([key.input_introducer]))
-      actor.continue(state)
-    }
-    control.TogglePlayPause -> {
-      echo "toggling play/pause"
-
-      let _ =
-        result.map_error(control.toggle_play_pause(state.socket), fn(err) {
-          echo "Could not toggle play/pause: " <> err.details
-        })
-
-      let _ =
-        result.map(control.get_playback_time(state.socket), fn(playback) {
-          echo "playback: " <> float.to_string(playback.data)
-        })
-
-      actor.continue(state)
-    }
-    control.Exit -> {
-      process.send(state.exit, Nil)
-      actor.stop()
-    }
-  }
-}
-
-/// `read_input` operates by reading from input until a `Key` can be created.
-/// It is possible to create a `Key` without the users input by sending
-/// messages to `inject_input` which will initialize the "input to key" sequence.
-/// This is useful to ultimately create a `Control` without the user having to
-/// input all of the character(s) needed.
-fn read_input(
-  agent: Subject(Control),
-  inject_input: Subject(Key),
-  tap_input: Subject(List(String)),
-) -> Nil {
-  let buffer = case process.receive(inject_input, 1) {
-    Ok(key.Continue(buffer)) -> buffer
-    Ok(_) | Error(_) -> []
-  }
-
-  case
-    key.read_input_until_key(buffer, tap_input)
-    |> control.from_key
-  {
-    Error(_) -> Nil
-    Ok(control) -> process.send(agent, control)
-  }
-
-  read_input(agent, inject_input, tap_input)
-}

src/musicplayer.gleam

@@ -1,8 +1,24 @@
-import gleam/erlang/process
-import mpv/mpv
+import gleam/erlang/process.{type Name}
+
+import musicplayer/input/input
+import musicplayer/input/key.{type Key}
+import musicplayer/logging/logging
+import musicplayer/mpv/mpv
+import musicplayer/musicplayer
+import musicplayer/ui/ui
 
 pub fn main() -> Nil {
-  let exit = process.new_subject()
-  let assert Ok(_) = mpv.new(exit)
-  process.receive_forever(exit)
+  let assert Ok(_) = logging.initialize()
+
+  let input_keys_name: Name(Key) = process.new_name("input_keys")
+  input.new(input_keys_name)
+
+  let assert Ok(ui) = ui.new()
+  let assert Ok(mpv) = mpv.new()
+  let assert Ok(musicplayer_pid) = musicplayer.new(ui, mpv, input_keys_name)
+
+  let monitor = process.monitor(musicplayer_pid)
+  process.new_selector()
+  |> process.select_specific_monitor(monitor, fn(_) { Nil })
+  |> process.selector_receive_forever
 }

src/musicplayer/control.gleam

@@ -0,0 +1,58 @@
+import gleam/string
+import musicplayer/ui/layout
+
+import musicplayer/input/key.{type Key}
+
+pub type Mode {
+  Idle
+  Searching(input: String)
+}
+
+pub type Control {
+  TogglePlayPause
+  Search(input: String, capturing: Bool)
+
+  SetView(view_idx: layout.ViewIdx)
+
+  Exit
+}
+
+pub fn from_key(key: Key, mode: Mode) -> Result(Control, Nil) {
+  case mode {
+    Idle -> idle_from_key(key)
+    Searching(input) -> searching_from_key(key, input)
+  }
+}
+
+pub fn idle_from_key(key: Key) -> Result(Control, Nil) {
+  case key {
+    key.Char(char) -> {
+      case char {
+        // Views are zero indexed
+        "1" -> Ok(SetView(0))
+        "2" -> Ok(SetView(1))
+
+        " " -> Ok(TogglePlayPause)
+        "/" -> Ok(Search(input: "", capturing: True))
+        "q" -> Ok(Exit)
+
+        // NOOP
+        _ -> Error(Nil)
+      }
+    }
+
+    // NOOP
+    _ -> Error(Nil)
+  }
+}
+
+pub fn searching_from_key(key: Key, input: String) -> Result(Control, Nil) {
+  case key {
+    key.Char(char) -> Ok(Search(input <> char, True))
+    key.Backspace -> Ok(Search(string.drop_end(input, 1), True))
+    key.Return -> Ok(Search(input, False))
+
+    // NOOP
+    _ -> Error(Nil)
+  }
+}

src/musicplayer/input/input.gleam

@@ -0,0 +1,15 @@
+import gleam/erlang/process.{type Name}
+
+import musicplayer/input/key.{type Key}
+
+/// `new` accepts a subject that all input will be sent to
+pub fn new(input_keys_name: Name(Key)) -> Nil {
+  let _ =
+    process.spawn(fn() {
+      let input_keys = process.named_subject(input_keys_name)
+      key.read_input_until_key(input_keys)
+    })
+
+  key.start_raw_shell()
+  Nil
+}

src/musicplayer/input/key.gleam

@@ -1,20 +1,21 @@
 import gleam/erlang/atom
 import gleam/erlang/process.{type Subject}
 import gleam/list
-import gleam/string
 
-import input/internal as internal_input
+import musicplayer/input/internal as internal_input
 
 pub type Key {
+  Continue(buffer: List(String))
   Char(String)
 
-  Input(String)
   Left
   Right
   Up
   Down
 
-  Continue(buffer: List(String))
+  Return
+  Backspace
+
   Unknown
 }
 
@@ -23,8 +24,9 @@ pub const esc = "\u{001B}"
 // control sequence introducer
 pub const csi = "["
 
-// input introducer
-pub const input_introducer = "::"
+pub const return = "\r"
+
+pub const backspace = "\u{007F}"
 
 pub fn from_list(l: List(String)) -> Key {
   case l {
@@ -35,16 +37,9 @@ pub fn from_list(l: List(String)) -> Key {
 
     [e, c] if e == esc && c == csi -> Continue(l)
 
-    [ci] | [ci, _] if ci == input_introducer -> Continue(l)
-    [ii, cmd, tail] if ii == input_introducer -> {
-      case tail {
-        "\r" -> Input(cmd)
-        "\u{007F}" -> Continue([ii, string.drop_end(cmd, 1)])
-        _ -> Continue([ii, cmd <> tail])
-      }
-    }
-
     [e] if e == esc -> Continue(l)
+    [bs] if bs == backspace -> Backspace
+    [rtn] if rtn == return -> Return
     [char] -> Char(char)
 
     [] -> Continue([])
@@ -58,20 +53,24 @@ pub fn start_raw_shell() {
   internal_input.shell_start_interactive(#(no_shell, raw))
 }
 
-pub fn read_input_until_key(
+pub fn read_input_until_key(input_keys: Subject(Key)) -> Nil {
+  read_input_until_key_loop([], input_keys)
+}
+
+pub fn read_input_until_key_loop(
   l: List(String),
-  tap_input: Subject(List(String)),
-) -> Key {
+  input_keys: Subject(Key),
+) -> Nil {
   case
     internal_input.read_input()
     |> list.wrap
     |> list.append(l, _)
     |> from_list
   {
-    Continue(l) -> {
-      process.send(tap_input, l)
-      read_input_until_key(l, tap_input)
-    }
-    k -> k
+    Continue(l) -> read_input_until_key_loop(l, input_keys)
+    k -> {
+      process.send(input_keys, k)
+      read_input_until_key_loop([], input_keys)
+    }
   }
 }

src/musicplayer/logging/control.gleam

@@ -0,0 +1,5 @@
+pub type Control {
+  Write(String)
+
+  Exit
+}

src/musicplayer/logging/logging.gleam

@@ -0,0 +1,30 @@
+import gleam/result
+import gleam/string
+import gleam/time/calendar
+import gleam/time/timestamp
+import simplifile
+
+const filepath = "/tmp/musicplayer.log"
+
+pub fn initialize() -> Result(Nil, String) {
+  case simplifile.is_file(filepath) {
+    Ok(True) -> Ok(Nil)
+    _ -> simplifile.create_file(filepath)
+  }
+  |> result.map_error(fn(e) {
+    "Could not access or create log file: " <> string.inspect(e)
+  })
+}
+
+pub fn log(content: String) -> Nil {
+  let log_line =
+    timestamp.system_time()
+    |> timestamp.to_rfc3339(calendar.utc_offset)
+    <> ": "
+    <> content
+    <> "\n"
+
+  // Ignore any logging errors
+  let _ = simplifile.append(filepath, log_line)
+  Nil
+}

src/musicplayer/mpv/control.gleam

@@ -1,45 +1,24 @@
+import gleam/erlang/process.{type Subject}
 import gleam/json
 import gleam/result
 import gleam/string
 
-import input/key.{type Key}
-import mpv/internal/control as internal_control
-import tcp/reason.{type Reason}
-import tcp/tcp.{type Socket}
+import musicplayer/mpv/internal as internal_control
+import musicplayer/tcp/reason.{type Reason}
+import musicplayer/tcp/tcp.{type Socket}
 
 pub type Control {
   TogglePlayPause
 
-  Search
+  GetPlaybackTime(reply_to: Subject(Result(PlaybackTime, ControlError)))
 
-  Exit
+  Exit(reply_to: Subject(Nil))
 }
 
 pub type ControlError {
   ControlError(details: String)
 }
 
-// TODO this should also have a context:
-// `/` in "artist list" "context will should be`control.Search`
-// `<some char>` in "create new playlist" context should be `control.Input`
-// `q` in most contexts should be `Exit`, but in a popup it should be `Close`
-pub fn from_key(key: Key) -> Result(Control, Nil) {
-  echo key
-  case key {
-    key.Char(char) -> char_control(char)
-    _ -> Error(Nil)
-  }
-}
-
-fn char_control(char: String) -> Result(Control, Nil) {
-  case char {
-    " " -> Ok(TogglePlayPause)
-    "q" -> Ok(Exit)
-    "/" -> Ok(Search)
-    _ -> Error(Nil)
-  }
-}
-
 pub fn toggle_play_pause(socket: Socket) -> Result(Nil, ControlError) {
   let command =
     json.object([#("command", json.array(["cycle", "pause"], of: json.string))])

src/musicplayer/mpv/mpv.gleam

@@ -0,0 +1,60 @@
+import gleam/erlang/process.{type Subject}
+import gleam/otp/actor
+import gleam/result
+import gleam/string
+
+import musicplayer/mpv/control.{type Control}
+import musicplayer/tcp/reason
+import musicplayer/tcp/tcp.{type Socket}
+
+type State(socket) {
+  State(socket: Socket)
+}
+
+pub fn new() -> Result(Subject(Control), String) {
+  // TODO start up mvp here, currently hi-jacking `naviterm`s socket
+  let socket_path = "/tmp/naviterm_mpv"
+
+  case tcp.connect(socket_path) {
+    Error(r) -> Error("Could not connect to mpv: " <> reason.to_string(r))
+    Ok(socket) -> {
+      case
+        actor.new(State(socket))
+        |> actor.on_message(handle_message)
+        |> actor.start
+      {
+        Error(start_error) ->
+          Error("Could not start mpv: " <> string.inspect(start_error))
+        Ok(actor.Started(data: mpv, ..)) -> Ok(mpv)
+      }
+    }
+  }
+}
+
+fn handle_message(
+  state: State(socket),
+  control: Control,
+) -> actor.Next(State(socket), Control) {
+  case control {
+    control.TogglePlayPause -> {
+      let _ =
+        result.map_error(control.toggle_play_pause(state.socket), fn(err) {
+          echo "Could not toggle play/pause: " <> err.details
+        })
+
+      actor.continue(state)
+    }
+
+    control.GetPlaybackTime(reply_to) -> {
+      let res = control.get_playback_time(state.socket)
+      process.send(reply_to, res)
+      actor.continue(state)
+    }
+
+    control.Exit(reply_to) -> {
+      tcp.close(state.socket)
+      process.send(reply_to, Nil)
+      actor.stop()
+    }
+  }
+}

src/musicplayer/musicplayer.gleam

@@ -0,0 +1,175 @@
+import gleam/erlang/process.{type Name, type Pid, type Subject}
+import gleam/otp/actor
+import gleam/string
+
+import musicplayer/control.{type Mode}
+import musicplayer/input/key.{type Key}
+import musicplayer/logging/logging
+import musicplayer/mpv/control as mpv_control
+import musicplayer/time/time
+import musicplayer/ui/control as ui_control
+import musicplayer/ui/layout
+
+type State {
+  State(
+    mode: Mode,
+    ui: Subject(ui_control.Control),
+    mpv: Subject(mpv_control.Control),
+  )
+}
+
+pub fn new(
+  ui: Subject(ui_control.Control),
+  mpv: Subject(mpv_control.Control),
+  input_keys_name: Name(Key),
+) -> Result(Pid, String) {
+  let input_keys = process.named_subject(input_keys_name)
+
+  case
+    actor.new(State(control.Idle, ui, mpv))
+    |> actor.on_message(handle_message)
+    |> actor.start
+  {
+    Error(start_error) ->
+      Error("Could not start actor: " <> string.inspect(start_error))
+    Ok(actor.Started(pid:, data: musicplayer)) -> {
+      logging.log("musicplayer - started")
+      process.spawn(fn() {
+        let assert Ok(_) = process.register(process.self(), input_keys_name)
+        forward_key(musicplayer, input_keys)
+      })
+
+      process.spawn(fn() { update_playback_time_loop(mpv, ui, 250) })
+
+      Ok(pid)
+    }
+  }
+}
+
+fn handle_message(state: State, key: Key) -> actor.Next(State, Key) {
+  case control.from_key(key, state.mode) {
+    Error(_) -> actor.continue(state)
+    Ok(c) ->
+      case c {
+        control.SetView(view_idx) -> {
+          logging.log(
+            "musicplayer - setting current view to: "
+            <> string.inspect(view_idx),
+          )
+
+          update_current_view(state.ui, view_idx)
+          actor.continue(state)
+        }
+        control.Search(input, capturing) -> {
+          case capturing {
+            True -> {
+              logging.log("musicplayer - searching: " <> input)
+
+              update_search(state.ui, "searching: " <> input)
+
+              actor.continue(State(..state, mode: control.Searching(input)))
+            }
+            False -> {
+              logging.log(
+                "musicplayer - recieved return. `input`: "
+                <> "'"
+                <> input
+                <> "'",
+              )
+
+              update_search(state.ui, "")
+
+              actor.continue(State(..state, mode: control.Idle))
+            }
+          }
+        }
+        control.TogglePlayPause -> {
+          logging.log("musicplayer - toggling play/pause")
+
+          process.send(state.mpv, mpv_control.TogglePlayPause)
+          update_playback_time(state.mpv, state.ui)
+          actor.continue(state)
+        }
+        control.Exit -> {
+          logging.log("musicplayer - initiating musicplayer shutdown")
+          // Close `mpv` socket
+          process.call(state.mpv, 1000, fn(reply_to) {
+            mpv_control.Exit(reply_to)
+          })
+
+          // Reset terminal state (show cursor etc.)
+          process.call(state.ui, 1000, fn(reply_to) {
+            ui_control.Exit(reply_to)
+          })
+
+          logging.log("musicplayer - stopped")
+
+          actor.stop()
+        }
+      }
+  }
+}
+
+fn update_playback_time_loop(
+  mpv: Subject(mpv_control.Control),
+  ui: Subject(ui_control.Control),
+  interval_ms: Int,
+) {
+  process.sleep(interval_ms)
+  // TODO only update if state is playing
+  update_playback_time(mpv, ui)
+
+  update_playback_time_loop(mpv, ui, interval_ms)
+}
+
+fn update_playback_time(
+  mpv: Subject(mpv_control.Control),
+  ui: Subject(ui_control.Control),
+) -> Nil {
+  case
+    process.call(mpv, 1000, fn(reply_to) {
+      mpv_control.GetPlaybackTime(reply_to)
+    })
+  {
+    Error(err) ->
+      process.send(
+        ui,
+        ui_control.UpdateHeading(
+          layout.PlaybackTime,
+          "playback time: N/A (err: " <> err.details <> ")",
+        ),
+      )
+
+    Ok(mpv_control.PlaybackTime(data: playback_time)) ->
+      process.send(
+        ui,
+        ui_control.UpdateHeading(
+          layout.PlaybackTime,
+          "playback time: " <> time.to_duration_string(playback_time),
+        ),
+      )
+  }
+}
+
+fn update_search(ui: Subject(ui_control.Control), content: String) -> Nil {
+  process.send(ui, ui_control.UpdateHeading(layout.Search, content))
+}
+
+fn update_current_view(
+  ui: Subject(ui_control.Control),
+  view_idx: layout.ViewIdx,
+) {
+  process.send(ui, ui_control.SetView(view_idx))
+}
+
+/// `forward_key` listens to a subject onto which `input` will send messages with `Key`s
+/// that is then forwarded to the `musicplayer` agent to handle
+fn forward_key(musicplayer: Subject(Key), input_keys: Subject(Key)) -> Nil {
+  let _ =
+    process.new_selector()
+    |> process.select(input_keys)
+    |> process.selector_receive_forever
+    |> process.send(musicplayer, _)
+
+  forward_key(musicplayer, input_keys)
+}

src/musicplayer/tcp/tcp.gleam

@@ -2,7 +2,7 @@ import gleam/bit_array
 import gleam/erlang/atom
 import gleam/result
 
-import tcp/reason.{type Reason}
+import musicplayer/tcp/reason.{type Reason}
 
 pub type Socket
 

src/musicplayer/time/time.gleam

@@ -0,0 +1,23 @@
+import gleam/float
+import gleam/int
+import gleam/string
+
+pub fn to_duration_string(seconds: Float) -> String {
+  let total =
+    seconds
+    |> float.max(0.0)
+    |> float.truncate
+
+  let minutes = total / 60
+  let seconds = total % 60
+
+  let mins =
+    int.to_string(minutes)
+    |> string.pad_start(to: 2, with: "0")
+
+  let secs =
+    int.to_string(seconds)
+    |> string.pad_start(to: 2, with: "0")
+
+  mins <> ":" <> secs
+}

src/musicplayer/ui/control.gleam

@@ -0,0 +1,11 @@
+import gleam/erlang/process.{type Subject}
+
+import musicplayer/ui/layout.{type Section, type ViewIdx}
+
+pub type Control {
+  UpdateDimensions(columns: Int, rows: Int)
+  UpdateHeading(section: Section, heading: String)
+  SetView(view_idx: ViewIdx)
+
+  Exit(reply_to: Subject(Nil))
+}

src/musicplayer/ui/internal.gleam

@@ -0,0 +1,41 @@
+import gleam/int
+import gleam/io
+
+// https://en.wikipedia.org/wiki/ANSI_escape_code#Control_Sequence_Introducer_commands
+
+pub const move_to_home = "\u{001B}[H"
+
+pub const disable_auto_wrap = "\u{001B}[?7l"
+
+pub const enable_auto_wrap = "\u{001B}[?7h"
+
+pub fn update(frame: String) -> Nil {
+  io.print(disable_auto_wrap <> move_to_home <> frame <> enable_auto_wrap)
+}
+
+pub fn clear_screen() -> Nil {
+  io.print("\u{001B}[2J\u{001B}[H")
+}
+
+pub fn chars_at(chars: String, x: Int, y: Int) -> String {
+  let seq = "\u{001B}[" <> int.to_string(y) <> ";" <> int.to_string(x) <> "H"
+  seq <> chars
+}
+
+pub fn hide_cursor() -> Nil {
+  io.print("\u{001B}[?25l")
+}
+
+pub fn show_cursor() -> Nil {
+  io.print("\u{001B}[?25h")
+}
+
+pub type Enotsup
+
+// https://www.erlang.org/doc/apps/stdlib/io.html#rows/0
+@external(erlang, "io", "rows")
+pub fn io_get_rows() -> Result(Int, Enotsup)
+
+// https://www.erlang.org/doc/apps/stdlib/io.html#columns/0
+@external(erlang, "io", "columns")
+pub fn io_get_columns() -> Result(Int, Enotsup)

src/musicplayer/ui/layout.gleam

@@ -0,0 +1,251 @@
+import gleam/dict
+import gleam/int
+import gleam/list
+import gleam/option.{type Option, None, Some}
+import gleam/pair
+import gleam/set
+import gleam/string
+
+import musicplayer/ui/internal
+import musicplayer/ui/plot.{type Buffer}
+import musicplayer/ui/style.{type Style, Percent, Style}
+
+pub const root_section = "reserved_root_section"
+
+pub type Section {
+  Section(String)
+
+  Header
+  Search
+  PlaybackTime
+}
+
+pub type Node {
+  Row(heading: Option(String), style: Style, children: List(Section))
+  Cell(heading: Option(String), style: Style)
+}
+
+pub type ViewIdx =
+  Int
+
+pub type View =
+  dict.Dict(Section, Node)
+
+// Layout consists of a list Views, and only one View is rendered at a time
+pub type Layout {
+  Layout(
+    columns: Int,
+    rows: Int,
+    current_view: ViewIdx,
+    views: dict.Dict(ViewIdx, View),
+  )
+}
+
+pub fn new(
+  columns: Int,
+  rows: Int,
+  views: List(List(#(Section, Node))),
+) -> Layout {
+  let views =
+    list.index_map(views, fn(view_nodes, i) { #(i, view_nodes) })
+    |> list.fold(dict.new(), fn(view_acc, iv) {
+      let #(i, view_nodes) = iv
+
+      dict.insert(view_acc, i, view_loop(i, view_nodes))
+    })
+
+  Layout(columns:, rows:, current_view: 0, views:)
+}
+
+fn view_loop(i: ViewIdx, view_nodes: List(#(Section, Node))) -> View {
+  let children =
+    view_nodes
+    |> list.flat_map(fn(node) {
+      case pair.second(node) {
+        Row(children: c, ..) -> c
+        Cell(..) -> []
+      }
+    })
+    |> set.from_list
+
+  // All sections that are not children of other nodes will be added as
+  // children to the root
+  let orphans =
+    view_nodes
+    |> list.map(pair.first)
+    |> list.filter(fn(node) { !set.contains(children, node) })
+
+  dict.from_list(view_nodes)
+  |> dict.insert(
+    view_index_section(i),
+    Row(
+      heading: None,
+      style: Style(dimensions: Percent(width: 100, height: 100), border: None),
+      children: orphans,
+    ),
+  )
+}
+
+/// Takes a ViewIndex and create a Section key from it
+fn view_index_section(view_idx: ViewIdx) -> Section {
+  Section(string.append("view_", int.to_string(view_idx)))
+}
+
+pub fn update_section_heading(
+  layout: Layout,
+  section: Section,
+  heading: String,
+) -> Layout {
+  case dict.get(layout.views, layout.current_view) {
+    Error(_) -> layout
+    Ok(view) ->
+      case dict.get(view, section) {
+        Error(_) -> layout
+        Ok(node) -> {
+          let updated_node = case node {
+            Cell(..) -> Cell(..node, heading: Some(heading))
+            Row(..) -> Row(..node, heading: Some(heading))
+          }
+
+          let updated_view = dict.insert(view, section, updated_node)
+
+          Layout(
+            ..layout,
+            views: dict.insert(layout.views, layout.current_view, updated_view),
+          )
+        }
+      }
+  }
+}
+
+pub fn update_dimensions(layout: Layout, columns: Int, rows: Int) -> Layout {
+  Layout(..layout, columns:, rows:)
+}
+
+pub fn update_current_view(layout: Layout, view_idx: ViewIdx) -> Layout {
+  Layout(..layout, current_view: view_idx)
+}
+
+pub fn render(layout: Layout) -> Nil {
+  let context =
+    RenderContext(
+      parent_width: layout.columns,
+      parent_height: layout.rows,
+      parent_top_left_x: 1,
+      parent_top_left_y: 1,
+      position_index: 0,
+    )
+
+  case dict.get(layout.views, layout.current_view) {
+    Error(_) -> Nil
+    Ok(view) -> {
+      let buffer: Buffer = dict.new()
+
+      render_loop(
+        view,
+        context,
+        view_index_section(layout.current_view),
+        buffer,
+      )
+      |> plot.flush_buffer(layout.columns, layout.rows)
+      |> internal.update
+    }
+  }
+}
+
+pub type RenderContext {
+  RenderContext(
+    parent_width: Int,
+    parent_height: Int,
+    parent_top_left_x: Int,
+    parent_top_left_y: Int,
+    position_index: Int,
+  )
+}
+
+pub fn render_loop(
+  view: View,
+  context: RenderContext,
+  from: Section,
+  buffer: Buffer,
+) -> Buffer {
+  case dict.get(view, from) {
+    Error(_) -> buffer
+    Ok(node) -> {
+      // Margin between container and the node being rendered
+      let margin = 2
+
+      let #(node_width, node_height) = case node.style.dimensions {
+        Percent(width:, height:) -> {
+          let width = { context.parent_width * width } / 100
+          let height = { context.parent_height * height } / 100
+
+          #(width, height)
+        }
+      }
+
+      // Check if this node should be placed to the left or below the parent
+      let #(node_top_left_x, node_top_left_y) = case node {
+        Row(..) -> #(
+          context.parent_top_left_x,
+          context.parent_top_left_y + { context.position_index * node_height },
+        )
+        Cell(..) -> #(
+          context.parent_top_left_x + { context.position_index * node_width },
+          context.parent_top_left_y,
+        )
+      }
+
+      let parent = case node.heading {
+        None ->
+          plot.box(
+            buffer,
+            node_top_left_x,
+            node_top_left_y,
+            node_width,
+            node_height,
+          )
+        option.Some(heading) ->
+          plot.box_with_heading(
+            buffer,
+            node_top_left_x,
+            node_top_left_y,
+            node_width,
+            node_height,
+            heading,
+          )
+      }
+
+      case node {
+        Cell(..) -> parent
+        Row(children:, ..) -> {
+          list.index_map(children, fn(child, i) { #(i, child) })
+          |> list.fold(parent, fn(acc_buffer, ic) {
+            let #(i, child) = ic
+
+            let #(child_width, child_height) = case node.style.dimensions {
+              Percent(width:, height:) -> {
+                let width = { { context.parent_width * width } / 100 } - margin
+                let height =
+                  { { context.parent_height * height } / 100 } - margin
+
+                #(width, height)
+              }
+            }
+
+            let context =
+              RenderContext(
+                parent_width: child_width,
+                parent_height: child_height,
+                parent_top_left_x: context.parent_top_left_x + 1,
+                parent_top_left_y: context.parent_top_left_y + 1,
+                position_index: i,
+              )
+
+            render_loop(view, context, child, acc_buffer)
+          })
+        }
+      }
+    }
+  }
+}

src/musicplayer/ui/layout_examples/layout_examples.gleam

@@ -0,0 +1,73 @@
+import gleam/option.{Some}
+
+import musicplayer/ui/internal
+import musicplayer/ui/layout.{Section}
+import musicplayer/ui/layout_examples/wait_for_input.{wait_for_input}
+import musicplayer/ui/style.{Percent, Style}
+
+pub fn main() {
+  let assert Ok(columns) = internal.io_get_columns()
+  let assert Ok(rows) = internal.io_get_rows()
+
+  two_rows_with_cells(columns, rows)
+  |> layout.render
+
+  wait_for_input()
+}
+
+/// Two rows:
+/// First row has two cells
+/// Second row has no cells
+fn two_rows_with_cells(columns: Int, rows: Int) -> layout.Layout {
+  let views = [
+    [
+      #(
+        Section("Row1"),
+        layout.Row(
+          heading: Some("row 1"),
+          style: Style(
+            dimensions: Percent(width: 100, height: 50),
+            border: Some(style.BorderSingle),
+          ),
+          children: [
+            Section("A"),
+            Section("B"),
+          ],
+        ),
+      ),
+      #(
+        Section("A"),
+        layout.Cell(
+          heading: Some("cell 1"),
+          style: Style(
+            dimensions: Percent(width: 50, height: 50),
+            border: Some(style.BorderSingle),
+          ),
+        ),
+      ),
+      #(
+        Section("B"),
+        layout.Cell(
+          heading: Some("cell 2"),
+          style: Style(
+            dimensions: Percent(width: 50, height: 50),
+            border: Some(style.BorderSingle),
+          ),
+        ),
+      ),
+      #(
+        Section("Row2"),
+        layout.Row(
+          heading: Some("row 2"),
+          style: Style(
+            dimensions: Percent(width: 50, height: 50),
+            border: Some(style.BorderSingle),
+          ),
+          children: [],
+        ),
+      ),
+    ],
+  ]
+
+  layout.new(columns, rows, views)
+}

src/musicplayer/ui/layout_examples/wait_for_input.gleam

@@ -0,0 +1,15 @@
+import gleam/erlang/process.{type Name}
+
+import musicplayer/input/input
+import musicplayer/input/key.{type Key}
+
+pub fn wait_for_input() {
+  let input_keys_name: Name(Key) = process.new_name("input_keys")
+  let assert Ok(_) = process.register(process.self(), input_keys_name)
+
+  input.new(input_keys_name)
+
+  process.new_selector()
+  |> process.select(process.named_subject(input_keys_name))
+  |> process.selector_receive_forever
+}

src/musicplayer/ui/plot.gleam

@@ -0,0 +1,85 @@
+import gleam/dict.{type Dict}
+import gleam/list
+import gleam/string
+
+pub type Buffer =
+  Dict(#(Int, Int), String)
+
+pub fn flush_buffer(buffer: Buffer, columns: Int, rows: Int) -> String {
+  list.range(1, rows)
+  |> list.map(fn(y) {
+    list.range(1, columns)
+    |> list.map(fn(x) {
+      case dict.get(buffer, #(x, y)) {
+        Ok(char) -> char
+        Error(_) -> " "
+      }
+    })
+    |> string.join("")
+  })
+  |> string.join("\r\n")
+}
+
+pub fn text(buffer: Buffer, text: String, x: Int, y: Int) -> Buffer {
+  text
+  |> string.to_graphemes
+  |> list.index_fold(buffer, fn(acc, char, i) {
+    dict.insert(acc, #(x + i, y), char)
+  })
+}
+
+pub fn box(buffer: Buffer, x: Int, y: Int, width: Int, height: Int) -> Buffer {
+  // TODO move box style to `layout.Style`
+  let box_chars = #("┌", "┐", "└", "┘", "─", "│")
+  let #(tl, tr, bl, br, hor, ver) = box_chars
+
+  case width < 2 || height < 2 {
+    True -> buffer
+    False -> {
+      buffer
+      |> dict.insert(#(x, y), tl)
+      |> dict.insert(#(x + width - 1, y), tr)
+      |> dict.insert(#(x, y + height - 1), bl)
+      |> dict.insert(#(x + width - 1, y + height - 1), br)
+      |> horizontal_line(x + 1, y, width - 2, hor)
+      |> horizontal_line(x + 1, y + height - 1, width - 2, hor)
+      |> vertical_line(x, y + 1, height - 2, ver)
+      |> vertical_line(x + width - 1, y + 1, height - 2, ver)
+    }
+  }
+}
+
+pub fn box_with_heading(
+  buffer: Buffer,
+  x: Int,
+  y: Int,
+  width: Int,
+  height: Int,
+  heading: String,
+) -> Buffer {
+  let heading_margin = 1
+  box(buffer, x, y, width, height)
+  |> text(heading, x + heading_margin, y)
+}
+
+fn horizontal_line(
+  buffer: Buffer,
+  x: Int,
+  y: Int,
+  len: Int,
+  char: String,
+) -> Buffer {
+  list.range(0, len - 1)
+  |> list.fold(buffer, fn(acc, i) { dict.insert(acc, #(x + i, y), char) })
+}
+
+fn vertical_line(
+  buffer: Buffer,
+  x: Int,
+  y: Int,
+  len: Int,
+  char: String,
+) -> Buffer {
+  list.range(0, len - 1)
+  |> list.fold(buffer, fn(acc, i) { dict.insert(acc, #(x, y + i), char) })
+}

src/musicplayer/ui/style.gleam

@@ -0,0 +1,34 @@
+import gleam/option.{type Option}
+
+pub type Dimension {
+  Percent(width: Int, height: Int)
+  // TODO add Flex that flows
+}
+
+pub type Border {
+  BorderNone
+  BorderSingle
+}
+
+pub type Style {
+  Style(dimensions: Dimension, border: Option(Border))
+}
+
+pub type BorderChars {
+  BorderChars(
+    top_left: String,
+    top_right: String,
+    bottom_left: String,
+    bottom_right: String,
+    horisontal: String,
+    vertical: String,
+  )
+}
+
+// https://en.wikipedia.org/wiki/Box-drawing_characters
+pub fn border_chars(border: Border) -> BorderChars {
+  case border {
+    BorderNone -> BorderChars("", "", "", "", "", "")
+    BorderSingle -> BorderChars("┌", "┐", "└", "┘", "─", "│")
+  }
+}

src/musicplayer/ui/ui.gleam

@@ -0,0 +1,175 @@
+import gleam/erlang/process.{type Subject}
+import gleam/int
+import gleam/list
+import gleam/option.{None, Some}
+import gleam/otp/actor
+import gleam/string
+
+import musicplayer/logging/logging
+import musicplayer/ui/control.{type Control}
+import musicplayer/ui/internal
+import musicplayer/ui/layout.{type Layout}
+import musicplayer/ui/style
+
+pub type State(redraw, content) {
+  State(redraw: Subject(Layout), layout: Layout)
+}
+
+pub fn new() -> Result(Subject(Control), String) {
+  let redraw_name = process.new_name("redraw")
+  let redraw: Subject(Layout) = process.named_subject(redraw_name)
+
+  let layout =
+    [
+      [
+        #(
+          layout.Header,
+          layout.Row(
+            heading: Some("Foo <1> | Bar (2)"),
+            style: style.Style(
+              dimensions: style.Percent(width: 100, height: 50),
+              border: Some(style.BorderSingle),
+            ),
+            children: [],
+          ),
+        ),
+        #(
+          layout.PlaybackTime,
+          layout.Row(
+            heading: None,
+            style: style.Style(
+              dimensions: style.Percent(width: 100, height: 50),
+              border: Some(style.BorderSingle),
+            ),
+            children: [],
+          ),
+        ),
+      ],
+      [
+        #(
+          layout.Header,
+          layout.Row(
+            heading: Some("Foo (1) | Bar <2>"),
+            style: style.Style(
+              dimensions: style.Percent(width: 100, height: 33),
+              border: Some(style.BorderSingle),
+            ),
+            children: [],
+          ),
+        ),
+        #(
+          layout.Search,
+          layout.Row(
+            heading: None,
+            style: style.Style(
+              dimensions: style.Percent(width: 100, height: 33),
+              border: Some(style.BorderSingle),
+            ),
+            children: [],
+          ),
+        ),
+        #(
+          layout.PlaybackTime,
+          layout.Row(
+            heading: None,
+            style: style.Style(
+              dimensions: style.Percent(width: 100, height: 33),
+              border: Some(style.BorderSingle),
+            ),
+            children: [],
+          ),
+        ),
+      ],
+    ]
+    |> layout.new(0, 0, _)
+
+  case
+    actor.new(State(redraw, layout))
+    |> actor.on_message(handle_message)
+    |> actor.start
+  {
+    Error(start_error) ->
+      Error("Could not start actor: " <> string.inspect(start_error))
+    Ok(actor.Started(data: ui, ..)) -> {
+      process.spawn(fn() {
+        let update_dimensions_interval_ms = 300
+        update_dimensions_on_interval(ui, update_dimensions_interval_ms)
+      })
+
+      process.spawn(fn() {
+        let assert Ok(_) = process.register(process.self(), redraw_name)
+
+        internal.clear_screen()
+        internal.hide_cursor()
+
+        redraw_loop(redraw)
+      })
+
+      Ok(ui)
+    }
+  }
+}
+
+fn handle_message(
+  state: State(redraw, layout),
+  control: Control,
+) -> actor.Next(State(redraw, layout), Control) {
+  case control {
+    control.UpdateDimensions(columns, rows) -> {
+      let current_dimensions = #(state.layout.columns, state.layout.rows)
+
+      case #(columns, rows) == current_dimensions {
+        True -> actor.continue(state)
+        False -> {
+          [columns, rows]
+          |> list.map(int.to_string)
+          |> string.join(" ")
+          |> string.append("ui - updating dimensions: ", _)
+          |> logging.log
+
+          let layout = layout.update_dimensions(state.layout, columns, rows)
+
+          process.send(state.redraw, layout)
+          actor.continue(State(..state, layout:))
+        }
+      }
+    }
+    control.UpdateHeading(section, heading) -> {
+      let layout = layout.update_section_heading(state.layout, section, heading)
+
+      actor.send(state.redraw, layout)
+      actor.continue(State(..state, layout:))
+    }
+
+    control.Exit(reply_to) -> {
+      internal.show_cursor()
+      process.send(reply_to, Nil)
+      actor.stop()
+    }
+    control.SetView(view_idx) -> {
+      let layout = layout.update_current_view(state.layout, view_idx)
+
+      actor.send(state.redraw, layout)
+      actor.continue(State(..state, layout:))
+    }
+  }
+}
+
+fn redraw_loop(redraw: Subject(Layout)) -> Nil {
+  process.receive_forever(redraw)
+  |> layout.render
+
+  redraw_loop(redraw)
+}
+
+fn update_dimensions_on_interval(ui: Subject(Control), interval_ms: Int) {
+  case internal.io_get_columns(), internal.io_get_rows() {
+    Ok(width), Ok(height) -> {
+      process.send(ui, control.UpdateDimensions(width, height))
+    }
+    _, _ -> logging.log("ui - failed to update dimensions")
+  }
+
+  process.sleep(interval_ms)
+  update_dimensions_on_interval(ui, interval_ms)
+}

test/echo_server.gleam

@@ -4,8 +4,8 @@ import gleam/otp/actor
 import gleam/result
 import gleam/string
 
-import tcp/reason.{type Reason}
-import tcp/tcp
+import musicplayer/tcp/reason.{type Reason}
+import musicplayer/tcp/tcp
 
 pub type Message {
   Shutdown

test/mpv/control_test.gleam

@@ -1,33 +0,0 @@
-import gleam/list
-import gleeunit
-
-import input/key.{type Key, Char}
-import mpv/control.{type Control}
-import mpv/internal/control as control_internal
-
-pub fn main() -> Nil {
-  gleeunit.main()
-}
-
-type TestCase {
-  TestCase(key: Key, expected: Result(Control, Nil))
-}
-
-pub fn control_from_key_test() {
-  let test_cases = [
-    TestCase(Char(" "), Ok(control.TogglePlayPause)),
-    TestCase(Char("q"), Ok(control.Exit)),
-  ]
-
-  list.each(test_cases, fn(tc) {
-    assert tc.expected == control.from_key(tc.key)
-  })
-}
-
-pub fn parse_playback_time_test() {
-  let json_string =
-    "{\"data\":\"123.456789\",\"request_id\":0,\"error\":\"success\"}\n"
-
-  let assert Ok(data) = control_internal.parse_playback_time(json_string)
-  assert data == 123.456789
-}

test/musicplayer/control_test.gleam

@@ -0,0 +1,32 @@
+import gleam/list
+import gleeunit
+
+import musicplayer/control.{type Control, type Mode}
+import musicplayer/input/key.{type Key, Char}
+
+pub fn main() -> Nil {
+  gleeunit.main()
+}
+
+type TestCase {
+  TestCase(key: Key, mode: Mode, expected: Result(Control, Nil))
+}
+
+pub fn control_from_key_test() {
+  let idle_tests = [
+    TestCase(Char(" "), control.Idle, Ok(control.TogglePlayPause)),
+    TestCase(Char("/"), control.Idle, Ok(control.Search("", True))),
+    TestCase(Char("q"), control.Idle, Ok(control.Exit)),
+  ]
+
+  let search_tests = [
+    TestCase(Char("a"), control.Searching(""), Ok(control.Search("a", True))),
+    TestCase(Char("b"), control.Searching("a"), Ok(control.Search("ab", True))),
+  ]
+
+  let test_cases = [idle_tests, search_tests]
+
+  list.each(list.flatten(test_cases), fn(tc) {
+    assert tc.expected == control.from_key(tc.key, tc.mode)
+  })
+}

test/musicplayer/input/input_test.gleam

@@ -1,7 +1,7 @@
 import gleam/list
 import gleeunit
 
-import input/key.{type Key, Char, csi, esc, input_introducer as ii}
+import musicplayer/input/key.{type Key, Char, backspace, csi, esc, return}
 
 pub fn main() -> Nil {
   gleeunit.main()
@@ -27,10 +27,8 @@ pub fn key_from_list_test() {
   ]
 
   let input_tests = [
-    TestCase([ii], key.Continue([ii])),
-    TestCase([ii, "a"], key.Continue([ii, "a"])),
-    TestCase([ii, "a", "b"], key.Continue([ii, "ab"])),
-    TestCase([ii, "ab", "\r"], key.Input("ab")),
+    TestCase([return], key.Return),
+    TestCase([backspace], key.Backspace),
   ]
 
   let test_cases = [base_tests, char_tests, escape_tests, input_tests]

test/musicplayer/mpv/mpv_test.gleam

@@ -0,0 +1,15 @@
+import gleeunit
+
+import musicplayer/mpv/internal
+
+pub fn main() -> Nil {
+  gleeunit.main()
+}
+
+pub fn parse_playback_time_test() {
+  let json_string =
+    "{\"data\":\"123.456789\",\"request_id\":0,\"error\":\"success\"}\n"
+
+  let assert Ok(data) = internal.parse_playback_time(json_string)
+  assert data == 123.456789
+}

test/musicplayer/tcp/tcp_test.gleam

@@ -3,7 +3,7 @@ import gleeunit
 import simplifile
 
 import echo_server
-import tcp/tcp
+import musicplayer/tcp/tcp
 
 pub fn main() -> Nil {
   gleeunit.main()

test/musicplayer/time/time_test.gleam

@@ -0,0 +1,32 @@
+import gleam/list
+import gleeunit
+
+import musicplayer/time/time
+
+pub fn main() -> Nil {
+  gleeunit.main()
+}
+
+type TestCase {
+  TestCase(seconds: Float, expected: String)
+}
+
+pub fn to_duration_string_test() {
+  let test_cases = [
+    TestCase(-1.0, "00:00"),
+    TestCase(0.0, "00:00"),
+    TestCase(9.0, "00:09"),
+    TestCase(10.0, "00:10"),
+    TestCase(11.0, "00:11"),
+    TestCase(60.0, "01:00"),
+    TestCase(61.0, "01:01"),
+    TestCase(120.0, "02:00"),
+    TestCase(600.0, "10:00"),
+    TestCase(6000.0, "100:00"),
+    TestCase(6001.0, "100:01"),
+  ]
+
+  list.each(test_cases, fn(tc) {
+    assert tc.expected == time.to_duration_string(tc.seconds)
+  })
+}

test/musicplayer/ui/layout_test.gleam

@@ -0,0 +1,130 @@
+import gleam/dict
+import gleam/io
+import gleam/option.{Some}
+import gleam/string
+import gleeunit
+import gleeunit/should
+
+import musicplayer/ui/layout.{RenderContext, Section}
+import musicplayer/ui/plot
+import musicplayer/ui/style.{Percent, Style}
+
+pub fn main() -> Nil {
+  gleeunit.main()
+}
+
+pub fn percent_layout_test() {
+  let views = [
+    [
+      #(
+        Section("Row1"),
+        layout.Row(
+          heading: Some("row 1"),
+          style: Style(
+            dimensions: Percent(width: 100, height: 50),
+            border: Some(style.BorderSingle),
+          ),
+          children: [
+            Section("A"),
+            Section("B"),
+          ],
+        ),
+      ),
+      #(
+        Section("A"),
+        layout.Cell(
+          heading: Some("cell 1"),
+          style: Style(
+            dimensions: Percent(width: 50, height: 100),
+            border: Some(style.BorderSingle),
+          ),
+        ),
+      ),
+      #(
+        Section("B"),
+        layout.Cell(
+          heading: Some("cell 2"),
+          style: Style(
+            dimensions: Percent(width: 50, height: 100),
+            border: Some(style.BorderSingle),
+          ),
+        ),
+      ),
+      #(
+        Section("Row2"),
+        layout.Row(
+          heading: Some("row 1"),
+          style: Style(
+            dimensions: Percent(width: 100, height: 50),
+            border: Some(style.BorderSingle),
+          ),
+          children: [],
+        ),
+      ),
+    ],
+  ]
+
+  let columns = 80
+  let rows = 20
+  let layout = layout.new(columns, rows, views)
+
+  let expected =
+    "
+┌──────────────────────────────────────────────────────────────────────────────┐
+│┌row 1───────────────────────────────────────────────────────────────────────┐│
+││┌cell 1──────────────────────────────┐┌cell 2──────────────────────────────┐││
+│││                                    ││                                    │││
+│││                                    ││                                    │││
+│││                                    ││                                    │││
+│││                                    ││                                    │││
+│││                                    ││                                    │││
+││└────────────────────────────────────┘└────────────────────────────────────┘││
+│└────────────────────────────────────────────────────────────────────────────┘│
+│┌row 1───────────────────────────────────────────────────────────────────────┐│
+││                                                                            ││
+││                                                                            ││
+││                                                                            ││
+││                                                                            ││
+││                                                                            ││
+││                                                                            ││
+││                                                                            ││
+│└────────────────────────────────────────────────────────────────────────────┘│
+└──────────────────────────────────────────────────────────────────────────────┘
+"
+    |> string.replace(each: "\n", with: "\r\n")
+    |> string.trim
+
+  let context =
+    RenderContext(
+      parent_width: layout.columns,
+      parent_height: layout.rows,
+      parent_top_left_x: 1,
+      parent_top_left_y: 1,
+      position_index: 0,
+    )
+
+  let assert Ok(view) = dict.get(layout.views, layout.current_view)
+
+  let flushed =
+    layout.render_loop(
+      view,
+      context,
+      Section(string.append("view_", string.inspect(layout.current_view))),
+      dict.new(),
+    )
+    |> plot.flush_buffer(layout.columns, layout.rows)
+
+  case flushed == expected {
+    True -> Nil
+    False -> {
+      io.println("Test failed")
+      io.println("Expected:")
+      io.println(string.trim(expected))
+
+      io.println("Got:")
+      io.println(flushed)
+
+      should.equal(flushed, expected)
+    }
+  }
+}