Send some messages

gleam.toml

@@ -14,11 +14,6 @@ version = "1.0.0"
 
 [dependencies]
 gleam_stdlib = ">= 0.44.0 and < 2.0.0"
-gleam_otp = ">= 1.2.0 and < 2.0.0"
-gleam_erlang = ">= 1.3.0 and < 2.0.0"
-simplifile = ">= 2.3.1 and < 3.0.0"
-gleam_json = ">= 3.1.0 and < 4.0.0"
-gleam_time = ">= 1.6.0 and < 2.0.0"
 
 [dev-dependencies]
 gleeunit = ">= 1.0.0 and < 2.0.0"

manifest.toml

@@ -2,21 +2,10 @@
 # You typically do not need to edit this file
 
 packages = [
-  { name = "filepath", version = "1.1.2", build_tools = ["gleam"], requirements = ["gleam_stdlib"], otp_app = "filepath", source = "hex", outer_checksum = "B06A9AF0BF10E51401D64B98E4B627F1D2E48C154967DA7AF4D0914780A6D40A" },
-  { name = "gleam_erlang", version = "1.3.0", build_tools = ["gleam"], requirements = ["gleam_stdlib"], otp_app = "gleam_erlang", source = "hex", outer_checksum = "1124AD3AA21143E5AF0FC5CF3D9529F6DB8CA03E43A55711B60B6B7B3874375C" },
-  { name = "gleam_json", version = "3.1.0", build_tools = ["gleam"], requirements = ["gleam_stdlib"], otp_app = "gleam_json", source = "hex", outer_checksum = "44FDAA8847BE8FC48CA7A1C089706BD54BADCC4C45B237A992EDDF9F2CDB2836" },
-  { name = "gleam_otp", version = "1.2.0", build_tools = ["gleam"], requirements = ["gleam_erlang", "gleam_stdlib"], otp_app = "gleam_otp", source = "hex", outer_checksum = "BA6A294E295E428EC1562DC1C11EA7530DCB981E8359134BEABC8493B7B2258E" },
   { name = "gleam_stdlib", version = "0.65.0", build_tools = ["gleam"], requirements = [], otp_app = "gleam_stdlib", source = "hex", outer_checksum = "7C69C71D8C493AE11A5184828A77110EB05A7786EBF8B25B36A72F879C3EE107" },
-  { name = "gleam_time", version = "1.6.0", build_tools = ["gleam"], requirements = ["gleam_stdlib"], otp_app = "gleam_time", source = "hex", outer_checksum = "0DF3834D20193F0A38D0EB21F0A78D48F2EC276C285969131B86DF8D4EF9E762" },
   { name = "gleeunit", version = "1.9.0", build_tools = ["gleam"], requirements = ["gleam_stdlib"], otp_app = "gleeunit", source = "hex", outer_checksum = "DA9553CE58B67924B3C631F96FE3370C49EB6D6DC6B384EC4862CC4AAA718F3C" },
-  { name = "simplifile", version = "2.3.1", build_tools = ["gleam"], requirements = ["filepath", "gleam_stdlib"], otp_app = "simplifile", source = "hex", outer_checksum = "957E0E5B75927659F1D2A1B7B75D7B9BA96FAA8D0C53EA71C4AD9CD0C6B848F6" },
 ]
 
 [requirements]
-gleam_erlang = { version = ">= 1.3.0 and < 2.0.0" }
-gleam_json = { version = ">= 3.1.0 and < 4.0.0" }
-gleam_otp = { version = ">= 1.2.0 and < 2.0.0" }
 gleam_stdlib = { version = ">= 0.44.0 and < 2.0.0" }
-gleam_time = { version = ">= 1.6.0 and < 2.0.0" }
 gleeunit = { version = ">= 1.0.0 and < 2.0.0" }
-simplifile = { version = ">= 2.3.1 and < 3.0.0" }

src/ipc.gleam

@@ -0,0 +1,59 @@
+import gleam/bytes_tree
+
+pub type Socket
+
+// https://www.erlang.org/doc/apps/kernel/inet#t:address_family/0
+// local socket
+type Local {
+  Local(socket_path: String)
+}
+
+type ModeValue {
+  Binary
+}
+
+type IPCOption {
+  Active(Bool)
+  Mode(ModeValue)
+}
+
+pub type IPCError {
+  IPCError(reason: String)
+}
+
+pub fn connect(socket_path: String) -> Result(Socket, IPCError) {
+  let options = [Mode(Binary), Active(False)]
+
+  // timeout in ms
+  let timeout = 1000
+
+  gen_tcp_connect(Local(socket_path), 0, options, timeout)
+}
+
+pub fn send(socket: Socket, message: String) -> Result(Nil, IPCError) {
+  gen_tcp_send(socket, bytes_tree.from_string(message))
+}
+
+pub fn close(socket: Socket) -> Nil {
+  gen_tcp_close(socket)
+}
+
+// https://www.erlang.org/doc/apps/kernel/gen_tcp.html#connect/4
+@external(erlang, "gen_tcp", "connect")
+fn gen_tcp_connect(
+  address: Local,
+  port: Int,
+  options: List(IPCOption),
+  timeout: Int,
+) -> Result(Socket, IPCError)
+
+// https://www.erlang.org/doc/apps/kernel/gen_tcp.html#send/2
+@external(erlang, "ipc_ffi", "send")
+fn gen_tcp_send(
+  socket: Socket,
+  packet: bytes_tree.BytesTree,
+) -> Result(Nil, IPCError)
+
+// https://www.erlang.org/doc/apps/kernel/gen_tcp.html#close/1
+@external(erlang, "gen_tcp", "close")
+fn gen_tcp_close(socket: Socket) -> Nil

src/ipc_ffi.erl

@@ -0,0 +1,8 @@
+-module(ipc_ffi).
+-export([send/2]).
+
+send(Socket, Packet) ->
+  case gen_tcp:send(Socket, Packet) of
+    ok -> {ok, nil};
+    Res -> Res
+  end.

src/musicplayer.gleam

