Remove unused fn ui.print

Instead of "injecting" characters into the input stream, the input
stream is now forwarded to the `musicplayer`. It has will have to
decide what to do with the stream, e.g. by setting the "mode" to
something that captures the input stream and acts upon it

gleam.toml

@@ -18,6 +18,7 @@ gleam_otp = ">= 1.2.0 and < 2.0.0"
 gleam_erlang = ">= 1.3.0 and < 2.0.0"
 simplifile = ">= 2.3.1 and < 3.0.0"
 gleam_json = ">= 3.1.0 and < 4.0.0"
+gleam_time = ">= 1.6.0 and < 2.0.0"
 
 [dev-dependencies]
 gleeunit = ">= 1.0.0 and < 2.0.0"

manifest.toml

@@ -7,6 +7,7 @@ packages = [
   { name = "gleam_json", version = "3.1.0", build_tools = ["gleam"], requirements = ["gleam_stdlib"], otp_app = "gleam_json", source = "hex", outer_checksum = "44FDAA8847BE8FC48CA7A1C089706BD54BADCC4C45B237A992EDDF9F2CDB2836" },
   { name = "gleam_otp", version = "1.2.0", build_tools = ["gleam"], requirements = ["gleam_erlang", "gleam_stdlib"], otp_app = "gleam_otp", source = "hex", outer_checksum = "BA6A294E295E428EC1562DC1C11EA7530DCB981E8359134BEABC8493B7B2258E" },
   { name = "gleam_stdlib", version = "0.65.0", build_tools = ["gleam"], requirements = [], otp_app = "gleam_stdlib", source = "hex", outer_checksum = "7C69C71D8C493AE11A5184828A77110EB05A7786EBF8B25B36A72F879C3EE107" },
+  { name = "gleam_time", version = "1.6.0", build_tools = ["gleam"], requirements = ["gleam_stdlib"], otp_app = "gleam_time", source = "hex", outer_checksum = "0DF3834D20193F0A38D0EB21F0A78D48F2EC276C285969131B86DF8D4EF9E762" },
   { name = "gleeunit", version = "1.9.0", build_tools = ["gleam"], requirements = ["gleam_stdlib"], otp_app = "gleeunit", source = "hex", outer_checksum = "DA9553CE58B67924B3C631F96FE3370C49EB6D6DC6B384EC4862CC4AAA718F3C" },
   { name = "simplifile", version = "2.3.1", build_tools = ["gleam"], requirements = ["filepath", "gleam_stdlib"], otp_app = "simplifile", source = "hex", outer_checksum = "957E0E5B75927659F1D2A1B7B75D7B9BA96FAA8D0C53EA71C4AD9CD0C6B848F6" },
 ]
@@ -16,5 +17,6 @@ gleam_erlang = { version = ">= 1.3.0 and < 2.0.0" }
 gleam_json = { version = ">= 3.1.0 and < 4.0.0" }
 gleam_otp = { version = ">= 1.2.0 and < 2.0.0" }
 gleam_stdlib = { version = ">= 0.44.0 and < 2.0.0" }
+gleam_time = { version = ">= 1.6.0 and < 2.0.0" }
 gleeunit = { version = ">= 1.0.0 and < 2.0.0" }
 simplifile = { version = ">= 2.3.1 and < 3.0.0" }

src/musicplayer.gleam

@@ -2,35 +2,24 @@ import gleam/erlang/process.{type Name}
 
 import musicplayer/input/input
 import musicplayer/input/key.{type Key}