@@ -1,24 +1,37 @@
-import gleam/erlang/process.{type Name}
+import gleam/io
-
+import ipc
-import musicplayer/input/input
-import musicplayer/input/key.{type Key}
-import musicplayer/logging/logging
-import musicplayer/mpv/mpv
-import musicplayer/musicplayer
-import musicplayer/ui/ui
 
 pub fn main() -> Nil {
-  let assert Ok(_) = logging.initialize()
+  let socket_path = "/tmp/musicplayer.sock"
 
-  let input_keys_name: Name(Key) = process.new_name("input_keys")
+  case ipc.connect(socket_path) {
-  input.new(input_keys_name)
+    Error(err) -> io.println("Failed to connect to socket: " <> err.reason)
+    Ok(socket) -> {
+      io.println("connected")
 
-  let assert Ok(ui) = ui.new()
+      let messages = ["hello, \n", "world!\n"]
-  let assert Ok(mpv) = mpv.new()
-  let assert Ok(musicplayer_pid) = musicplayer.new(ui, mpv, input_keys_name)
 
-  let monitor = process.monitor(musicplayer_pid)
+      messages |> send_messages(socket, _)
-  process.new_selector()
+
-  |> process.select_specific_monitor(monitor, fn(_) { Nil })
+      io.println("closing")
-  |> process.selector_receive_forever
+      ipc.close(socket)
+    }
+  }
+}
+
+fn send_messages(socket: ipc.Socket, messages: List(String)) -> Nil {
+  case messages {
+    [] -> Nil
+    [message, ..rest] -> {
+      send_message(socket, message)
+      send_messages(socket, rest)
+    }
+  }
+}
+
+fn send_message(socket: ipc.Socket, message: String) -> Nil {
+  case ipc.send(socket, message) {
+    Error(err) -> io.println("Failed to send message to socket: " <> err.reason)
+    Ok(_) -> io.println("Sent message to socket")
+  }
 }

src/musicplayer/control.gleam

@@ -1,30 +0,0 @@
-import musicplayer/input/key.{type Key}
-
-pub type Control {
-  TogglePlayPause
-  Search
-
-  Raw(String)
-  Return
-  Backspace
-
-  Exit
-}
-
-pub fn from_key(key: Key) -> Result(Control, Nil) {
-  case key {
-    key.Return -> Ok(Return)
-    key.Backspace -> Ok(Backspace)
-    key.Char(char) -> Ok(char_control(char))
-    _ -> Error(Nil)
-  }
-}
-
-fn char_control(char: String) -> Control {
-  case char {
-    " " -> TogglePlayPause
-    "/" -> Search
-    "q" -> Exit
-    _ -> Raw(char)
-  }
-}

src/musicplayer/input/input.gleam

@@ -1,15 +0,0 @@
-import gleam/erlang/process.{type Name}
-
-import musicplayer/input/key.{type Key}
-
-/// `new` accepts a subject that all input will be sent to
-pub fn new(input_keys_name: Name(Key)) -> Nil {
-  let _ =
-    process.spawn(fn() {
-      let input_keys = process.named_subject(input_keys_name)
-      key.read_input_until_key(input_keys)
-    })
-
-  key.start_raw_shell()
-  Nil
-}

src/musicplayer/input/internal.gleam

@@ -1,15 +0,0 @@
-import gleam/erlang/atom
-
-pub fn read_input() -> String {
-  io_get_chars("", 1)
-}
-
-pub type NotUsed
-
-// https://www.erlang.org/doc/apps/stdlib/shell.html#start_interactive/1
-@external(erlang, "shell", "start_interactive")
-pub fn shell_start_interactive(options: #(atom.Atom, atom.Atom)) -> NotUsed
-
-// https://www.erlang.org/doc/apps/stdlib/io.html#get_chars/2
-@external(erlang, "io", "get_chars")
-fn io_get_chars(prompt: String, count: Int) -> String

src/musicplayer/input/key.gleam

@@ -1,76 +0,0 @@
-import gleam/erlang/atom
-import gleam/erlang/process.{type Subject}
-import gleam/list
-
-import musicplayer/input/internal as internal_input
-
-pub type Key {
-  Continue(buffer: List(String))
-  Char(String)
-
-  Left
-  Right
-  Up
-  Down
-
-  Return
-  Backspace
-
-  Unknown
-}
-
-pub const esc = "\u{001B}"
-
-// control sequence introducer
-pub const csi = "["
-
-pub const return = "\r"
-
-pub const backspace = "\u{007F}"
-
-pub fn from_list(l: List(String)) -> Key {
-  case l {
-    [e, c, "D"] if e == esc && c == csi -> Left
-    [e, c, "C"] if e == esc && c == csi -> Right
-    [e, c, "A"] if e == esc && c == csi -> Up
-    [e, c, "B"] if e == esc && c == csi -> Down
-
-    [e, c] if e == esc && c == csi -> Continue(l)
-
-    [e] if e == esc -> Continue(l)
-    [bs] if bs == backspace -> Backspace
-    [rtn] if rtn == return -> Return
-    [char] -> Char(char)
-
-    [] -> Continue([])
-    _ -> Unknown
-  }
-}
-
-pub fn start_raw_shell() {
-  let no_shell = atom.create("noshell")
-  let raw = atom.create("raw")
-  internal_input.shell_start_interactive(#(no_shell, raw))
-}
-
-pub fn read_input_until_key(input_keys: Subject(Key)) -> Nil {
-  read_input_until_key_loop([], input_keys)
-}
-
-pub fn read_input_until_key_loop(
-  l: List(String),
-  input_keys: Subject(Key),
-) -> Nil {
-  case
-    internal_input.read_input()
-    |> list.wrap
-    |> list.append(l, _)
-    |> from_list
-  {
-    Continue(l) -> read_input_until_key_loop(l, input_keys)
-    k -> {
-      process.send(input_keys, k)
-      read_input_until_key_loop([], input_keys)
-    }
-  }
-}

src/musicplayer/logging/control.gleam

@@ -1,5 +0,0 @@
-pub type Control {
-  Write(String)
-
-  Exit
-}

src/musicplayer/logging/logging.gleam

@@ -1,30 +0,0 @@
-import gleam/result
-import gleam/string
-import gleam/time/calendar
-import gleam/time/timestamp
-import simplifile
-
-const filepath = "/tmp/musicplayer.log"
-
-pub fn initialize() -> Result(Nil, String) {
-  case simplifile.is_file(filepath) {
-    Ok(True) -> Ok(Nil)
-    _ -> simplifile.create_file(filepath)
-  }
-  |> result.map_error(fn(e) {
-    "Could not access or create log file: " <> string.inspect(e)
-  })
-}
-
-pub fn log(content: String) -> Nil {
-  let log_line =
-    timestamp.system_time()
-    |> timestamp.to_rfc3339(calendar.utc_offset)
-    <> ": "
-    <> content
-    <> "\n"
-
-  // Ignore any logging errors
-  let _ = simplifile.append(filepath, log_line)
-  Nil
-}

src/musicplayer/mpv/control.gleam

@@ -1,61 +0,0 @@
-import gleam/erlang/process.{type Subject}
-import gleam/json
-import gleam/result
-import gleam/string
-
-import musicplayer/mpv/internal as internal_control
-import musicplayer/tcp/reason.{type Reason}
-import musicplayer/tcp/tcp.{type Socket}
-
-pub type Control {
-  TogglePlayPause
-
-  GetPlaybackTime(reply_to: Subject(Result(PlaybackTime, ControlError)))
-
-  Exit(reply_to: Subject(Nil))
-}
-
-pub type ControlError {
-  ControlError(details: String)
-}
-
-pub fn toggle_play_pause(socket: Socket) -> Result(Nil, ControlError) {
-  let command =
-    json.object([#("command", json.array(["cycle", "pause"], of: json.string))])
-
-  case send_command(socket, command) {
-    Error(r) -> Error(ControlError(reason.to_string(r)))
-    Ok(_) -> Ok(Nil)
-  }
-}
-
-// https://mpv.io/manual/master/#command-interface-playback-time
-pub type PlaybackTime {
-  PlaybackTime(data: Float)
-}
-
-pub fn get_playback_time(socket: Socket) -> Result(PlaybackTime, ControlError) {
-  let command =
-    json.object([
-      #(
-        "command",
-        json.array(["get_property_string", "playback-time"], of: json.string),
-      ),
-    ])
-
-  case send_command(socket, command) {
-    Error(r) -> Error(ControlError(reason.to_string(r)))
-    Ok(json_string) ->
-      case internal_control.parse_playback_time(json_string) {
-        Error(e) -> Error(ControlError(string.inspect(e)))
-        Ok(data) -> Ok(PlaybackTime(data))
-      }
-  }
-}
-
-fn send_command(socket: Socket, command: json.Json) -> Result(String, Reason) {
-  result.try(tcp.send(socket, json.to_string(command) <> "\n"), fn(_) {
-    let timeout_ms = 10_000
-    tcp.receive(socket, timeout_ms)
-  })
-}

src/musicplayer/mpv/internal.gleam

@@ -1,25 +0,0 @@
-import gleam/dynamic/decode
-import gleam/float
-import gleam/json
-import gleam/string
-
-pub fn parse_playback_time(
-  json_string: String,
-) -> Result(Float, json.DecodeError) {
-  let decoder = {
-    let float_dececoder = fn(data_string) {
-      case float.parse(data_string) {
-        Error(_) -> decode.failure(0.0, "data")
-        Ok(float_value) -> decode.success(float_value)
-      }
-    }
-    use data <- decode.field(
-      "data",
-      decode.then(decode.string, float_dececoder),
-    )
-
-    decode.success(data)
-  }
-
-  json.parse(from: string.trim(json_string), using: decoder)
-}

src/musicplayer/mpv/mpv.gleam

@@ -1,60 +0,0 @@
-import gleam/erlang/process.{type Subject}
-import gleam/otp/actor
-import gleam/result
-import gleam/string
-
-import musicplayer/mpv/control.{type Control}
-import musicplayer/tcp/reason
-import musicplayer/tcp/tcp.{type Socket}
-
-type State(socket) {
-  State(socket: Socket)
-}
-
-pub fn new() -> Result(Subject(Control), String) {
-  // TODO start up mvp here, currently hi-jacking `naviterm`s socket
-  let socket_path = "/tmp/naviterm_mpv"
-
-  case tcp.connect(socket_path) {
-    Error(r) -> Error("Could not connect to mpv: " <> reason.to_string(r))
-    Ok(socket) -> {
-      case
-        actor.new(State(socket))
-        |> actor.on_message(handle_message)
-        |> actor.start
-      {
-        Error(start_error) ->
-          Error("Could not start mpv: " <> string.inspect(start_error))
-        Ok(actor.Started(data: mpv, ..)) -> Ok(mpv)
-      }
-    }
-  }
-}
-
-fn handle_message(
-  state: State(socket),
-  control: Control,
-) -> actor.Next(State(socket), Control) {
-  case control {
-    control.TogglePlayPause -> {
-      let _ =
-        result.map_error(control.toggle_play_pause(state.socket), fn(err) {
-          echo "Could not toggle play/pause: " <> err.details
-        })
-
-      actor.continue(state)
-    }
-
-    control.GetPlaybackTime(reply_to) -> {
-      let res = control.get_playback_time(state.socket)
-      process.send(reply_to, res)
-      actor.continue(state)
-    }
-
-    control.Exit(reply_to) -> {
-      tcp.close(state.socket)
-      process.send(reply_to, Nil)
-      actor.stop()
-    }
-  }
-}

src/musicplayer/musicplayer.gleam

@@ -1,197 +0,0 @@
-import gleam/erlang/process.{type Name, type Pid, type Subject}
-import gleam/otp/actor
-import gleam/result
-import gleam/string
-
-import musicplayer/control.{type Control}
-import musicplayer/input/key.{type Key}
-import musicplayer/logging/logging
-import musicplayer/mpv/control as mpv_control
-import musicplayer/time/time
-import musicplayer/ui/control as ui_control
-import musicplayer/ui/layout
-
-type Mode {
-  Idle
-  Searching
-}
-
-type Input {
-  Input(capturing: Bool, content: String)
-}
-
-type State {
-  State(
-    mode: Mode,
-    input: Input,
-    ui: Subject(ui_control.Control),
-    mpv: Subject(mpv_control.Control),
-  )
-}
-
-pub fn new(
-  ui: Subject(ui_control.Control),
-  mpv: Subject(mpv_control.Control),
-  input_keys_name: Name(Key),
-) -> Result(Pid, String) {
-  let input_keys = process.named_subject(input_keys_name)
-
-  let input = Input(False, "")
-
-  case
-    actor.new(State(Idle, input, ui, mpv))
-    |> actor.on_message(handle_message)
-    |> actor.start
-  {
-    Error(start_error) ->
-      Error("Could not start actor: " <> string.inspect(start_error))
-    Ok(actor.Started(pid:, data: musicplayer)) -> {
-      logging.log("musicplayer - started")
-      process.spawn(fn() {
-        let assert Ok(_) = process.register(process.self(), input_keys_name)
-        handle_key(musicplayer, input_keys)
-      })
-
-      process.spawn(fn() { update_playback_time_loop(mpv, ui, 1000) })
-
-      Ok(pid)
-    }
-  }
-}
-
-fn handle_message(state: State, control: Control) -> actor.Next(State, Control) {
-  case control {
-    control.Search -> {
-      logging.log("musicplayer - initiating search")
-
-      update_search(state.ui, "searching: ")
-
-      actor.continue(
-        State(
-          ..state,
-          mode: Searching,
-          input: Input(..state.input, capturing: True),
-        ),
-      )
-    }
-
-    control.Raw(content) -> {
-      logging.log("musicplayer - recieved raw input: " <> content)
-
-      let content = case state.mode {
-        Idle -> state.input.content
-        Searching -> {
-          let updated = state.input.content <> content
-          update_search(state.ui, "searching: " <> updated)
-          updated
-        }
-      }
-
-      actor.continue(State(..state, input: Input(..state.input, content:)))
-    }
-    control.Backspace -> {
-      logging.log("musicplayer - recieved backspace")
-
-      let content = case state.mode {
-        Idle -> state.input.content
-        Searching -> string.drop_end(state.input.content, 1)
-      }
-      actor.continue(State(..state, input: Input(..state.input, content:)))
-    }
-    control.Return -> {
-      logging.log(
-        "musicplayer - recieved return. `input.capture`: "
-        <> "'"
-        <> state.input.content
-        <> "'",
-      )
-
-      // Note: state.input.content is now the final input, use it
-      // before it is reset
-      case state.mode {
-        Idle -> Nil
-        Searching -> update_search(state.ui, "")
-      }
-
-      actor.continue(
-        State(..state, mode: Idle, input: Input(capturing: False, content: "")),
-      )
-    }
-
-    control.TogglePlayPause -> {
-      logging.log("musicplayer - toggling play/pause")
-
-      process.send(state.mpv, mpv_control.TogglePlayPause)
-      update_playback_time(state.mpv, state.ui)
-      actor.continue(state)
-    }
-    control.Exit -> {
-      logging.log("musicplayer - initiating musicplayer shutdown")
-      // Close `mpv` socket
-      process.call(state.mpv, 1000, fn(reply_to) { mpv_control.Exit(reply_to) })
-
-      // Reset terminal state (show cursor etc.)
-      process.call(state.ui, 1000, fn(reply_to) { ui_control.Exit(reply_to) })
-
-      logging.log("musicplayer - stopped")
-
-      actor.stop()
-    }
-  }
-}
-
-fn update_playback_time_loop(
-  mpv: Subject(mpv_control.Control),
-  ui: Subject(ui_control.Control),
-  interval_ms: Int,
-) {
-  process.sleep(interval_ms)
-  update_playback_time(mpv, ui)
-
-  update_playback_time_loop(mpv, ui, interval_ms)
-}
-
-fn update_playback_time(
-  mpv: Subject(mpv_control.Control),
-  ui: Subject(ui_control.Control),
-) -> Nil {
-  case
-    process.call(mpv, 1000, fn(reply_to) {
-      mpv_control.GetPlaybackTime(reply_to)
-    })
-  {
-    Error(err) ->
-      process.send(
-        ui,
-        ui_control.UpdateState(
-          layout.PlaybackTime,
-          "playback time: N/A (err: " <> err.details <> ")",
-        ),
-      )
-
-    Ok(mpv_control.PlaybackTime(data: playback_time)) ->
-      process.send(
-        ui,
-        ui_control.UpdateState(
-          layout.PlaybackTime,
-          "playback time: " <> time.to_duration_string(playback_time),
-        ),
-      )
-  }
-}
-
-fn update_search(ui: Subject(ui_control.Control), content: String) -> Nil {
-  process.send(ui, ui_control.UpdateState(layout.Search, content))
-}
-
-/// `handle_key` listens to a subject onto which `input` will send messages with `Key`s
-fn handle_key(musicplayer: Subject(Control), input_keys: Subject(Key)) -> Nil {
-  let _ =
-    process.new_selector()
-    |> process.select(input_keys)
-    |> process.selector_receive_forever
-    |> control.from_key
-    |> result.map(process.send(musicplayer, _))
-
-  handle_key(musicplayer, input_keys)
-}

src/musicplayer/tcp/reason.gleam

@@ -1,240 +0,0 @@
-pub type Reason {
-  /// from `connect`
-  Timeout
-  /// from `send`
-  Closed
-
-  /// Address already in use
-  Eaddrinuse
-  /// Cannot assign requested address
-  Eaddrnotavail
-  /// Address family not supported by protocol family
-  Eafnosupport
-  /// Operation already in progress
-  Ealready
-  /// Software caused connection abort
-  Econnaborted
-  /// Connection refused
-  Econnrefused
-  /// Connection reset by peer
-  Econnreset
-  /// Destination address required
-  Edestaddrreq
-  /// Host is down
-  Ehostdown
-  /// Host is unreachable
-  Ehostunreach
-  /// Operation now in progress
-  Einprogress
-  /// Socket is already connected
-  Eisconn
-  /// Message too long
-  Emsgsize
-  /// Network is down
-  Enetdown
-  /// Network is unreachable
-  Enetunreach
-  /// Package not installed
-  Enopkg
-  /// Bad protocol option
-  Enoprotoopt
-  /// Socket is not connected
-  Enotconn
-  /// Inappropriate device for ioctl
-  Enotty
-  /// Socket operation on non-socket
-  Enotsock
-  /// Protocol error
-  Eproto
-  /// Protocol not supported
-  Eprotonosupport
-  /// Wrong protocol type for socket
-  Eprototype
-  /// Socket type not supported
-  Esocktnosupport
-  /// Connection timed out
-  Etimedout
-  /// Operation would block
-  Ewouldblock
-  /// Invalid exchange
-  Exbadport
-  /// Invalid sequence number
-  Exbadseq
-  /// Permission denied
-  Eacces
-  /// Resource temporarily unavailable
-  Eagain
-  /// Bad file number
-  Ebadf
-  /// Not a data message
-  Ebadmsg
-  /// File busy
-  Ebusy
-  /// Resource deadlock avoided
-  Edeadlk
-  /// Resource deadlock avoided
-  Edeadlock
-  /// Disk quota exceeded
-  Edquot
-  /// File already exists
-  Eexist
-  /// Bad address in system call argument
-  Efault
-  /// File too large
-  Efbig
-  /// Inappropriate file type or format
-  Eftype
-  /// Interrupted system call
-  Eintr
-  /// Invalid argument
-  Einval
-  /// I/O error
-  Eio
-  /// Illegal operation on a directory
-  Eisdir
-  /// Too many levels of symbolic links
-  Eloop
-  /// Too many open files
-  Emfile
-  /// Too many links
-  Emlink
-  /// Multihop attempted
-  Emultihop
-  /// Filename too long
-  Enametoolong
-  /// File table overflow
-  Enfile
-  /// No buffer space available
-  Enobufs
-  /// No such device
-  Enodev
-  /// No locks available
-  Enolck
-  /// Link has been severed
-  Enolink
-  /// No such file or directory
-  Enoent
-  /// Not enough memory
-  Enomem
-  /// No space left on device
-  Enospc
-  /// Out of stream resources or not a stream device
-  Enosr
-  /// Not a stream device
-  Enostr
-  /// Function not implemented
-  Enosys
-  /// Block device required
-  Enotblk
-  /// Not a directory
-  Enotdir
-  /// Operation not supported
-  Enotsup
-  /// No such device or address
-  Enxio
-  /// Operation not supported on socket
-  Eopnotsupp
-  /// Value too large for defined data type
-  Eoverflow
-  /// Not owner
-  Eperm
-  /// Broken pipe
-  Epipe
-  /// Math result unrepresentable
-  Erange
-  /// Read-only filesystem
-  Erofs
-  /// Invalid seek
-  Espipe
-  /// No such process
-  Esrch
-  /// Stale remote file handle
-  Estale
-  /// Text file or pseudo-device busy
-  Etxtbsy
-  /// Cross-device link
-  Exdev
-}
-
-pub fn to_string(reason: Reason) -> String {
-  case reason {
-    Closed -> "Connection closed (closed)"
-    Eacces -> "Permission denied (eacces)"
-    Eaddrinuse -> "Address already in use (eaddrinuse)"
-    Eaddrnotavail -> "Cannot assign requested address (eaddrnotavail)"
-    Eafnosupport ->
-      "Address family not supported by protocol family (eafnosupport)"
-    Eagain -> "Resource temporarily unavailable (eagain)"
-    Ealready -> "Operation already in progress (ealready)"
-    Ebadf -> "Bad file number (ebadf)"
-    Ebadmsg -> "Not a data message (ebadmsg)"
-    Ebusy -> "File busy (ebusy)"
-    Econnaborted -> "Software caused connection abort (econnaborted)"
-    Econnrefused -> "Connection refused (econnrefused)"
-    Econnreset -> "Connection reset by peer (econnreset)"
-    Edeadlk -> "Resource deadlock avoided (edeadlk)"
-    Edeadlock -> "Resource deadlock avoided (edeadlock)"
-    Edestaddrreq -> "Destination address required (edestaddrreq)"
-    Edquot -> "Disk quota exceeded (edquot)"
-    Eexist -> "File already exists (eexist)"
-    Efault -> "Bad address in system call argument (efault)"
-    Efbig -> "File too large (efbig)"
-    Eftype -> "Inappropriate file type or format (eftype)"
-    Ehostdown -> "Host is down (ehostdown)"
-    Ehostunreach -> "Host is unreachable (ehostunreach)"
-    Einprogress -> "Operation now in progress (einprogress)"
-    Eintr -> "Interrupted system call (eintr)"
-    Einval -> "Invalid argument (einval)"
-    Eio -> "I/O error (eio)"
-    Eisconn -> "Socket is already connected (eisconn)"
-    Eisdir -> "Illegal operation on a directory (eisdir)"
-    Eloop -> "Too many levels of symbolic links (eloop)"
-    Emfile -> "Too many open files (emfile)"
-    Emlink -> "Too many links (emlink)"
-    Emsgsize -> "Message too long (emsgsize)"
-    Emultihop -> "Multihop attempted (emultihop)"
-    Enametoolong -> "Filename too long (enametoolong)"
-    Enetdown -> "Network is down (enetdown)"
-    Enetunreach -> "Network is unreachable (enetunreach)"
-    Enfile -> "File table overflow (enfile)"
-    Enobufs -> "No buffer space available (enobufs)"
-    Enodev -> "No such device (enodev)"
-    Enoent -> "No such file or directory (enoent)"
-    Enolck -> "No locks available (enolck)"
-    Enolink -> "Link has been severed (enolink)"
-    Enomem -> "Not enough memory (enomem)"
-    Enopkg -> "Package not installed (enopkg)"
-    Enoprotoopt -> "Bad protocol option (enoprotoopt)"
-    Enospc -> "No space left on device (enospc)"
-    Enosr -> "Out of stream resources or not a stream device (enosr)"
-    Enostr -> "Not a stream device (enostr)"
-    Enosys -> "Function not implemented (enosys)"
-    Enotblk -> "Block device required (enotblk)"
-    Enotconn -> "Socket is not connected (enotconn)"
-    Enotdir -> "Not a directory (enotdir)"
-    Enotsock -> "Socket operation on non-socket (enotsock)"
-    Enotsup -> "Operation not supported (enotsup)"
-    Enotty -> "Inappropriate device for ioctl (enotty)"
-    Enxio -> "No such device or address (enxio)"
-    Eopnotsupp -> "Operation not supported on socket (eopnotsupp)"
-    Eoverflow -> "Value too large for defined data type (eoverflow)"
-    Eperm -> "Not owner (eperm)"
-    Epipe -> "Broken pipe (epipe)"
-    Eproto -> "Protocol error (eproto)"
-    Eprotonosupport -> "Protocol not supported (eprotonosupport)"
-    Eprototype -> "Wrong protocol type for socket (eprototype)"
-    Erange -> "Math result unrepresentable (erange)"
-    Erofs -> "Read-only filesystem (erofs)"
-    Esocktnosupport -> "Socket type not supported (esocktnosupport)"
-    Espipe -> "Invalid seek (espipe)"
-    Esrch -> "No such process (esrch)"
-    Estale -> "Stale remote file handle (estale)"
-    Etimedout -> "Connection timed out (etimedout)"
-    Etxtbsy -> "Text file or pseudo-device busy (etxtbsy)"
-    Ewouldblock -> "Operation would block (ewouldblock)"
-    Exbadport -> "Invalid exchange (exbadport)"
-    Exbadseq -> "Invalid sequence number (exbadseq)"
-    Exdev -> "Cross-device link (exdev)"
-    Timeout -> "Operation timed out (timeout)"
-  }
-}

src/musicplayer/tcp/tcp.gleam

@@ -1,117 +0,0 @@
-import gleam/bit_array
-import gleam/erlang/atom
-import gleam/result
-
-import musicplayer/tcp/reason.{type Reason}
-
-pub type Socket
-
-// https://www.erlang.org/doc/apps/kernel/inet#t:address_family/0
-// local socket
-type Local {
-  Local(socket_path: String)
-}
-
-type ModeValue {
-  Binary
-}
-
-type TCPOption {
-  Active(Bool)
-  Mode(ModeValue)
-  Reuseaddr(Bool)
-  Ifaddr(Local)
-  ExitOnClose(Bool)
-}
-
-pub fn listen(socket_path: String) -> Result(Socket, Reason) {
-  let options = [
-    Mode(Binary),
-    Active(False),
-    Reuseaddr(True),
-    Ifaddr(Local(socket_path)),
-    ExitOnClose(False),
-  ]
-  // port zero with `local` address
-  let port = 0
-
-  gen_tcp_listen(port, options)
-}
-
-pub fn accept(listen_socket: Socket) -> Result(Socket, Reason) {
-  gen_tcp_accept(listen_socket)
-}
-
-pub fn receive(socket: Socket, timeout: Int) -> Result(String, Reason) {
-  // Get all bytes
-  let length = 0
-
-  use bits <- result.try(gen_tcp_recv(socket, length, timeout))
-  case bits |> bit_array.to_string {
-    // TODO what error is best?
-    Error(_) -> Error(reason.Ebadmsg)
-    Ok(s) -> Ok(s)
-  }
-}
-
-pub fn connect(socket_path: String) -> Result(Socket, Reason) {
-  let options = [Mode(Binary), Active(False)]
-
-  // port zero with `local` address
-  let port = 0
-
-  // timeout in ms
-  let timeout = 1000
-
-  gen_tcp_connect(Local(socket_path), port, options, timeout)
-}
-
-pub fn send(socket: Socket, message: String) -> Result(Nil, Reason) {
-  gen_tcp_send(socket, bit_array.from_string(message))
-}
-
-pub fn close(socket: Socket) -> Nil {
-  gen_tcp_close(socket)
-}
-
-pub fn shutdown(socket: Socket) -> Result(Nil, Reason) {
-  let how = atom.create("write")
-  gen_tcp_shutdown(socket, how)
-}
-
-// https://www.erlang.org/doc/apps/kernel/gen_tcp.html#listen/2
-@external(erlang, "gen_tcp", "listen")
-fn gen_tcp_listen(port: Int, option: List(TCPOption)) -> Result(Socket, Reason)
-
-// https://www.erlang.org/doc/apps/kernel/gen_tcp.html#accept/1
-@external(erlang, "gen_tcp", "accept")
-fn gen_tcp_accept(listen_socket: Socket) -> Result(Socket, Reason)
-
-// https://www.erlang.org/doc/apps/kernel/gen_tcp.html#recv/3
-@external(erlang, "gen_tcp", "recv")
-fn gen_tcp_recv(
-  socket: Socket,
-  length: Int,
-  timeout: Int,
-) -> Result(BitArray, Reason)
-
-// https://www.erlang.org/doc/apps/kernel/gen_tcp.html#connect/4
-@external(erlang, "gen_tcp", "connect")
-fn gen_tcp_connect(
-  address: Local,
-  port: Int,
-  options: List(TCPOption),
-  timeout: Int,
-) -> Result(Socket, Reason)
-
-// https://www.erlang.org/doc/apps/kernel/gen_tcp.html#send/2
-@external(erlang, "tcp_ffi", "send")
-fn gen_tcp_send(socket: Socket, packet: BitArray) -> Result(Nil, Reason)
-
-// https://www.erlang.org/doc/apps/kernel/gen_tcp.html#close/1
-@external(erlang, "gen_tcp", "close")
-fn gen_tcp_close(socket: Socket) -> Nil
-
-// https://www.erlang.org/doc/apps/kernel/gen_tcp.html#shutdown/2
-@external(erlang, "tcp_ffi", "shutdown")
-fn gen_tcp_shutdown(socket: Socket, how: atom.Atom) -> Result(Nil, Reason)

src/musicplayer/tcp/tcp_ffi.erl

@@ -1,14 +0,0 @@
--module(tcp_ffi).
--export([send/2, shutdown/2]).
-
-send(Socket, Packet) ->
-  case gen_tcp:send(Socket, Packet) of
-    ok -> {ok, nil};
-    Res -> Res
-  end.
-
-shutdown(Socket, How) ->
-  case gen_tcp:shutdown(Socket, How) of
-    ok -> {ok, nil};
-    Res -> Res
-  end.

src/musicplayer/time/time.gleam

@@ -1,23 +0,0 @@
-import gleam/float
-import gleam/int
-import gleam/string
-
-pub fn to_duration_string(seconds: Float) -> String {
-  let total =
-    seconds
-    |> float.max(0.0)
-    |> float.truncate
-
-  let minutes = total / 60
-  let seconds = total % 60
-
-  let mins =
-    int.to_string(minutes)
-    |> string.pad_start(to: 2, with: "0")
-
-  let secs =
-    int.to_string(seconds)
-    |> string.pad_start(to: 2, with: "0")
-
-  mins <> ":" <> secs
-}

src/musicplayer/ui/control.gleam

@@ -1,10 +0,0 @@
-import gleam/erlang/process.{type Subject}
-
-import musicplayer/ui/layout.{type Section}
-
-pub type Control {
-  UpdateDimensions(width: Int, height: Int)
-  UpdateState(section: Section, content: String)
-
-  Exit(reply_to: Subject(Nil))
-}

src/musicplayer/ui/internal.gleam

@@ -1,35 +0,0 @@
-import gleam/int
-import gleam/io
-
-// https://en.wikipedia.org/wiki/ANSI_escape_code#Control_Sequence_Introducer_commands
-
-pub fn clear_screen() -> Nil {
-  io.print("\u{001B}[2J\u{001B}[H")
-}
-
-pub fn chars_at(chars: String, x: Int, y: Int) -> String {
-  let seq = "\u{001B}[" <> int.to_string(y) <> ";" <> int.to_string(x) <> "H"
-  seq <> chars
-}
-
-pub fn print(chars: String) -> Nil {
-  io.print(chars)
-}
-
-pub fn hide_cursor() -> Nil {
-  io.print("\u{001B}[?25l")
-}
-
-pub fn show_cursor() -> Nil {
-  io.print("\u{001B}[?25h")
-}
-
-pub type Enotsup
-
-// https://www.erlang.org/doc/apps/stdlib/io.html#rows/0
-@external(erlang, "io", "rows")
-pub fn io_get_rows() -> Result(Int, Enotsup)
-
-// https://www.erlang.org/doc/apps/stdlib/io.html#columns/0
-@external(erlang, "io", "columns")
-pub fn io_get_columns() -> Result(Int, Enotsup)

src/musicplayer/ui/layout.gleam

@@ -1,90 +0,0 @@
-import gleam/dict
-import gleam/list
-import gleam/string_tree.{type StringTree}
-
-import musicplayer/ui/internal
-
-pub type Layout {
-  Layout(width: Int, height: Int, nodes: dict.Dict(Section, Node))
-}
-
-pub type Section {
-  Root
-  Header
-  Search
-  PlaybackTime
-}
-
-pub type Node {
-  Node(content: String, x: Int, y: Int, children: List(Section))
-}
-
-pub fn new() -> Layout {
-  let nodes =
-    dict.from_list([
-      #(
-        Root,
-        Node(content: "", x: 0, y: 0, children: [
-          Header,
-          Search,
-          PlaybackTime,
-        ]),
-      ),
-      #(Header, Node(content: "Music Player", x: 1, y: 1, children: [])),
-      #(Search, Node(content: "", x: 30, y: 1, children: [])),
-      #(PlaybackTime, Node(content: "00:00", x: 1, y: 2, children: [])),
-    ])
-
-  Layout(0, 0, nodes: nodes)
-}
-
-pub fn update_section(
-  layout: Layout,
-  section: Section,
-  content: String,
-) -> Layout {
-  case dict.get(layout.nodes, section) {
-    Error(_) -> layout
-    Ok(node) ->
-      Layout(
-        ..layout,
-        nodes: dict.insert(
-          layout.nodes,
-          section,
-          Node(..node, content: content),
-        ),
-      )
-  }
-}
-
-pub fn update_dimensions(layout: Layout, width: Int, height: Int) -> Layout {
-  Layout(..layout, width:, height:)
-}
-
-pub fn render(layout: Layout, from: Section) -> Nil {
-  string_tree.new()
-  |> render_loop(layout, from, _)
-  |> string_tree.to_string
-  |> internal.print
-}
-
-pub fn render_loop(
-  layout: Layout,
-  from: Section,
-  into: StringTree,
-) -> StringTree {
-  case dict.get(layout.nodes, from) {
-    Error(_) -> into
-    Ok(node) -> {
-      let parent =
-        string_tree.append(
-          into,
-          internal.chars_at(node.content, node.x, node.y),
-        )
-
-      list.fold(node.children, parent, fn(into_acc, child) {
-        render_loop(layout, child, into_acc)
-      })
-    }
-  }
-}

src/musicplayer/ui/ui.gleam

@@ -1,110 +0,0 @@
-import gleam/erlang/process.{type Subject}
-import gleam/int
-import gleam/list
-import gleam/otp/actor
-import gleam/string
-
-import musicplayer/logging/logging
-import musicplayer/ui/control.{type Control}
-import musicplayer/ui/internal
-import musicplayer/ui/layout.{type Layout}
-
-pub type State(redraw, content) {
-  State(redraw: Subject(Layout), layout: Layout)
-}
-
-pub fn new() -> Result(Subject(Control), String) {
-  let redraw_name = process.new_name("redraw")
-  let redraw: Subject(Layout) = process.named_subject(redraw_name)
-
-  let layout = layout.new()
-
-  case
-    actor.new(State(redraw, layout))
-    |> actor.on_message(handle_message)
-    |> actor.start
-  {
-    Error(start_error) ->
-      Error("Could not start actor: " <> string.inspect(start_error))
-    Ok(actor.Started(data: ui, ..)) -> {
-      process.spawn(fn() {
-        let update_dimensions_interval_ms = 300
-        update_dimensions_on_interval(ui, update_dimensions_interval_ms)
-      })
-
-      process.spawn(fn() {
-        let assert Ok(_) = process.register(process.self(), redraw_name)
-
-        internal.clear_screen()
-        internal.hide_cursor()
-
-        redraw_on_update_loop(redraw)
-      })
-
-      Ok(ui)
-    }
-  }
-}
-
-fn handle_message(
-  state: State(redraw, layout),
-  control: Control,
-) -> actor.Next(State(redraw, layout), Control) {
-  case control {
-    control.UpdateDimensions(width, height) -> {
-      let current_dimensions = #(state.layout.width, state.layout.height)
-
-      case #(width, height) == current_dimensions {
-        True -> actor.continue(state)
-        False -> {
-          [width, height]
-          |> list.map(int.to_string)
-          |> string.join(" ")
-          |> string.append("ui - updating dimensions: ", _)
-          |> logging.log
-
-          actor.continue(
-            State(
-              ..state,
-              layout: layout.update_dimensions(state.layout, width, height),
-            ),
-          )
-        }
-      }
-    }
-    control.UpdateState(section, content) -> {
-      let layout = layout.update_section(state.layout, section, content)
-      let state = State(..state, layout:)
-
-      actor.send(state.redraw, layout)
-      actor.continue(state)
-    }
-
-    control.Exit(reply_to) -> {
-      internal.show_cursor()
-      process.send(reply_to, Nil)
-      actor.stop()
-    }
-  }
-}
-
-fn redraw_on_update_loop(redraw: Subject(Layout)) -> Nil {
-  let layout = process.receive_forever(redraw)
-
-  internal.clear_screen()
-  layout.render(layout, layout.Root)
-
-  redraw_on_update_loop(redraw)
-}
-
-fn update_dimensions_on_interval(ui: Subject(Control), interval_ms: Int) {
-  case internal.io_get_columns(), internal.io_get_rows() {
-    Ok(width), Ok(height) -> {
-      process.send(ui, control.UpdateDimensions(width, height))
-    }
-    _, _ -> logging.log("ui - failed to update dimensions")
-  }
-
-  process.sleep(interval_ms)
-  update_dimensions_on_interval(ui, interval_ms)
-}

test/echo_server.gleam

@@ -1,81 +0,0 @@
-import gleam/erlang/process.{type Subject}
-import gleam/io
-import gleam/otp/actor
-import gleam/result
-import gleam/string
-
-import musicplayer/tcp/reason.{type Reason}
-import musicplayer/tcp/tcp
-
-pub type Message {
-  Shutdown
-  ReadyToAccept(subject: Subject(Message), listen_socket: tcp.Socket)
-}
-
-pub fn new(socket_path: String) -> Result(tcp.Socket, String) {
-  let server = actor.new(Nil) |> actor.on_message(handle_message) |> actor.start
-
-  case tcp.listen(socket_path), server {
-    Error(r), _ -> Error(reason.to_string(r))
-    _, Error(start_error) ->
-      case start_error {
-        actor.InitExited(_) -> Error("InitExited")
-        actor.InitFailed(_) -> Error("InitFailed")
-        actor.InitTimeout -> Error("InitTimeout")
-      }
-    Ok(listen_socket), Ok(b) -> {
-      let subject = b.data
-      actor.send(subject, ReadyToAccept(subject, listen_socket))
-      Ok(listen_socket)
-    }
-  }
-}
-
-fn handle_message(_: Nil, message: Message) -> actor.Next(Nil, Message) {
-  case message {
-    Shutdown -> actor.stop()
-
-    ReadyToAccept(subject, listen_socket) -> {
-      case tcp.accept(listen_socket) {
-        Error(r) ->
-          actor.stop_abnormal(
-            "Could not accept connection :" <> reason.to_string(r),
-          )
-        Ok(socket) -> {
-          case receive_from_connection(socket) {
-            Error(r) ->
-              io.println_error(
-                "Failed to receive from connection :" <> reason.to_string(r),
-              )
-            Ok(_) -> Nil
-          }
-
-          actor.send(subject, ReadyToAccept(subject, listen_socket))
-          actor.continue(Nil)
-        }
-      }
-    }
-  }
-}
-
-fn receive_from_connection(socket: tcp.Socket) -> Result(Nil, Reason) {
-  result.try(receive_until_closed(socket, ""), fn(data) {
-    let _ = tcp.send(socket, data)
-    tcp.close(socket)
-    Ok(Nil)
-  })
-}
-
-fn receive_until_closed(
-  socket: tcp.Socket,
-  result: String,
-) -> Result(String, Reason) {
-  case tcp.receive(socket, 10_000) {
-    Error(reason.Closed) -> Ok(result)
-    Error(err) -> Error(err)
-    Ok(data) -> {
-      let result = data |> string.append(result, _)
-      receive_until_closed(socket, result)
-    }
-  }
-}

test/musicplayer/control_test.gleam

@@ -1,24 +0,0 @@
-import gleam/list
-import gleeunit
-
-import musicplayer/control.{type Control}
-import musicplayer/input/key.{type Key, Char}
-
-pub fn main() -> Nil {
-  gleeunit.main()
-}
-
-type TestCase {
-  TestCase(key: Key, expected: Result(Control, Nil))
-}
-
-pub fn control_from_key_test() {
-  let test_cases = [
-    TestCase(Char(" "), Ok(control.TogglePlayPause)),
-    TestCase(Char("q"), Ok(control.Exit)),
-  ]
-
-  list.each(test_cases, fn(tc) {
-    assert tc.expected == control.from_key(tc.key)
-  })
-}

test/musicplayer/input/input_test.gleam

@@ -1,39 +0,0 @@
-import gleam/list
-import gleeunit
-
-import musicplayer/input/key.{type Key, Char, backspace, csi, esc, return}
-
-pub fn main() -> Nil {
-  gleeunit.main()
-}
-
-type TestCase {
-  TestCase(input: List(String), expected: Key)
-}
-
-pub fn key_from_list_test() {
-  let base_tests = [TestCase([], key.Continue([]))]
-
-  let char_tests = [TestCase(["c"], Char("c"))]
-
-  let escape_tests = [
-    TestCase([esc, csi], key.Continue([esc, csi])),
-    TestCase([esc], key.Continue([esc])),
-
-    TestCase([esc, csi, "D"], key.Left),
-    TestCase([esc, csi, "C"], key.Right),
-    TestCase([esc, csi, "A"], key.Up),
-    TestCase([esc, csi, "B"], key.Down),
-  ]
-
-  let input_tests = [
-    TestCase([return], key.Return),
-    TestCase([backspace], key.Backspace),
-  ]
-
-  let test_cases = [base_tests, char_tests, escape_tests, input_tests]
-
-  list.each(list.flatten(test_cases), fn(tc) {
-    assert tc.expected == key.from_list(tc.input)
-  })
-}

test/musicplayer/mpv/mpv_test.gleam

@@ -1,15 +0,0 @@
-import gleeunit
-
-import musicplayer/mpv/internal
-
-pub fn main() -> Nil {
-  gleeunit.main()
-}
-
-pub fn parse_playback_time_test() {
-  let json_string =
-    "{\"data\":\"123.456789\",\"request_id\":0,\"error\":\"success\"}\n"
-
-  let assert Ok(data) = internal.parse_playback_time(json_string)
-  assert data == 123.456789
-}

test/musicplayer/tcp/tcp_test.gleam

@@ -1,30 +0,0 @@
-import gleam/list
-import gleeunit
-import simplifile
-
-import echo_server
-import musicplayer/tcp/tcp
-
-pub fn main() -> Nil {
-  gleeunit.main()
-}
-
-pub fn tcp_send_shutdown_receive_test() {
-  let socket_path = "/tmp/musicplayer-test.sock"
-
-  let assert Ok(_) = echo_server.new(socket_path)
-  let assert Ok(socket) = tcp.connect(socket_path)
-
-  let messages = ["hello, ", "world!\n"]
-  list.each(messages, fn(message) {
-    let assert Ok(_) = tcp.send(socket, message)
-  })
-
-  let assert Ok(_) = tcp.shutdown(socket)
-
-  let timeout_ms = 100
-  assert Ok("hello, world!\n") == tcp.receive(socket, timeout_ms)
-
-  // TODO find better way to always do cleanup
-  simplifile.delete(socket_path)
-}

test/musicplayer/time/time_test.gleam

@@ -1,32 +0,0 @@
-import gleam/list
-import gleeunit
-
-import musicplayer/time/time
-
-pub fn main() -> Nil {
-  gleeunit.main()
-}
-
-type TestCase {
-  TestCase(seconds: Float, expected: String)
-}
-
-pub fn to_duration_string_test() {
-  let test_cases = [
-    TestCase(-1.0, "00:00"),
-    TestCase(0.0, "00:00"),
-    TestCase(9.0, "00:09"),
-    TestCase(10.0, "00:10"),
-    TestCase(11.0, "00:11"),
-    TestCase(60.0, "01:00"),
-    TestCase(61.0, "01:01"),
-    TestCase(120.0, "02:00"),
-    TestCase(600.0, "10:00"),
-    TestCase(6000.0, "100:00"),
-    TestCase(6001.0, "100:01"),
-  ]
-
-  list.each(test_cases, fn(tc) {
-    assert tc.expected == time.to_duration_string(tc.seconds)
-  })
-}

test/musicplayer_test.gleam

@@ -3,3 +3,11 @@ import gleeunit
 pub fn main() -> Nil {
   gleeunit.main()
 }
+
+// gleeunit test functions end in `_test`
+pub fn hello_world_test() {
+  let name = "Joe"
+  let greeting = "Hello, " <> name <> "!"
+
+  assert greeting == "Hello, Joe!"
+}