+import musicplayer/logging/logging
 import musicplayer/mpv/mpv
 import musicplayer/musicplayer
 import musicplayer/ui/ui
 
 pub fn main() -> Nil {
+  let assert Ok(logger) = logging.new("/tmp/musicplayer.log")
+
   let input_keys_name: Name(Key) = process.new_name("input_keys")
-  let input_stream_name: Name(List(String)) = process.new_name("input_stream")
-
-  // `input_inject` is created by name to allow the `input` process that
-  // owns `read_input` to be able to register and receive from it,
-  //  while the any other processes can use the name reference to
-  // inject input
-  let input_inject_name: Name(Key) = process.new_name("input_inject_keys")
-
-  // TODO should input.new just return the inject_subject?
-  input.new(input_keys_name, input_stream_name, input_inject_name)
+  input.new(input_keys_name)
 
   let assert Ok(ui) = ui.new()
   let assert Ok(mpv) = mpv.new()
+  let assert Ok(musicplayer_pid) =
+    musicplayer.new(logger, ui, mpv, input_keys_name)
 
-  let exit = process.new_subject()
-  let assert Ok(_) =
-    musicplayer.new(
-      ui,
-      mpv,
-      input_keys_name,
-      input_stream_name,
-      input_inject_name,
-      exit,
-    )
-  process.receive_forever(exit)
+  let monitor = process.monitor(musicplayer_pid)
+  process.new_selector()
+  |> process.select_specific_monitor(monitor, fn(_) { Nil })
+  |> process.selector_receive_forever
 }

src/musicplayer/control.gleam

@@ -4,21 +4,27 @@ pub type Control {
   TogglePlayPause
   Search
 
+  Raw(String)
+  Return
+  Backspace
+
   Exit
 }
 
 pub fn from_key(key: Key) -> Result(Control, Nil) {
   case key {
-    key.Char(char) -> char_control(char)
+    key.Return -> Ok(Return)
+    key.Backspace -> Ok(Backspace)
+    key.Char(char) -> Ok(char_control(char))
     _ -> Error(Nil)
   }
 }
 
-fn char_control(char: String) -> Result(Control, Nil) {
+fn char_control(char: String) -> Control {
   case char {
-    " " -> Ok(TogglePlayPause)
-    "/" -> Ok(Search)
-    "q" -> Ok(Exit)
-    _ -> Error(Nil)
+    " " -> TogglePlayPause
+    "/" -> Search
+    "q" -> Exit
+    _ -> Raw(char)
   }
 }

src/musicplayer/input/input.gleam

@@ -1,47 +1,15 @@
-import gleam/erlang/process.{type Name, type Subject}
+import gleam/erlang/process.{type Name}
 
 import musicplayer/input/key.{type Key}
 
-// TODO REWRITE below
-
-/// `new` accepts a list of listeners that are composed of two subjects;
-///   - one to get the final `Key` and
-///   - one to tap the input as it is read from i/o
-/// and
-///   - a subject name that is used to create a `Subject` that other processes
-///     know they can inject a `Key` into the input with
-pub fn new(
-  input_keys_name: Name(Key),
-  input_stream_name: Name(List(String)),
-  input_inject_name: Name(Key),
-) -> Nil {
+/// `new` accepts a subject that all input will be sent to
+pub fn new(input_keys_name: Name(Key)) -> Nil {
   let _ =
     process.spawn(fn() {
       let input_keys = process.named_subject(input_keys_name)
-      let input_stream = process.named_subject(input_stream_name)
-      let input_inject = process.named_subject(input_inject_name)
-
-      let assert Ok(_) = process.register(process.self(), input_inject_name)
-
-      read_input(input_keys, input_stream, input_inject)
+      key.read_input_until_key(input_keys)
     })
 
   key.start_raw_shell()
   Nil
 }
-
-fn read_input(
-  input_keys: Subject(Key),
-  input_stream: Subject(List(String)),
-  input_inject: Subject(Key),
-) -> Nil {
-  let buffer = case process.receive(input_inject, 1) {
-    Ok(key.Continue(buffer)) -> buffer
-    Ok(_) | Error(_) -> []
-  }
-
-  key.read_input_until_key(buffer, input_stream)
-  |> process.send(input_keys, _)
-
-  read_input(input_keys, input_stream, input_inject)
-}

src/musicplayer/input/key.gleam

@@ -1,20 +1,21 @@
 import gleam/erlang/atom
 import gleam/erlang/process.{type Subject}
 import gleam/list
-import gleam/string
 
 import musicplayer/input/internal as internal_input
 
 pub type Key {
+  Continue(buffer: List(String))
   Char(String)
 
-  Input(String)
   Left
   Right
   Up
   Down
 
-  Continue(buffer: List(String))
+  Return
+  Backspace
+
   Unknown
 }
 
@@ -23,8 +24,9 @@ pub const esc = "\u{001B}"
 // control sequence introducer
 pub const csi = "["
 
-// input introducer
-pub const input_introducer = "::"
+pub const return = "\r"
+
+pub const backspace = "\u{007F}"
 
 pub fn from_list(l: List(String)) -> Key {
   case l {
@@ -35,18 +37,9 @@ pub fn from_list(l: List(String)) -> Key {
 
     [e, c] if e == esc && c == csi -> Continue(l)
 
-    [ci] | [ci, _] if ci == input_introducer -> Continue(l)
-    [ii, cmd, tail] if ii == input_introducer -> {
-      case tail {
-        // Return
-        "\r" -> Input(cmd)
-        // Backspace
-        "\u{007F}" -> Continue([ii, string.drop_end(cmd, 1)])
-        _ -> Continue([ii, cmd <> tail])
-      }
-    }
-
     [e] if e == esc -> Continue(l)
+    [bs] if bs == backspace -> Backspace
+    [rtn] if rtn == return -> Return
     [char] -> Char(char)
 
     [] -> Continue([])
@@ -60,20 +53,24 @@ pub fn start_raw_shell() {
   internal_input.shell_start_interactive(#(no_shell, raw))
 }
 
-pub fn read_input_until_key(
+pub fn read_input_until_key(input_keys: Subject(Key)) -> Nil {
+  read_input_until_key_loop([], input_keys)
+}
+
+pub fn read_input_until_key_loop(
   l: List(String),
-  input_stream: Subject(List(String)),
-) -> Key {
+  input_keys: Subject(Key),
+) -> Nil {
   case
     internal_input.read_input()
     |> list.wrap
     |> list.append(l, _)
     |> from_list
   {
-    Continue(l) -> {
-      process.send(input_stream, l)
-      read_input_until_key(l, input_stream)
+    Continue(l) -> read_input_until_key_loop(l, input_keys)
+    k -> {
+      process.send(input_keys, k)
+      read_input_until_key_loop([], input_keys)
     }
-    k -> k
   }
 }

src/musicplayer/logging/control.gleam

@@ -0,0 +1,7 @@
+import gleam/erlang/process.{type Subject}
+
+pub type Control {
+  Write(String)
+
+  Exit(reply_to: Subject(Nil))
+}

src/musicplayer/logging/logging.gleam

@@ -0,0 +1,58 @@
+import gleam/erlang/process.{type Subject}
+import gleam/otp/actor
+import gleam/result
+import gleam/string
+import gleam/time/calendar
+import gleam/time/timestamp
+import simplifile
+
+import musicplayer/logging/control.{type Control}
+
+type State {
+  State(filepath: String)
+}
+
+pub fn new(filepath: String) -> Result(Subject(Control), String) {
+  use _ <- result.try(
+    case simplifile.is_file(filepath) {
+      Ok(True) -> Ok(Nil)
+      _ -> simplifile.create_file(filepath)
+    }
+    |> result.map_error(fn(e) {
+      "Could not access or create log file: " <> string.inspect(e)
+    }),
+  )
+
+  actor.new(State(filepath:))
+  |> actor.on_message(handle_message)
+  |> actor.start
+  |> result.map_error(fn(start_error) {
+    "Could not start logger: " <> string.inspect(start_error)
+  })
+  |> result.map(fn(started) { started.data })
+}
+
+fn handle_message(state: State, control: Control) -> actor.Next(State, Control) {
+  case control {
+    control.Write(content) -> {
+      let log_line =
+        timestamp.system_time()
+        |> timestamp.to_rfc3339(calendar.utc_offset)
+        <> ": "
+        <> content
+        <> "\n"
+
+      // Ignore any logging errors
+      let _ = simplifile.append(state.filepath, log_line)
+      actor.continue(state)
+    }
+    control.Exit(reply_to) -> {
+      process.send(reply_to, Nil)
+      actor.stop()
+    }
+  }
+}
+
+pub fn log(logger: Subject(Control), content: String) -> Nil {
+  process.send(logger, control.Write(content))
+}

src/musicplayer/mpv/mpv.gleam

@@ -24,7 +24,7 @@ pub fn new() -> Result(Subject(Control), String) {
         |> actor.start
       {
         Error(start_error) ->
-          Error("Could not start actor: " <> string.inspect(start_error))
+          Error("Could not start mpv: " <> string.inspect(start_error))
         Ok(actor.Started(data: mpv, ..)) -> Ok(mpv)
       }
     }
@@ -37,8 +37,6 @@ fn handle_message(
 ) -> actor.Next(State(socket), Control) {
   case control {
     control.TogglePlayPause -> {
-      echo "mpv: toggling play/pause"
-
       let _ =
         result.map_error(control.toggle_play_pause(state.socket), fn(err) {
           echo "Could not toggle play/pause: " <> err.details

src/musicplayer/musicplayer.gleam

@@ -1,124 +1,206 @@
-import gleam/erlang/process.{type Name, type Subject}
-import gleam/float
+import gleam/erlang/process.{type Name, type Pid, type Subject}
 import gleam/otp/actor
 import gleam/result
 import gleam/string
 
 import musicplayer/control.{type Control}
 import musicplayer/input/key.{type Key}
+import musicplayer/logging/control as logging_control
+import musicplayer/logging/logging
 import musicplayer/mpv/control as mpv_control
+import musicplayer/time/time
 import musicplayer/ui/control as ui_control
+import musicplayer/ui/layout
 
-type State(ui, mpv, input_inject, exit) {
+type Mode {
+  Idle
+  Searching
+}
+
+type Input {
+  Input(capturing: Bool, content: String)
+}
+
+type State {
   State(
+    mode: Mode,
+    input: Input,
+    logger: Subject(logging_control.Control),
     ui: Subject(ui_control.Control),
     mpv: Subject(mpv_control.Control),
-    input_inject: Subject(Key),
-    exit: Subject(Nil),
   )
 }
 
 pub fn new(
+  logger: Subject(logging_control.Control),
   ui: Subject(ui_control.Control),
   mpv: Subject(mpv_control.Control),
   input_keys_name: Name(Key),
-  input_stream_name: Name(List(String)),
-  input_inject_name: Name(Key),
-  exit: Subject(Nil),
-) -> Result(Nil, String) {
+) -> Result(Pid, String) {
   let input_keys = process.named_subject(input_keys_name)
-  let input_stream = process.named_subject(input_stream_name)
-  let input_inject = process.named_subject(input_inject_name)
+
+  let input = Input(False, "")
 
   case
-    actor.new(State(ui, mpv, input_inject, exit))
+    actor.new(State(Idle, input, logger, ui, mpv))
     |> actor.on_message(handle_message)
     |> actor.start
   {
     Error(start_error) ->
       Error("Could not start actor: " <> string.inspect(start_error))
-    Ok(actor.Started(data: musicplayer, ..)) -> {
+    Ok(actor.Started(pid:, data: musicplayer)) -> {
+      logging.log(logger, "musicplayer - started")
       process.spawn(fn() {
         let assert Ok(_) = process.register(process.self(), input_keys_name)
         handle_key(musicplayer, input_keys)
       })
 
-      process.spawn(fn() {
-        let assert Ok(_) = process.register(process.self(), input_stream_name)
-        temp_input_stream(input_stream)
-      })
+      process.spawn(fn() { update_playback_time_loop(mpv, ui, 1000) })
 
-      Ok(Nil)
+      Ok(pid)
     }
   }
 }
 
-fn handle_message(
-  state: State(ui, mpv, input_inject, exit),
-  control: Control,
-) -> actor.Next(State(ui, mpv, input_inject, exit), Control) {
+fn handle_message(state: State, control: Control) -> actor.Next(State, Control) {
   case control {
     control.Search -> {
-      process.send(state.input_inject, key.Continue([key.input_introducer]))
+      logging.log(state.logger, "musicplayer - initiating search")
 
-      actor.continue(state)
+      update_search(state.ui, "searching: ")
+
+      actor.continue(
+        State(
+          ..state,
+          mode: Searching,
+          input: Input(..state.input, capturing: True),
+        ),
+      )
     }
+
+    control.Raw(content) -> {
+      logging.log(state.logger, "musicplayer - recieved raw input: " <> content)
+
+      let content = case state.mode {
+        Idle -> state.input.content
+        Searching -> {
+          let updated = state.input.content <> content
+          update_search(state.ui, "searching: " <> updated)
+          updated
+        }
+      }
+
+      actor.continue(State(..state, input: Input(..state.input, content:)))
+    }
+    control.Backspace -> {
+      logging.log(state.logger, "musicplayer - recieved backspace")
+
+      let content = case state.mode {
+        Idle -> state.input.content
+        Searching -> string.drop_end(state.input.content, 1)
+      }
+      actor.continue(State(..state, input: Input(..state.input, content:)))
+    }
+    control.Return -> {
+      logging.log(
+        state.logger,
+        "musicplayer - recieved return. `input.capture`: "
+          <> "'"
+          <> state.input.content
+          <> "'",
+      )
+
+      // Note: state.input.content is now the final input, use it
+      // before it is reset
+      case state.mode {
+        Idle -> Nil
+        Searching -> update_search(state.ui, "")
+      }
+
+      actor.continue(
+        State(..state, mode: Idle, input: Input(capturing: False, content: "")),
+      )
+    }
+
     control.TogglePlayPause -> {
-      echo "toggling play/pause"
+      logging.log(state.logger, "musicplayer - toggling play/pause")
 
       process.send(state.mpv, mpv_control.TogglePlayPause)
-
-      case
-        process.call(state.mpv, 1000, fn(reply_to) {
-          mpv_control.GetPlaybackTime(reply_to)
-        })
-      {
-        Error(err) ->
-          process.send(
-            state.ui,
-            ui_control.UpdateState(
-              "playback time: N/A (err: " <> err.details <> ")",
-            ),
-          )
-
-        Ok(mpv_control.PlaybackTime(data: playback_time)) ->
-          process.send(
-            state.ui,
-            ui_control.UpdateState(
-              "playback time: " <> float.to_string(playback_time),
-            ),
-          )
-      }
-
+      update_playback_time(state.mpv, state.ui)
       actor.continue(state)
     }
     control.Exit -> {
+      logging.log(state.logger, "musicplayer - initiating musicplayer shutdown")
       // Close `mpv` socket
       process.call(state.mpv, 1000, fn(reply_to) { mpv_control.Exit(reply_to) })
 
       // Reset terminal state (show cursor etc.)
       process.call(state.ui, 1000, fn(reply_to) { ui_control.Exit(reply_to) })
 
-      // End main process
-      process.send(state.exit, Nil)
+      logging.log(state.logger, "musicplayer - stopped")
+
+      // Close logger (NOOP)
+      process.call(state.logger, 1000, fn(reply_to) {
+        logging_control.Exit(reply_to)
+      })
+
       actor.stop()
     }
   }
 }
 
-/// `handle_key` listens to a subject onto which `input` will send messages with
-/// parsed `Key`s which will be mapped to `Control`s (if possible)
+fn update_playback_time_loop(
+  mpv: Subject(mpv_control.Control),
+  ui: Subject(ui_control.Control),
+  interval_ms: Int,
+) {
+  process.sleep(interval_ms)
+  update_playback_time(mpv, ui)
+
+  update_playback_time_loop(mpv, ui, interval_ms)
+}
+
+fn update_playback_time(
+  mpv: Subject(mpv_control.Control),
+  ui: Subject(ui_control.Control),
+) -> Nil {
+  case
+    process.call(mpv, 1000, fn(reply_to) {
+      mpv_control.GetPlaybackTime(reply_to)
+    })
+  {
+    Error(err) ->
+      process.send(
+        ui,
+        ui_control.UpdateState(
+          layout.PlaybackTime,
+          "playback time: N/A (err: " <> err.details <> ")",
+        ),
+      )
+
+    Ok(mpv_control.PlaybackTime(data: playback_time)) ->
+      process.send(
+        ui,
+        ui_control.UpdateState(
+          layout.PlaybackTime,
+          "playback time: " <> time.to_duration_string(playback_time),
+        ),
+      )
+  }
+}
+
+fn update_search(ui: Subject(ui_control.Control), content: String) -> Nil {
+  process.send(ui, ui_control.UpdateState(layout.Search, content))
+}
+
+/// `handle_key` listens to a subject onto which `input` will send messages with `Key`s
 fn handle_key(musicplayer: Subject(Control), input_keys: Subject(Key)) -> Nil {
   let _ =
-    process.receive_forever(input_keys)
+    process.new_selector()
+    |> process.select(input_keys)
+    |> process.selector_receive_forever
     |> control.from_key
     |> result.map(process.send(musicplayer, _))
 
   handle_key(musicplayer, input_keys)
 }
-
-fn temp_input_stream(input_stream: Subject(List(String))) -> Nil {
-  let stream = process.receive_forever(input_stream)
-  echo "input stream: " <> string.inspect(stream)
-  temp_input_stream(input_stream)
-}

src/musicplayer/time/time.gleam

@@ -0,0 +1,23 @@
+import gleam/float
+import gleam/int
+import gleam/string
+
+pub fn to_duration_string(seconds: Float) -> String {
+  let total =
+    seconds
+    |> float.max(0.0)
+    |> float.truncate
+
+  let minutes = total / 60
+  let seconds = total % 60
+
+  let mins =
+    int.to_string(minutes)
+    |> string.pad_start(to: 2, with: "0")
+
+  let secs =
+    int.to_string(seconds)
+    |> string.pad_start(to: 2, with: "0")
+
+  mins <> ":" <> secs
+}

src/musicplayer/ui/control.gleam

@@ -1,7 +1,9 @@
 import gleam/erlang/process.{type Subject}
 
+import musicplayer/ui/layout.{type Section}
+
 pub type Control {
-  UpdateState(content: String)
+  UpdateState(section: Section, content: String)
 
   Exit(reply_to: Subject(Nil))
 }

src/musicplayer/ui/internal.gleam

@@ -1,15 +1,17 @@
+import gleam/int
 import gleam/io
 
-pub fn print(content: String) -> Nil {
-  io.print(content <> "\n")
-}
-
 // https://en.wikipedia.org/wiki/ANSI_escape_code#Control_Sequence_Introducer_commands
 
 pub fn clear_screen() -> Nil {
   io.print("\u{001B}[2J\u{001B}[H")
 }
 
+pub fn print_at(text: String, x: Int, y: Int) -> Nil {
+  let seq = "\u{001B}[" <> int.to_string(y) <> ";" <> int.to_string(x) <> "H"
+  io.print(seq <> text)
+}
+
 pub fn hide_cursor() -> Nil {
   io.print("\u{001B}[?25l")
 }

src/musicplayer/ui/layout.gleam

@@ -0,0 +1,51 @@
+import gleam/dict
+
+pub type Layout {
+  Layout(nodes: dict.Dict(Section, Node))
+}
+
+pub type Section {
+  Root
+  Header
+  Search
+  PlaybackTime
+}
+
+pub type Node {
+  Node(content: String, x: Int, y: Int, children: List(Section))
+}
+
+pub fn new() -> Layout {
+  let nodes =
+    dict.from_list([
+      #(
+        Root,
+        Node(content: "", x: 0, y: 0, children: [
+          Header,
+          Search,
+          PlaybackTime,
+        ]),
+      ),
+      #(Header, Node(content: "Music Player", x: 1, y: 1, children: [])),
+      #(Search, Node(content: "", x: 30, y: 1, children: [])),
+      #(PlaybackTime, Node(content: "00:00", x: 1, y: 2, children: [])),
+    ])
+
+  Layout(nodes: nodes)
+}
+
+pub fn update_section(
+  layout: Layout,
+  section: Section,
+  content: String,
+) -> Layout {
+  case dict.get(layout.nodes, section) {
+    Error(_) -> layout
+    Ok(node) ->
+      Layout(nodes: dict.insert(
+        layout.nodes,
+        section,
+        Node(..node, content: content),
+      ))
+  }
+}

src/musicplayer/ui/ui.gleam

@@ -1,19 +1,25 @@
+import gleam/dict
 import gleam/erlang/process.{type Subject}
+import gleam/list
 import gleam/otp/actor
 import gleam/string
 
 import musicplayer/ui/control.{type Control}
 import musicplayer/ui/internal as ui_internal
+import musicplayer/ui/layout.{type Layout, type Section}
 
 pub type State(redraw, content) {
-  State(redraw: Subject(String), content: String)
+  State(redraw: Subject(Layout), layout: Layout)
 }
 
 pub fn new() -> Result(Subject(Control), String) {
   let redraw_name = process.new_name("redraw")
-  let redraw: Subject(String) = process.named_subject(redraw_name)
+  let redraw: Subject(Layout) = process.named_subject(redraw_name)
+
+  let layout = layout.new()
+
   case
-    actor.new(State(redraw, ""))
+    actor.new(State(redraw, layout))
     |> actor.on_message(handle_message)
     |> actor.start
   {
@@ -26,7 +32,7 @@ pub fn new() -> Result(Subject(Control), String) {
         ui_internal.clear_screen()
         ui_internal.hide_cursor()
 
-        redraw_loop(redraw)
+        redraw_on_update_loop(redraw)
       })
 
       Ok(ui)
@@ -35,15 +41,18 @@ pub fn new() -> Result(Subject(Control), String) {
 }
 
 fn handle_message(
-  state: State(redraw, content),
+  state: State(redraw, layout),
   control: Control,
-) -> actor.Next(State(redraw, content), Control) {
+) -> actor.Next(State(redraw, layout), Control) {
   case control {
-    control.UpdateState(content) -> {
-      let state = State(..state, content:)
-      actor.send(state.redraw, content)
+    control.UpdateState(section, content) -> {
+      let layout = layout.update_section(state.layout, section, content)
+      let state = State(..state, layout:)
+
+      actor.send(state.redraw, layout)
       actor.continue(state)
     }
+
     control.Exit(reply_to) -> {
       ui_internal.show_cursor()
       process.send(reply_to, Nil)
@@ -52,11 +61,21 @@ fn handle_message(
   }
 }
 
-fn redraw_loop(redraw: Subject(String)) -> Nil {
-  let content = process.receive_forever(redraw)
+fn redraw_on_update_loop(redraw: Subject(Layout)) -> Nil {
+  let layout = process.receive_forever(redraw)
 
   ui_internal.clear_screen()
-  ui_internal.print(content)
+  render_layout(layout, layout.Root)
 
-  redraw_loop(redraw)
+  redraw_on_update_loop(redraw)
+}
+
+fn render_layout(layout: Layout, from: Section) -> Nil {
+  case dict.get(layout.nodes, from) {
+    Error(_) -> Nil
+    Ok(node) -> {
+      list.each(node.children, fn(child) { render_layout(layout, child) })
+      ui_internal.print_at(node.content, node.x, node.y)
+    }
+  }
 }

test/musicplayer/input/input_test.gleam

@@ -1,7 +1,7 @@
 import gleam/list
 import gleeunit
 
-import musicplayer/input/key.{type Key, Char, csi, esc, input_introducer as ii}
+import musicplayer/input/key.{type Key, Char, backspace, csi, esc, return}
 
 pub fn main() -> Nil {
   gleeunit.main()
@@ -27,11 +27,8 @@ pub fn key_from_list_test() {
   ]
 
   let input_tests = [
-    TestCase([ii], key.Continue([ii])),
-    TestCase([ii, "a"], key.Continue([ii, "a"])),
-    TestCase([ii, "a", "b"], key.Continue([ii, "ab"])),
-    TestCase([ii, "ab", "\u{007F}"], key.Continue([ii, "a"])),
-    TestCase([ii, "ab", "\r"], key.Input("ab")),
+    TestCase([return], key.Return),
+    TestCase([backspace], key.Backspace),
   ]
 
   let test_cases = [base_tests, char_tests, escape_tests, input_tests]

test/musicplayer/time/time_test.gleam

@@ -0,0 +1,32 @@
+import gleam/list
+import gleeunit
+
+import musicplayer/time/time
+
+pub fn main() -> Nil {
+  gleeunit.main()
+}
+
+type TestCase {
+  TestCase(seconds: Float, expected: String)
+}
+
+pub fn to_duration_string_test() {
+  let test_cases = [
+    TestCase(-1.0, "00:00"),
+    TestCase(0.0, "00:00"),
+    TestCase(9.0, "00:09"),
+    TestCase(10.0, "00:10"),
+    TestCase(11.0, "00:11"),
+    TestCase(60.0, "01:00"),
+    TestCase(61.0, "01:01"),
+    TestCase(120.0, "02:00"),
+    TestCase(600.0, "10:00"),
+    TestCase(6000.0, "100:00"),
+    TestCase(6001.0, "100:01"),
+  ]
+
+  list.each(test_cases, fn(tc) {
+    assert tc.expected == time.to_duration_string(tc.seconds)
+  })
+}